Kā Outlook iestatīt atšķirīgu noklusējuma atgādinājuma laiku dažāda veida atzīmētiem vienumiem

Pēc noklusējuma Outlook automātiski izmantos uzdevumu noklusējuma atgādinājuma laiku visu veidu atzīmētajiem vienumiem. Tomēr, ja vēlaties atzīmētiem vienumiem izmantot atšķirīgu atgādinājuma laiku, pamatojoties uz vienuma tipu, varat atsaukties uz šajā rakstā ieviesto metodi.

Programma Outlook ļauj iestatīt noklusējuma atgādinājuma laiku visiem atzīmētajiem vienumiem neatkarīgi no vienuma veida. Jūs varat doties uz izvēlni Fails un noklikšķināt uz Opcijas. Pēc tam logā “Outlook opcijas” cilnē “Uzdevumi” varat redzēt opciju “Noklusējuma atgādinājuma laiks”, kā parādīts nākamajā ekrānuzņēmumā.

Tomēr vairums lietotāju vēlas izmantot atšķirīgu atgādinājuma laiku dažādiem atzīmēto vienumu veidiem, piemēram, “9:00” atzīmētajām e-pasta ziņām un “17:30” atzīmētajām kontaktpersonām. Tagad, turpmāk, mēs pievērsīsimies šim piemēram, lai ieviestu metodi.

Iestatiet atšķirīgu noklusējuma atgādinājuma laiku dažāda veida atzīmētiem vienumiem

1. Lai sāktu, palaidiet programmu Outlook.
2. Pēc tam piekļūstiet Outlook VBA redaktoram, atsaucoties uzKā palaist VBA kodu programmā Outlook".
3. Nākamajā logā “Microsoft Visual Basic for Applications” nokopējiet šo kodu projektā “ThisOutlookSession”.

Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objMail As Outlook.MailItem
Public WithEvents objContact As Outlook.ContactItem

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olMail Then
       Set objMail = objExplorer.Selection.Item(1)
    ElseIf TypeOf objExplorer.Selection.Item(1) Is ContactItem Then
       Set objContact = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail Then
       Set objMail = Inspector.CurrentItem
    ElseIf Inspector.CurrentItem.Class = olContact Then
       Set objContact = Inspector.CurrentItem
    End If
End Sub

Private Sub objMail_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objMail.IsMarkedAsTask = True Then
          If objMail.TaskDueDate <> "1/1/4501" Then
             With objMail
                  .ReminderSet = True
                  'Change the reminder time for flagged emails
                  .ReminderTime = objMail.TaskDueDate & " 10:00"
                  .Save
             End With
          End If
       End If
    End If
End Sub

Private Sub objContact_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objContact.IsMarkedAsTask = True Then
          If objContact.TaskDueDate <> "1/1/4501" Then
             With objContact
                  .ReminderSet = True
                  'Change the reminder time for flagged contacts
                  .ReminderTime = objContact.TaskDueDate & " 17:30"
                  .Save
             End With
          End If
       End If
    End If
End Sub

4. Pēc tam restartējiet programmu Outlook, lai aktivizētu šo makro.
5. Turpmāk katru reizi, kad atzīmējat e-pastu, atgādinājuma laiks karoga izpildes datumā tiks iestatīts uz “10:00”.
6. Kad atzīmējat kontaktu, karoga izpildes datumā atgādinājuma laiks tiks iestatīts uz “17:30”.

Elastīgi risiniet Outlook problēmas

Programmā Outlook var rasties visdažādākās problēmas. Tāpēc jums jau iepriekš jāapgūst daži pasākumi, lai tās risinātu. Piemēram, ja jūsu Outlook bieži restartējas, jums ir jālabo Office vai jāatspējo trešo pušu pievienojumprogrammas utt. Vai arī, ja jūsu Outlook PST tiek apdraudēts, varat vispirms izmēģināt iesūtnes labošanas rīks. Kad tas neizdodas, varat turpināt izmantot spēcīgu ārēju rīku, piemēram, DataNumen Outlook Repair.

Autora ievads:

Šērlija Džana ir datu atkopšanas eksperte DataNumen, Inc., kas ir pasaules līderis datu atkopšanas tehnoloģiju, tostarp mdf atkopšana un perspektīvas remonta programmatūras produktus. Lai iegūtu vairāk informācijas, apmeklējiet vietni www.datanumen. Ar