အလံတင်ထားသော Outlook အီးမေးလ်များအားလုံးကို Excel သို့ အမြန်ထုတ်ရန် နည်းလမ်း 2 ခု

Outlook ဖြေရှင်းချက် စက်တင်ဘာလ 29, 2025

သင်၏ Outlook စာတိုက်ပုံးမှ အလံတင်ထားသော အီးမေးလ်များအားလုံးကို Excel သို့ တင်ပို့လိုပါက၊ ဤဆောင်းပါးတွင် မျှဝေထားသော နည်းလမ်း 2 ခုထဲမှ တစ်ခုခုကို အသုံးပြုနိုင်ပါသည်။

ဥပမာအားဖြင့်၊ အလံတင်ထားသောအီးမေးလ်အားလုံးကို အချိန်နှင့်တစ်ပြေးညီ ကိုင်တွယ်ဖြေရှင်းရန် သို့မဟုတ် ၎င်းတို့ကို အခြားသူတစ်ဦးဦးနှင့် မျှဝေရန်အတွက်၊ ၎င်းတို့ကို Excel worksheet တစ်ခုသို့ တင်ပို့ရန် သင်မျှော်လင့်နိုင်သည်။ ဤတွင်ကျွန်ုပ်တို့သည်၎င်းကိုနားလည်ရန်နည်းလမ်း 2 ခုကိုမိတ်ဆက်ပေးပါမည်။ ယခင်တစ်ခုက အလံပြထားသောအီးမေးလ်များကို ရှာဖွေပြီးနောက် ပုံမှန် "သွင်းကုန်နှင့် တင်ပို့ခြင်း" အင်္ဂါရပ်ကို အသုံးပြုသည်။ ရိုးရိုးသားသားပြောရရင် ဒါက နည်းနည်းတော့ ပျင်းစရာကောင်းတယ်။ ထို့ကြောင့်၊ နောက်ဆုံးတစ်ခုတွင်၊ VBA ကိုအသုံးပြုသည့် ပိုမိုအဆင်ပြေသောနည်းလမ်းကို သင်ပေးပါမည်။

နည်းလမ်း 1- တွေ့ရှိသောအလံတင်ထားသောအီးမေးလ်များအားလုံးကို ကိုယ်တိုင်ထုတ်ပါ။

ပထမဆုံးအနေနဲ့ မေးလ်စာရင်းရဲ့ အပေါ်က search box ကို နှိပ်ပါ။
ထို့နောက် "Search" tab ရှိ "Scope" အုပ်စုရှိ "စာပို့ပစ္စည်းများအားလုံး" ကိုနှိပ်ပါ။
ထို့နောက်၊ “သတ်မှတ်ရန်” အဖွဲ့ရှိ “အလံတင်ထားသည်” ခလုတ်ကို နှိပ်ပါ။
စာရင်းတွင်ပြသထားသည့်အလံပြထားသောအီးမေးလ်များအားလုံးပြီးနောက်၊ မေးလ်တစ်ခုကိုရွေးချယ်ပြီး ၎င်းတို့အားလုံးကိုရွေးချယ်ရန် "Ctrl + A" ကိုနှိပ်ပါ။
ထို့နောက် “Ctrl+Shift+V” ခလုတ်ဖြတ်လမ်းများကို နှိပ်ပါ။
ဒိုင်ယာလော့ဂ်ဘောက်စ်အသစ်တွင်၊ Outlook ဖိုင်အောက်တွင် ဖိုင်တွဲအသစ်တစ်ခုကို ဖန်တီးပါ။
နောက်ပိုင်းတွင်၊ ဖန်တီးထားသောဖိုင်တွဲအသစ်ကိုရွေးချယ်ပြီး “OK” ကိုနှိပ်ပါ၊ ၎င်းသည် တွေ့ရှိထားသည့်အလံတင်ထားသောအီးမေးလ်အားလုံးကို ဖိုင်တွဲအသစ်သို့ရွှေ့ပါမည်။
ထို့နောက် “File” > “Open” > “Import” ကိုနှိပ်ပါ၊
ပေါ်လာသော ဒိုင်ယာလော့ခ်ဘောက်စ်တွင် “ဖိုင်တစ်ခုသို့ တင်ပို့ရန်” > “နောက်တစ်ခု” > “Microsoft Excel 97-2003” > “နောက်တစ်ခု” ကို ရွေးပါ။
မျက်နှာပြင်အသစ်တွင်၊ မှန်ကန်သောဖိုင်တွဲကိုရွေးချယ်ပြီး “Next” ကိုနှိပ်ပါ။
ထို့နောက် “Export” ကို အပြီးသတ်ရန် wizards များကို လိုက်နာပါ။
အောက်ပါပုံအတိုင်း ပုံတွင်ပြထားသည့် Excel ဖိုင်အသစ်ကို သင်ရရှိမည်ဖြစ်သည်။

နည်းလမ်း 2- VBA မှတဆင့် အလံတင်ထားသော အီးမေးလ်များစာရင်းကို ထုတ်ယူပါ။

