როგორ გავაუქმოთ ყველა Outlook-ის შეხვედრები, რომლებიც დაგეგმილია თარიღის კონკრეტულ დიაპაზონში

თუ გსურთ გააუქმოთ ყველა შეხვედრები, რომლებიც დაგეგმილია თარიღის კონკრეტულ დიაპაზონში თქვენს Outlook-ში, შეგიძლიათ გამოიყენოთ ამ სტატიაში წარმოდგენილი საშუალებები. მას შეუძლია დაგახსნას ასეთი შეხვედრების ხელით ძიება და გაუქმება.

თუ რაიმე მიზეზის გამო ვერ შეძლებთ შეხვედრების ორგანიზებას ან მონაწილეობას, რომლებიც ჩატარდება თარიღის გარკვეულ დიაპაზონში, შეიძლება გსურდეთ გააუქმოთ ყველა ასეთი შეხვედრა. საერთოდ, ჯერ უნდა გაარკვიო და მერე სათითაოდ გააუქმო. საკმაოდ პრობლემური იქნება. ამიტომ, შემდგომში გაგიზიარებთ სხვა გზას, რომელიც ბევრად უფრო მოსახერხებელია.

ჯგუფურად გააუქმეთ ყველა შეხვედრები, რომლებიც დაგეგმილია თარიღის კონკრეტულ დიაპაზონში

1. დასაწყისშივე, გაუშვით თქვენი Outlook პროგრამა.
2. შემდეგ, Outlook-ში, თქვენ უნდა დააჭიროთ "Alt + F11" ღილაკებს.
3. შემდეგი, თქვენ მოხვდებით "Microsoft Visual Basic აპლიკაციებისთვის" ფანჯარაში.
4. ამ ფანჯარაში უნდა გახსნათ გამოუყენებელი მოდული ან უბრალოდ ჩასვათ ახალი.
5. შემდგომში, შეგიძლიათ დააკოპიროთ შემდეგი VBA კოდი ამ მოდულში.

Sub BatchCancelAllMeetingsInSpecificDateRange()
    Dim dStartDate As Date
    Dim dEndDate As Date
    Dim objCalendarFolder As Outlook.folder
    Dim objItems As Outlook.Items
    Dim objItemsInDateRange As Outlook.Items
    Dim objAppointment As Outlook.AppointmentItem
    Dim objResponse As Outlook.MeetingItem
 
    'Specify the start date and end date
    dStartDate = InputBox("Enter the start date:", , "10/1/2017")
    dEndDate = InputBox("Enter the end date:", , "10/8/2017")
 
    If dStartDate <> #1/1/4501# And dEndDate <> #1/1/4501# Then
       'Select a calendar folder
       Set objCalendarFolder = Outlook.Application.Session.PickFolder
       Set objItems = objCalendarFolder.Items
       objItems.IncludeRecurrences = True
       objItems.Sort "[Start]"
 
       'Get the appointments in the specific date range
       strFilter = "[Start] >= " & Chr(34) & dStartDate & " 00:00 AM" & Chr(34) & " AND [End] <= " & Chr(34) & dEndDate & " 11:59 PM" & Chr(34)
       Set objItemsInDateRange = objItems.Restrict(strFilter)
 
       objItemsInDateRange.Sort "[Start]"
       For Each objAppointment In objItemsInDateRange
           'Cancel the meetings in this date range
           If objAppointment.MeetingStatus = olMeeting Then
              If objAppointment.Organizer = Outlook.Session.CurrentUser Then
                 objAppointment.MeetingStatus = olMeetingCanceled
                 objAppointment.Save
                 objAppointment.Send
                 objAppointment.Delete
              Else
                 Set objResponse = objAppointment.Respond(olMeetingDeclined)
                 objResponse.Send
                 objAppointment.Delete
              End If
            End If
       Next
    End If
End Sub

6. საბოლოოდ, თქვენ ახლავე შეგეძლოთ ამ მაკროს გაშვება.

• მიმდინარე მაკრო ფანჯარაში დააჭირეთ ღილაკს "F5".
• შემდეგი, თქვენ მოგიწევთ მიუთითოთ თარიღის დიაპაზონი.
• ამის შემდეგ, გამოჩნდება სხვა დიალოგური ფანჯარა, რომელიც მოითხოვს, აირჩიოთ წყარო კალენდრის საქაღალდე და დააწკაპუნოთ "OK".
• და ბოლოს, როდესაც მაკრო დასრულდება, შეგიძლიათ ნახოთ, რომ ყველა შეხვედრა გაუქმდა თარიღის კონკრეტულ დიაპაზონში.
• "გაგზავნილი ნივთების" საქაღალდეში შეგიძლიათ იპოვოთ შეხვედრის გაუქმება, როგორც ქვემოთ მოცემული ეკრანის სურათი:

Outlook-ის შეცდომების გამოსწორება

თუ თქვენ იყენებდით Outlook-ს ათწლეულების განმავლობაში, აუცილებლად შეგხვედრიათ რამდენიმე შეცდომა. საბედნიეროდ Outlook აღჭურვილია ჩაშენებული სარემონტო ხელსაწყოთი - Scanpst. თქვენ შეგიძლიათ გამოიყენოთ იგი Outlook-ის შესწორება შეცდომები. თუმცა, თუ ის ვერ მოხერხდა, თქვენი უკანასკნელი გამოსავალი არის გარე შეკეთების ხელსაწყოები, როგორიცაა DataNumen Outlook Repairმას შეუძლია Outlook ფაილის სკანირება და შეცდომების უმეტესობის გამოსწორება, ასევე დაზიანებული Outlook მონაცემების მარტივად აღდგენა.

ავტორი შესავალი:

შირლი ჟანგი არის მონაცემთა აღდგენის ექსპერტი DataNumen, Inc., რომელიც მსოფლიო ლიდერია მონაცემთა აღდგენის ტექნოლოგიებში, მათ შორის გაასწორე sql და Outlook სარემონტო პროგრამული პროდუქტები. დამატებითი ინფორმაციისთვის ეწვიეთ www.datanumen. ერთად