သင့် Word Documents များကို အမြန်ပြောင်းရန် Macro နည်းလမ်း ၃ ခု PDF files တွေကို

ဤဆောင်းပါးတွင်၊ သင့်အား Word စာရွက်စာတမ်းများအဖြစ်သို့ လျင်မြန်စွာပြောင်းလဲရန်အတွက် သင်အသုံးပြုနိုင်သည့် မက်ခရို 3 ခုကို ပေးဆောင်ရန် အာရုံစိုက်ပါမည်။ pdf ဖိုင်များကို။

Word 2003 တွင် မီနူးဘားတွင် အိုင်ကွန်တစ်ခု ရှိသည်။ တစ်ချက်နှိပ်ရုံဖြင့် သုံးစွဲသူများသည် “Save As” ဝင်းဒိုးကို ချက်ချင်းစတင်နိုင်ပြီး စာရွက်စာတမ်းကို သိမ်းဆည်းနိုင်မည်ဖြစ်သည်။ pdf format နဲ့။

သို့သော် သင်သတိပြုမိသည့်အတိုင်း Word 2010 ၏ အပြင်အဆင်သည် များစွာပြောင်းလဲသွားသည်။ အသုံးပြုသူများသည် "File" tab ကိုနှိပ်ပြီး "Save As" ဟူသောအမိန့်ကို "Save As" ဝင်းဒိုးကိုစတင်ရန်ဖြစ်သည်။ ထို့အပြင်၊ “Save” ခလုတ်ကိုမနှိပ်မီ သိမ်းဆည်းမှုအမျိုးအစားကို ကိုယ်တိုင်ရွေးချယ်ရမည်ဖြစ်သည်။

ဒီကလစ်တွေအားလုံးနဲ့ဆိုရင် လုံလောက်တဲ့ မြန်နှုန်းမရှိပါဘူး။ ဒါကြောင့် ဒီပို့စ်မှာ macro နည်းလမ်းကို ပြသချင်ပါတယ်။

Macro 1- "Save As" Window ကို အမြန်စတင်ပါ။

1. အရင်ဆုံး “Developer” tab ကိုနှိပ်ပြီးရင် “Visual Basic” command ကိုနှိပ်ပြီး VBA editor ကိုဖွင့်ပါ။ “Developer” tab ပေါ်လာပြီဆိုရင် ၂ ချက်နှိပ်ရပါမယ်။ တခြားနည်းလမ်းကတော့ “Alt+ F11” ကိုနှိပ်တာပါပဲ။
2. ဒုတိယအနေဖြင့်၊ "ပုံမှန်" ပရောဂျက်ကိုနှိပ်ပါ။
3. တတိယအနေဖြင့် “Insert” ကိုနှိပ်ပြီး စာရင်းမီနူးရှိ “Module” ကိုရွေးချယ်ပါ။
4. တည်းဖြတ်ဧရိယာကိုပြသရန် ယခု module ကို နှစ်ချက်နှိပ်ပါ။
5. ထို့နောက် အောက်ပါကုဒ်များကို ကူးထည့်ပါ-

Sub TriggerSaveAsWindow()
  Dim dlgSaveAs As Dialog
 
  Set dlgSaveAs = Dialogs(wdDialogFileSaveAs)
  With dlgSaveAs
    .Format = wdFormatPDF
    .Show
    .Execute
  End With
End Sub

6. ထို့နောက် "Run" ကိုနှိပ်ပါ။

အခုဆိုရင် “Save As” ဝင်းဒိုးရောက်ပါပြီ။ save အမျိုးအစားက pdf မှာရှိပြီးသားပါ။ “Save” ခလုတ်ကို နှိပ်လိုက်ရုံပါပဲ။ ဒီ macro က လိုအပ်ရင် ဖိုင်နာမည်ကို ပြောင်းလဲနိုင်စေပါတယ်။

Macro 2: Word ဖိုင်များကို PDF သို့ တိုက်ရိုက်သိမ်းဆည်းပါ

အဖြစ်အပျက်တွင် လူအချို့သည် ဖိုင်ကို တိုက်ရိုက်သိမ်းဆည်းလိုကြသည်။ pdf ဖိုင်အမည်ကို မပြင်ဆင်ဘဲ၊ ဤနေရာတွင် လိုအပ်နေသော မက်ခရိုဖြစ်သည်။

1. ပထမဆုံးအနေနဲ့ အပေါ်က ပထမအဆင့် 4 ခုကို ပြန်လုပ်ပါ။
2. ထို့နောက်၊ ၎င်းအစား အောက်ပါကုဒ်များကို ကူးထည့်ပါ-