Outlook တွင် VBA တည်းဖြတ်မှုစတင်ရန် "Alt + F11" ကိုနှိပ်ပါ။
ထို့နောက် "MS Excel Object" ကို "" နှင့်အညီဖွင့်ပါ။VBA မှာ Object Library Reference ထည့်နည်း"။
ထို့နောက်၊ အောက်ပါ VBA ကုဒ်ကို မော်ဂျူးတစ်ခုသို့ ကူးယူပါ။

Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportAllFlaggedEmailsToExcel()
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
  
    'Select a source PST file
    Set objOutlookFile = Outlook.Application.Session.PickFolder
 
    If Not (objOutlookFile Is Nothing) Then
       'Create a new Excel file
       Set objExcelApp = CreateObject("Excel.Application")
       Set objExcelWorkbook = objExcelApp.Workbooks.Add
       Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
       objExcelApp.Visible = True
 
       With objExcelWorksheet
           .Cells(1, 1) = "Subject"
           .Cells(1, 1).Font.Bold = True
           .Cells(1, 2) = "Start Date"
           .Cells(1, 2).Font.Bold = True
           .Cells(1, 3) = "Due Date"
           .Cells(1, 3).Font.Bold = True
           .Cells(1, 4) = "From"
           .Cells(1, 4).Font.Bold = True
           .Cells(1, 5) = "To"
           .Cells(1, 5).Font.Bold = True
      End With
 
      For Each objFolder In objOutlookFile.Folders
          If objFolder.DefaultItemType = olMailItem Then
             Call ProcessMailFolders(objFolder)
          End If
      Next
 
      objExcelWorksheet.Columns("A:E").AutoFit

      MsgBox "Completed!", vbInformation + vbOKOnly, "Export Emails"
    End If
End Sub

Sub ProcessMailFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim i As Long
    Dim objMail As Outlook.MailItem
    Dim objFlaggedMail As Outlook.MailItem
    Dim nLastRow As Integer
    Dim objSubfolder As Outlook.Folder
 
    For i = 1 To objCurrentFolder.Items.Count
        If objCurrentFolder.Items(i).Class = olMail Then
           'Export the information of each flagged email to Excel
           Set objMail = objCurrentFolder.Items(i)
           If objMail.IsMarkedAsTask = True And objMail.FlagStatus <> olFlagComplete Then
              Set objFlaggedMail = objMail
 
              With objExcelWorksheet
                   nLastRow = .Range("A" & .Rows.Count).End(xlUp).Row + 1
                   .Range("A" & nLastRow) = objFlaggedMail.Subject
                   .Range("B" & nLastRow) = objFlaggedMail.TaskStartDate
                   .Range("C" & nLastRow) = objFlaggedMail.TaskDueDate
                   .Range("D" & nLastRow) = objFlaggedMail.SenderName
                   .Range("E" & nLastRow) = objFlaggedMail.To
              End With
          End If
        End If
    Next i
 
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessMailFolders(objSubfolder)
       Next
    End If
End Sub

နောက်ဆုံးအနေဖြင့်၊ “ExportAllFlaggedEmailsToExcel” လုပ်ရိုးလုပ်စဉ်ခွဲတွင် ကာဆာကိုထည့်ကာ “F5” ခလုတ်ခလုတ်ကို နှိပ်ပါ။
ထို့နောက် dialog box အသစ်တွင် Outlook ဖိုင်ကို ရွေးပါ။
သင်သည် "ပြီးမြောက်သည်" အမှာစာရရှိသောအခါ၊ အောက်ဖော်ပြပါပုံကဲ့သို့ Excel ဖိုင်အသစ်တစ်ခုကိုလည်းရလိမ့်မည်။

သင်၏ Outlook ကို အကျင့်ပျက်ခြစားမှုမှ ကာကွယ်ပါ။

Outlook မှာ အမှားအယွင်းတွေနဲ့ ပျက်စီးမှုတွေ ကြုံတွေ့ရလွယ်တာကြောင့် ကျွန်ုပ်တို့ရဲ့ Outlook ဒေတာတွေကို ကာကွယ်ဖို့က အလွန်ခက်ခဲတဲ့ အလုပ်တစ်ခုပါပဲ။ အထိရောက်ဆုံးနဲ့ လက်တွေ့ကျဆုံးနည်းလမ်းကတော့ Outlook အတွက် ပုံမှန်ဒေတာ အရန်ကူးယူခြင်းပါပဲ။ ဒါ့အပြင် အစွမ်းထက်ပြီး ယုံကြည်စိတ်ချရတဲ့ Outlook ပြင်ဆင်ရေးကိရိယာတစ်ခုကိုလည်း ရယူထားဖို့ လိုအပ်ပါတယ်။ ဥပမာ - DataNumen Outlook Repair. အဆင်ပြေရင် အဆင်ပြေမှာပါ။ inbox ပြုပြင်ရေးကိရိယာ အကျိုးသက်ရောက်မှုမရှိစေပါ။

စာရေးသူနိဒါန်း:

Shirley Zhang သည် ဒေတာပြန်လည်ရယူရေးဆိုင်ရာ ကျွမ်းကျင်သူဖြစ်သည်။ DataNumen, Inc. အပါအဝင် ဒေတာပြန်လည်ရယူရေးနည်းပညာများတွင် ကမ္ဘာ့ခေါင်းဆောင်ဖြစ်သည်။ ပုံသေတပ်ထား SQL Server နှင့် outlook ပြုပြင်ရေး software ထုတ်ကုန်များ။ ပိုမိုသိရှိလိုပါကသွားရောက်ကြည့်ရှု www ။datanumen.com

မှတ်ချက်များကိုပိတ်ထားကြသည်။