როგორ სწრაფად მიამაგროთ ბოლო შეცვლილი ფაილი Windows საქაღალდეში თქვენს Outlook ელფოსტაზე

ზოგჯერ შეიძლება დაგჭირდეთ სწრაფად იპოვოთ და მიამაგროთ ბოლო შეცვლილი ფაილი კონკრეტულ Windows საქაღალდეში Outlook-ის ელფოსტაზე. ამ შემთხვევაში, შეგიძლიათ გამოიყენოთ ამ სტატიაში წარმოდგენილი მეთოდი.

ზოგიერთ მომხმარებელს სურს, რომ Outlook-მა სწრაფად იპოვოს და ელფოსტას დაურთოს Windows-ის საქაღალდეში ბოლო შეცვლილი ფაილი, მაგალითად, ბოლოს შექმნილი, შეცვლილი ან შენახული ფაილი. თუმცა, Outlook არ გვთავაზობს ასეთ პირდაპირ და მშობლიურ ფუნქციას. ამიტომ, ქვემოთ წარმოგიდგენთ VBA კოდის ნაწილს, რომელიც მის მარტივად რეალიზებას შეძლებს.

მიამაგრეთ ბოლო შეცვლილი ფაილი Windows საქაღალდეში ელფოსტაზე

1. თავიდანვე, თქვენ უნდა გაუშვათ თქვენი Outlook აპლიკაცია.
2. შემდეგ, Outlook-ის მთავარ ფანჯარაში შესვლის შემდეგ, შეგიძლიათ დააჭიროთ "Alt + F11" ღილაკებს.
3. შემდეგ თქვენ წარმატებით შეხვალთ Outlook VBA რედაქტორის ფანჯარაში.
4. შემდგომში, თქვენ უნდა იპოვოთ და გახსნათ მოდული, რომელიც არ გამოიყენება.
5. შემდეგ დააკოპირეთ და ჩასვით შემდეგი VBA კოდი ამ მოდულის ფანჯარაში.

Sub AttachLastModifiedSpecificFile()
    Dim objShell As Object
    Dim objSelectedFolder As Object
    Dim objFileSystem As Object
    Dim strSourceFolderPath As String
    Dim objSourceFolder As Object
    Dim objFile As Object
    Dim dLastModifiedDate As Date
    Dim strLastModifiedFilePath As String
    Dim objMail As Outlook.MailItem
 
    On Error GoTo ErrorHandler
    'Select a local source folder
    Set objShell = CreateObject("Shell.Application")
    Set objSelectedFolder = objShell.BrowseForFolder(0, "Select the source folder", 0, "")
    strSourceFolderPath = objSelectedFolder.self.Path
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objSourceFolder = objFileSystem.GetFolder(strSourceFolderPath)
 
    If objSourceFolder.Files.Count > 0 Then
       For Each objFile In objSourceFolder.Files
           'Find the last modified file within "xlsx" file type in the selected Windows folder
           If (objFile.DateLastModified > dLastModifiedDate) And (objFileSystem.GetExtensionName(objFile) = "xlsx") Then
              'You can add or change criteria, such as
              'Left(objFile.Name, 4) = "Test" ---> file whose name begins with "Test"
              '(objFile / 1024) / 1024 > 2 --> File exceeds 2 MB
              'Note: Use "And" to connect more than one criteria
              strLastModifiedFilePath = objFile.Path
              dLastModifiedDate = objFile.DateLastModified
           End If
       Next
 
       If strLastModifiedFilePath <> "" Then
          'Confirm attaching it to the current outlook email
          strMsg = "The last modified file in the " & Chr(34) & strSourceFolderPath & Chr(34) & " is: " & vbCrLf & vbCrLf & "File: " & strLastModifiedFilePath & vbCrLf & "Date: " & dLastModifiedDate & vbCrLf & vbCrLf & "Do you want to attach it?"
          nPrompt = MsgBox(strMsg, vbQuestion + vbYesNo, "Confirm Attaching Last Modified File")
 
          If nPrompt = vbYes Then
             Set objMail = Outlook.Application.ActiveInspector.CurrentItem
             objMail.Attachments.Add strLastModifiedFilePath
         End If
      Else
         MsgBox "No file in the selected folder can meet your predefined criteria!", vbExclamation + vbOKOnly
      End If
    Else
      MsgBox "No file exists in the selected Windows folder!", vbExclamation + vbOKOnly
    End If
 
ErrorHandler:
    Exit Sub
End Sub

6. ამის შემდეგ, შეგიძლიათ გახვიდეთ VBA რედაქტორის ფანჯრიდან და გააგრძელოთ ახალი მაკროს დამატება სწრაფი წვდომის ხელსაწყოთა ზოლში ან შეტყობინებების ფანჯრის ლენტზე.
7. მოგვიანებით თქვენ უნდა შეცვალოთ თქვენი Outlook მაკრო უსაფრთხოების დონე დაბალზე.
8. საბოლოოდ შეგიძლიათ სცადოთ.

• პირველ რიგში, შექმენით და შეადგინეთ ახალი Outlook ელფოსტა, როგორც ყოველთვის.
• შემდეგ დააჭირეთ მაკრო ღილაკს სწრაფი წვდომის ხელსაწყოთა ზოლში, როგორც ქვემოთ მოცემული სურათი:
• შემდეგ მოგიწევთ Windows-ის წყაროს საქაღალდის არჩევა და დააჭირეთ ღილაკს "OK".
• თუ Windows-ის არჩეულ საქაღალდეში არის ასეთი ფაილი, თქვენ მიიღებთ მოთხოვნას, როგორიცაა შემდეგი ეკრანის სურათი:
• როდესაც დააჭირეთ ღილაკს "დიახ", ეს ფაილი ერთდროულად მიმაგრდება.

მოაგვარეთ Outlook-ის პრობლემები რაც შეიძლება მალე

როდესაც Outlook-ის რაიმე პრობლემას წააწყდებით, რეკომენდებულია მათი მოგვარება რაც შეიძლება მალე. ამ სიტუაციაში, უმჯობესია მოამზადოთ ძლიერი Outlook შესწორება ინსტრუმენტი წინასწარ, როგორიცაა DataNumen Outlook Repair. მას შეუძლია PST შეცდომების გამოსწორება და თქვენი Outlook მონაცემების ეფექტურად გადარჩენა.

ავტორი შესავალი:

შირლი ჟანგი არის მონაცემთა აღდგენის ექსპერტი DataNumen, Inc., რომელიც მსოფლიო ლიდერია მონაცემთა აღდგენის ტექნოლოგიებში, მათ შორის დაზიანებული მდფ და Outlook სარემონტო პროგრამული პროდუქტები. დამატებითი ინფორმაციისთვის ეწვიეთ www.datanumen. ერთად