'Directly save Word file as Pdf and aumatically open it.
Sub DirectlySaveDocxToPdf()
  Dim objDoc As Document
 
  Set objDoc = ActiveDocument
  objDoc.ExportAsFixedFormat _
    OutputFileName:=Replace(objDoc.FullName, ".docx", ".pdf"), _
    ExportFormat:=wdExportFormatPDF, OpenAfterExport:=True, OptimizeFor:=wdExportOptimizeForPrint, _
    Range:=wdExportAllDocument, Item:=wdExportDocumentContent
End Sub

3. အလားတူ “Run” ကိုနှိပ်ပါ။

Macro 3: Word Docx ဖိုင်များကို PDF များအဖြစ် အသုတ်လိုက်ပြောင်းလဲခြင်း

1. docx ဖိုင်အားလုံးကို ဖိုဒါတစ်ခုတွင် ဦးစွာထားပါ။
2. တည်းဖြတ်ဧရိယာဖွင့်ရန် အထက်ဖော်ပြပါအဆင့်များကို လိုက်နာပါ။
3. ထို့နောက် အောက်ပါ macro ကို ကူးထည့်ပါ

Sub BatchConvertDocxToPDF()
  Dim objDoc As Document
  Dim strFile As String, strFolder As String
 
  'Initialization
  strFolder = "C:\Users\Test\Desktop\Test Files\"
  strFile = Dir(strFolder & "*.docx", vbNormal)
 
  'Precess each file in the file folder and convert them to pdf.
  While strFile <> ""
    Set objDoc = Documents.Open(FileName:=strFolder & strFile)
 
    objDoc.ExportAsFixedFormat _
      OutputFileName:=Replace(objDoc.FullName, ".docx", ".pdf"), _
      ExportFormat:=wdExportFormatPDF, OpenAfterExport:=False, OptimizeFor:=wdExportOptimizeForPrint, _
      Range:=wdExportAllDocument, Item:=wdExportDocumentContent
 
    objDoc.Close
    strFile = Dir()
  Wend
End Sub

4. "Run" ခလုတ်ကိုနှိပ်ရန်မမေ့ပါနှင့်။

မှတ်စုကုဒ်များတွင် “strFolder = “C:\Users\Test\Desktop\Test Files\”"the"“C:\Users\Test\Desktop\Test Files\”” ဖိုဒါ၏ ဖိုင်လမ်းကြောင်းဖြစ်သည်။ အလိုက်သင့်ပြောင်းဖို့ မမေ့ပါနဲ့။

ဒီ macro ကို run ပြီးနောက် pdf တွေကို Word document တွေရှိတဲ့ folder တစ်ခုတည်းမှာ save လုပ်ပါလိမ့်မယ်။

ဖိုင်များကို တတ်နိုင်သမျှ လုံခြုံအောင်ထားပါ။

ပျက်စီးနေသောဖိုင်များကို ပြန်လည်ဆယ်ယူရန်အတွက် ကြိုတင်ကာကွယ်မှုအစီအမံများနှင့် ဘေးအန္တရာယ်အပြီးလုပ်ဆောင်ချက်များရှိပါသည်။ သင့်ဖိုင်များကို ပုံမှန် backup လုပ်ပါက မူရင်းဖိုင်ကို ပြန်လည်ရယူရန်မှာ လွယ်ကူသောအလုပ်တစ်ခုသာဖြစ်သည်။ အမှန်တရားမှာ လူအနည်းငယ်သာ ၎င်းတို့၏ backup အစီအစဉ်ကို လိုက်နာနိုင်ပြီး အဖိုးတန်ဒေတာများ ဆုံးရှုံးနိုင်ခြေကို မြင့်တက်စေပါသည်။ ထိုကဲ့သို့သောအခြေအနေများတွင် အဆင့်မြင့်နည်းလမ်းကို အသုံးပြုရန် အချိန်ရောက်ပါပြီ။ Word document အဂတိလိုက်စားမှုဖြေရှင်းရေးကိရိယာ.

စာရေးသူနိဒါန်း:

Vera Chen သည် ဒေတာပြန်လည်ရယူရေးဆိုင်ရာ ကျွမ်းကျင်သူဖြစ်သည်။ DataNumen, Inc. အပါအဝင် ဒေတာပြန်လည်ရယူရေးနည်းပညာများတွင် ကမ္ဘာ့ခေါင်းဆောင်ဖြစ်သည်။ ပျက်စီးနေသော Excel xlsx ပြုပြင်ရန် နှင့် pdf ဆော့ဖ်ဝဲ ထုတ်ကုန်များကို ပြုပြင်ခြင်း။ ပိုမိုသိရှိလိုပါကသွားရောက်ကြည့်ရှု www ။datanumen.com