როგორ ჯგუფური კონვერტაცია და მიმაგრება მრავალი Word დოკუმენტის სახით PDF ფაილები Outlook ელფოსტაზე

მარტივია Word დოკუმენტის მიმაგრება, როგორც a PDF ფაილი Outlook-ის ელფოსტაზე. მიუხედავად ამისა, თუ გსურთ, დაურთოთ რამდენიმე Word დოკუმენტი, როგორც PDF ფაილი ელექტრონული ფოსტით, შეგიძლიათ წაიკითხოთ ეს სტატია. აქ ჩვენ გაჩვენებთ ჯგუფური მიღების მეთოდს.

Word დოკუმენტის მიმაგრება როგორც PDF შეიტანეთ Outlook ელფოსტაზე, შეგიძლიათ ჯერ გახსნათ Word დოკუმენტი და გადახვიდეთ მენიუში "ფაილი". შემდეგ, შეგიძლიათ გადახვიდეთ „შენახვა და გაგზავნა“ ჩანართზე, რომელზეც არის „გაგზავნა როგორც PDF” ღილაკი, როგორც შემდეგი ეკრანის სურათი.

ამრიგად, საკმაოდ მარტივია Word დოკუმენტის მიმაგრება, როგორც PDF მეილზე. მაგრამ, თუ გსურთ გადაიყვანოთ და დაურთოთ მრავალი Word დოკუმენტი, როგორც PDF ფაილები ფოსტაზე, უმჯობესია გამოიყენოთ შემდეგი გზა. მას შეუძლია მოგცეთ ამის სრულყოფილად შესრულება.

Batch Convert & Attach Multiple Word Document as PDF ფაილები ელფოსტაზე

1. როგორცtart, შეაგროვეთ Word დოკუმენტები, რომლებიც გსურთ იმავე Windows საქაღალდეში.
2. შემდეგ გაუშვით Outlook პროგრამა.
3. შემდეგი, დააკოპირეთ შემდეგი კოდი გამოუყენებელ პროექტში ან მოდულში.

Dim objMail As Outlook.MailItem

Sub BatchAttachMultipleWordDocumentsAsPDFToEmail()
    Dim objShell As Object
    Dim objWindowsFolder As Object
    Dim strWindowsFolder As String

    Set objMail = Outlook.Application.CreateItem(olMailItem)

    'Select the specific Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows folder:", 0, "")

    If Not objWindowsFolder Is Nothing Then
       strWindowsFolder = objWindowsFolder.self.Path & "\"

       Call ProcessFolders(strWindowsFolder)

       objMail.Display
    End If
End Sub

Sub ProcessFolders(strPath As String)
    Dim objFileSystem As Object
    Dim objFolder As Object
    Dim objFile As Object
    Dim objWordApp As Word.Application
    Dim objWordDocument As Word.Document
    Dim strDocumentName As String
    Dim strPDF As String

    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objFolder = objFileSystem.GetFolder(strPath)

    For Each objFile In objFolder.Files
        strFileExtension = objFileSystem.GetExtensionName(objFile)
        If LCase(strFileExtension) = "doc" Or LCase(strFileExtension) = "docx" Then
           Set objWordApp = CreateObject("Word.Application")
           Set objWordDocument = objWordApp.Documents.Open(objFile.Path)

           'Convert document to pdf
           strDocumentName = Left(objWordDocument.Name, (Len(objWordDocument.Name) - Len(strFileExtension)) - 1)
           strPDF = strPath & strDocumentName & ".pdf"
           objWordDocument.ExportAsFixedFormat strPDF, wdExportFormatPDF

           objWordDocument.Close False

           'Attach the pdf to email
           objMail.Attachments.Add strPDF

           Kill strPDF
        End If
    Next

    'Process all folders and subfolders
    If objFolder.SubFolders.Count > 0 Then
       For Each objSubfolder In objFolder.SubFolders
           If ((objSubfolder.Attributes And 2) = 0) And ((objSubfolder.Attributes And 4) = 0) Then
              ProcessFolders (objSubfolder.Path)
           End If
       Next
    End If
End Sub

4. ამის შემდეგ გადაიტანეთ კურსორი პირველ ქვეპროგრამაში.
5. ამის შემდეგ, დააჭირეთ "F5" ამ მაკროს დაუყოვნებლივ გასაშვებად.
6. ამომხტარი პატარა დიალოგური ფანჯარაში აირჩიეთ Windows საქაღალდე, სადაც ინახება წყარო Word დოკუმენტები.
7. ერთდროულად შეიქმნება ახალი ელ.წერილი, რომელშიც შეგიძლიათ იხილოთ მიმაგრებული PDF ფაილები, როგორიცაა შემდეგი ეკრანიost.

აწუხებს Outlook-ის პრობლემები

გაწუხებთ Outlook-ის სხვადასხვა პრობლემები? მაგალითად, Outlook ხშირად ჩერდება „არ პასუხობს“ მდგომარეობაში ან Outlook PST ფაილი მიუწვდომელი ხდება და ა.შ. ზოგადად, შეგიძლიათ ჯერ სცადოთ შემოსულების შეკეთების ინსტრუმენტი, სკანპსტი, PST საკითხების მოსაგვარებლად. თუმცა, ზოგჯერ პრობლემები შეიძლება აღემატებოდეს იმას, რაც ჩაშენებულ ხელსაწყოს შეუძლია. ამიტომ, თქვენ ჯობია შეინახოთ უფრო ძლიერი გარე უტილიტა სიახლოვეს, როგორიცაა DataNumen Outlook Repair.

ავტორი შესავალი:

შირლი ჟანგი არის მონაცემთა აღდგენის ექსპერტი DataNumen, Inc., რომელიც მსოფლიო ლიდერია მონაცემთა აღდგენის ტექნოლოგიებში, მათ შორის sql შეკეთება და Outlook სარემონტო პროგრამული პროდუქტები. დამატებითი ინფორმაციისთვის ეწვიეთ www.datanumen. ერთად