როგორ ჯგუფურად შეინახოთ მრავალი Draft ელფოსტა Outlook-ის შაბლონებად

შესაძლოა, თქვენ შექმენით რამდენიმე პროექტი ელ.წერილი და იმედი გაქვთ, რომ ხელახლა გამოიყენებთ მათ ბევრჯერ. თუ ასეა, რატომ არ ინახავთ მათ ჯგუფურად Outlook-ის შაბლონებად? ეს სტატია გასწავლით ამის გაკეთებას ერთი ნაბიჯით VBA-ს საშუალებით.

ნაგულისხმევად, Outlook საშუალებას აძლევს მომხმარებლებს შეინახონ ერთი ელფოსტა ერთდროულად შაბლონად. სხვა სიტყვებით რომ ვთქვათ, თქვენ არ შეგიძლიათ შეინახოთ მრავალი პროექტი ელ.წერილი შაბლონებად. როგორც ხედავთ, როდესაც ირჩევთ ერთზე მეტ ფოსტას და გადადით "ფაილი" > "შენახვა როგორც", ვერ იპოვით "Outlook შაბლონს" ფორმატს "შენახვა როგორც ტიპის" სიაში, ხელმისაწვდომია მხოლოდ "მხოლოდ ტექსტი". მაგრამ, ჩვენ გაგაცნობთ, თუ როგორ უნდა მოხდეს მისი ნაყარი რეალიზება შემდეგში.

ჯგუფური შენახვა მრავალი Draft ელ.წერილი Outlook-ის შაბლონებად

1. თავიდანვე ჩართეთ Outlook VBA რედაქტორი.
2. ახალ "Microsoft Visual Basic აპლიკაციებისთვის" ფანჯარაში დააკოპირეთ და ჩასვით ქვემოთ მოცემული VBA კოდი.

Sub SaveMultipleDraftsAsTemplates()
    Dim objSelection As Outlook.Selection
    Dim i As Long
    Dim strTemplateFolder As String
    Dim objMail As Outlook.MailItem
    Dim strSubject As String
 
    'Get all selected mails
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
 
    If Not (objSelection Is Nothing) Then
       'Get the default folder for saving Outlook Templates
       strTemplateFolder = CStr(Environ("USERPROFILE")) & "\Documents\UserTemplates\"
 
       'Save each mail as template
       For i = objSelection.Count To 1 Step -1
           If objSelection(i).Class = olMail Then
              Set objMail = objSelection(i)
              If objMail.Subject <> "" Then
 
                 'Remove unsupported characters
                 strSubject = objMail.Subject
                 strSubject = Replace(strSubject, "/", " ")
                 strSubject = Replace(strSubject, "\", " ")
                 strSubject = Replace(strSubject, ":", "")
                 strSubject = Replace(strSubject, "?", " ")
                 strSubject = Replace(strSubject, Chr(34), " ")
 
                 objMail.SaveAs strTemplateFolder & strSubject & ".oft", olTemplate
              Else
                 objMail.SaveAs strTemplateFolder & "Template" & i & ".oft", olTemplate
              End If
           End If
       Next
 
       'Open the folder of Templates
       Shell "Explorer.exe" & " " & strTemplateFolder, vbNormalFocus
    End If
End Sub

3. ამის შემდეგ, შემდგომი მოხერხებულობისთვის, რეკომენდებულია ამ მაკროს მიმაგრება Quick Access Toolbar-ზე (QAT). დეტალური ნაბიჯების შესახებ შეგიძლიათ წაიკითხოთ "როგორ გაუშვათ VBA კოდი თქვენს Outlook-ში"
4. საბოლოო ჯამში, თქვენ შეგიძლიათ გადაიღოთ ქვემოთ მოცემული ოპერაციების შემდეგ.

• თავდაპირველად აირჩიეთ ელ.ფოსტის მონახაზი შაბლონებად შესანახად.
• შემდეგ დააჭირეთ მაკრო ღილაკს QAT-ში.
• როდესაც მაკრო დასრულდება, გამოჩნდება Windows საქაღალდე ნაგულისხმევი Outlook შაბლონების შესანახად. თქვენ ხედავთ, რომ შაბლონები არჩეული ელფოსტის პროექტებიდან არის იქ.

შემოსულების სარემონტო ხელსაწყო მაინც შეიძლება ვერ მოხერხდეს

რაც შეეხება შიდა Outlook-ის გამოსწორების ინსტრუმენტს – Scanpst, მომხმარებელთა დიდი რაოდენობა დააფასებს მას. ეჭვგარეშეა, ამ პროგრამას ნამდვილად შეუძლია Outlook-ში არსებული მცირე პრობლემების უმეტესობის გადაჭრა. თუმცა, ეს არ არის სრულიად უზადო. ის მაინც შეიძლება წარუმატებელი იყოს და გამოიწვიოს მრავალი შეცდომა. მაგალითად, მძიმე შემთხვევებში პერსპექტიული კორუფცია, მას არ შეუძლია გაფუჭებული PST ფაილის შეკეთება. ამ სცენარში, თქვენ არ გაქვთ ალტერნატივა, გარდა იმისა, რომ გამოიყენოთ უფრო ძლიერი და საუკეთესო მესამე მხარის ინსტრუმენტი, როგორიცაა DataNumen Outlook Repair.

ავტორი შესავალი:

შირლი ჟანგი არის მონაცემთა აღდგენის ექსპერტი DataNumen, Inc., რომელიც მსოფლიო ლიდერია მონაცემთა აღდგენის ტექნოლოგიებში, მათ შორის sql აღდგენა და Outlook სარემონტო პროგრამული პროდუქტები. დამატებითი ინფორმაციისთვის ეწვიეთ www.datanumen. ერთად