როგორ სწრაფად დააკოპიროთ საქაღალდის სტრუქტურა ერთი Outlook PST ფაილიდან მეორეზე VBA-ს საშუალებით

Outlook Solutions სექტემბერი 29, 2025

თუ გსურთ საქაღალდის სტრუქტურის კოპირება ერთი Outlook PST ფაილიდან მეორეში, შეგიძლიათ გამოიყენოთ ამ სტატიაში წარმოდგენილი მეთოდი, რომელიც გასწავლით თუ როგორ გამოიყენოთ VBA, რომ მიიღოთ იგი ერთი ნაბიჯით.

შესაძლოა, იმისთვის, რომ უკეთ მართოთ თქვენი ელფოსტა, თქვენ შექმენით რამდენიმე მორგებული საქაღალდე თქვენს მთავარ Outlook ფაილში. ამრიგად, ახალი Outlook PST ფაილის შექმნისას, შეიძლება დაგჭირდეთ იგივე საქაღალდის სტრუქტურის გამოყენება. სინამდვილეში, ჩემს წინა სტატიაში - ”2 ნაბიჯი მიმდინარე საქაღალდის Hie შესანარჩუნებლადrarchy ახალ Outlook ფაილში”, შეგიძლიათ ისწავლოთ ტრადიციული მეთოდი, რომელიც იყენებს „არქივის“ ფუნქციას მის მისაღწევად. მიუხედავად ამისა, რეალურად, ეს მაინც ცოტა დამღლელია. მასთან შედარებით, მისი მისაღებად VBA კოდების გამოყენება ბევრად უფრო სწრაფი იქნება. ამიტომ, შემდეგში გეტყვით დეტალურ ნაბიჯებსა და კოდებს.

დააკოპირეთ საქაღალდის სტრუქტურა ერთი Outlook PST ფაილიდან მეორეში

თავიდანვე, სtarთქვენი Outlook პროგრამა.
შემდეგ Outlook-ის ფანჯარაში დააჭირეთ ღილაკს "Alt + F11".
შემდეგ თქვენ შეხვალთ Outlook VBA რედაქტორის ფანჯარაში.
ამის შემდეგ, დააკოპირეთ და ჩასვით შემდეგი VBA კოდები ახალ მოდულში.

Public objNewPSTFolder As Outlook.Folder
 
Sub CopyFolderStructure()
    Dim objFolders As Outlook.Folders
    Dim objFolder As Outlook.Folder
 
    'Get the folders of the source Outlook PST file
    Set objFolders = Outlook.Application.Session.Folders("Personal").Folders
 
    'Create the new pst file in your desired local folder and name
    Outlook.Application.Session.AddStore "E:\New PST File.pst"
    Set objNewPSTFolder = Session.Folders.GetLast()
 
    For Each objFolder In objFolders
        CreateFolder objFolder
    Next
 
    MsgBox "Completed!", vbOKOnly + vbInformation, "Copy Folder Structure"
End Sub
 
Sub CreateFolder(objFolder As Outlook.Folder)
    Dim objSubFolder As Outlook.Folder
 
    'Only copy the mail folder
    If (objFolder.DefaultItemType = olMailItem) Then
       'New Outlook PST file auto includes the "Deleted Items" folder, so skip it
       'Skip the useless mail folders - "Conversation Action Settings" and "Quick Step Settings"
       If (objFolder.Name <> "Deleted Items") And (objFolder.Name <> "Conversation Action Settings") And (objFolder.Name <> "Quick Step Settings") Then
 
          'Create the new folder
          objNewPSTFolder.Folders.Add objFolder.Name
          Set objNewPSTFolder = objNewPSTFolder.Folders.Item(objFolder.Name)
 
          For Each objSubFolder In objFolder.Folders
              CreateFolder objSubFolder
          Next
 
          Set objNewPSTFolder = objNewPSTFolder.parent
       End If
    End If

End Sub

ამის შემდეგ, შეცვალეთ თქვენი მაკრო უსაფრთხოების დონე დაბალზე.
მოგვიანებით დაუბრუნდით VBA რედაქტორის ფანჯარას და დააჭირეთ ღილაკს "F5" მაკროს გასაშვებად.
დაბოლოს, მაკროს მუშაობის დასრულების შემდეგ, თქვენ მიიღებთ შეტყობინებას "დასრულებულია!".
ამ ეტაპზე, შეგიძლიათ გადახვიდეთ ფოსტის ნავიგაციის პანელზე. თქვენ დაინახავთ ახალ Outlook მონაცემთა ფაილს, რომელიც არის იმავე საქაღალდის სტრუქტურაში, როგორც წყაროს PST ფაილი, როგორც ქვემოთ მოცემული სურათი:

გაუმკლავდეთ PST პრობლემებს

იმის გამო, რომ Outlook PST არის შეცდომის მიდრეკილება, ბევრ თქვენგანს ოდესმე შეხვედრია სხვადასხვა პრობლემა Outlook-ში. მათთან პირისპირ, პირველ რიგში შეგიძლიათ გამოიყენოთ Outlook შემოსულების შეკეთების ინსტრუმენტი, რომ სცადოთ. თუ ის ვერ მოხერხდა, შეგიძლიათ გამოიყენოთ უფრო ძლიერი მესამე მხარის ინსტრუმენტი, როგორიცაა DataNumen Outlook Repair, რომელსაც შეუძლია Outlook-ის შესწორება PST შეცდომები, როგორც ნიავი.

ავტორი შესავალი:

შირლი ჟანგი არის მონაცემთა აღდგენის ექსპერტი DataNumen, Inc., რომელიც მსოფლიო ლიდერია მონაცემთა აღდგენის ტექნოლოგიებში, მათ შორის SQL Server დაფიქსირება და Outlook სარემონტო პროგრამული პროდუქტები. დამატებითი ინფორმაციისთვის ეწვიეთ www.datanumen. ერთად