როგორ სწრაფად მოხდეს Outlook საქაღალდის ექსპორტი ყველა ქვესაქაღალდესთან და ელემენტთან Windows საქაღალდეში

ზოგჯერ შეიძლება დაგჭირდეთ Outlook საქაღალდის ჯგუფური ექსპორტი ყველა ქვესაქაღალდესთან და ელემენტთან ერთად Windows საქაღალდეში. ეს სტატია გასწავლით ისეთ მეთოდს, რომელიც იყენებს Outlook VBA-ს.

როდესაც გსურთ Outlook-ის საქაღალდის ექსპორტი ადგილობრივ დისკზე ყველა ელემენტით იმავე საქაღალდის სტრუქტურაში, თუ აირჩევთ შენახვას და ექსპორტს ხელით, ამას დიდი დრო დაგჭირდებათ. ამდენად, რატომ არ მიმართავთ სხვა საშუალებებს, როგორიცაა საექსპორტო ინსტრუმენტები ან VBA კოდები? აქ ჩვენ გაგაცნობთ VBA კოდის ასეთ ნაწილს. ის მოგცემთ საშუალებას მიაღწიოთ მას, როგორც ნიავი.

Outlook-ის საქაღალდეში არსებული ყველა ქვესაქაღალდისა და ელემენტის ექსპორტი Windows საქაღალდეში

1. დასაწყისისთვის, ჩართეთ თქვენი Outlook პროგრამა.
2. შემდეგ Outlook-ის მთავარ ფანჯარაში დააჭირეთ ღილაკს "Alt + F11" კლავიშების მალსახმობებს.
3. ამის შემდეგ გამოჩნდება "Microsoft Visual Basic აპლიკაციებისთვის" ფანჯარა.
4. შემდეგ თქვენ უნდა გახსნათ ცარიელი მოდული და დააკოპირეთ მასში შემდეგი VBA კოდები.

Private objFileSystem As Object
 
Private Sub ExportFolderWithAllItems()
    Dim objFolder As Outlook.Folder
    Dim strPath As String
 
    'Specify the root local folder
    'Change it as per your needs
    strPath = "E:\Outlook\"
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
    'Select a Outlook PST file or Outlook folder
    Set objFolder = Outlook.Application.Session.PickFolder
 
    Call ProcessFolders(objFolder, strPath)
 
    MsgBox "Complete", vbExclamation
End Sub
 
Private Sub ProcessFolders(objCurrentFolder As Outlook.Folder, strCurrentPath As String)
    Dim objItem As Object
    Dim strSubject, strFileName, strFilePath As String
    Dim objSubfolder As Outlook.Folder
 
    'Create the local folder based on the Outlook folder
    strCurrentPath = strCurrentPath & objCurrentFolder.Name
    objFileSystem.CreateFolder strCurrentPath
 
    For Each objItem In objCurrentFolder.Items
 
        strSubject = objItem.Subject
 
        'Remove unsupported characters in the subject
        strSubject = Replace(strSubject, "/", " ")
        strSubject = Replace(strSubject, "\", " ")
        strSubject = Replace(strSubject, ":", "")
        strSubject = Replace(strSubject, "?", " ")
        strSubject = Replace(strSubject, Chr(34), " ")

        strFileName = strSubject & ".msg"
 
        i = 0
        Do Until False
           strFilePath = strCurrentPath & "\" & strFileName
           'Check if there exist a file in the same name
           If objFileSystem.FileExists(strFilePath) Then
              'Add a sequence order to the file name
              i = i + 1
              strFileName = strSubject & " (" & i & ").msg"
           Else
              Exit Do
          End If
        Loop
 
        'Save as MSG file
        objItem.SaveAs strFilePath, olMSG
    Next
 
    'Process subfolders recursively
    If objCurrentFolder.folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.folders
           Call ProcessFolders(objSubfolder, strCurrentPath & "\")
       Next
    End If
End Sub

5. ამის შემდეგ, თქვენ უნდა დარწმუნდეთ, რომ თქვენი Outlook ნებას რთავს მაკროებს მაკრო პარამეტრებში.
6. საბოლოოდ, შეგიძლიათ სცადოთ.

• პირველ რიგში, დაუბრუნდით ახალ მაკრო ფანჯარას.
• შემდეგ დააჭირეთ "ExportFolderWithItems" ქვეპროგრამას.
• შემდეგ დააჭირეთ F5 ღილაკს ამ მაკროს გასაშვებად.
• ამის შემდეგ, თქვენ უნდა აირჩიოთ კონკრეტული საქაღალდე.
• და ბოლოს, როდესაც მიიღებთ შეტყობინებას „დასრულებულია“, შეგიძლიათ შეხვიდეთ წინასწარ განსაზღვრულ ლოკალურ საქაღალდეზე. თქვენ ნახავთ, რომ ყველა ელემენტი შენახულია იმავე საქაღალდის სტრუქტურაში.

თავიდან აიცილეთ მონაცემების დაკარგვა Outlook-ის ავარიებისგან

შესაძლოა, ოდესმე Outlook-ის მუშაობის მრავალი შეფერხება შეგხვედრიათ. უმეტეს შემთხვევაში, გადატვირთვის შემდეგ, Outlook შეძლებს ჩვეულებრივად მუშაობას. თუმცა, არსებობს შემთხვევაც, როდესაც ჩვენი PST ფაილი შეიძლება დაზიანდეს. ამ დროს, თქვენ უნდა ეცადოთ თქვენი PST მონაცემების აღდგენას, მაგალითად, გამოცდილი ინსტრუმენტის გამოყენებით, როგორიცაა DataNumen Outlook Repair. მას შეუძლია Outlook-ის შესწორება შეცდომები და ამოიღეთ მონაცემები კომპრომეტირებული PST ფაილიდან ოფლის გაფუჭების გარეშე.

ავტორი შესავალი:

შირლი ჟანგი არის მონაცემთა აღდგენის ექსპერტი DataNumen, Inc., რომელიც მსოფლიო ლიდერია მონაცემთა აღდგენის ტექნოლოგიებში, მათ შორის SQL Server სარემონტო და Outlook სარემონტო პროგრამული პროდუქტები. დამატებითი ინფორმაციისთვის ეწვიეთ www.datanumen. ერთად