როგორ ავტომატურად დააყენოთ Outlook ონლაინ ან ხაზგარეშე თქვენი სამუშაო საათების მიხედვით

ზოგიერთ მომხმარებელს სურს Outlook-ს ავტომატური გადართვა ონლაინ და ოფლაინ სტატუსებს შორის სამუშაო საათებიდან გამომდინარე. ასე რომ, ამ სტატიაში ჩვენ გაგიზიარებთ სწრაფ მეთოდს.

სინამდვილეში, Outlook-ის ონლაინ ან ოფლაინ დაყენება ძალიან მარტივია. Outlook-ის ოფლაინ სტატუსად გადაქცევისთვის, შეგიძლიათ უბრალოდ გადახვიდეთ „გაგზავნა/მიღება“ ჩანართზე და დააჭიროთ ღილაკს „მუშაობა ოფლაინში“. და ონლაინ სტატუსზე დასაბრუნებლად, უბრალოდ კვლავ დააჭირეთ ამ ღილაკს. თუმცა, ზოგიერთი მომხმარებელი იმედოვნებს, რომ Outlook-ს შეუძლია ავტომატურად გადაერთოს ოფლაინ სტატუსზე, როდესაც ის სამუშაო საათების ამოწურულია და სამუშაო საათებში დაუბრუნდეს ონლაინ რეჟიმში. მიუხედავად იმისა, რომ Outlook არ იძლევა ასეთ ფუნქციას, თქვენ მაინც შეგიძლიათ გამოიყენოთ შემდეგი VBA კოდი მის მისაღწევად.

ავტომატური დაყენება Outlook ონლაინ ან ხაზგარეშე თქვენი სამუშაო საათების მიხედვით

1. დასაწყისისთვის, გაუშვით თქვენი Outlook აპლიკაცია.
2. შემდეგ, თქვენს Outlook-ზე წვდომის მიღების შემდეგ, თქვენ უნდა გახსნათ თქვენი Tasks საქაღალდე.
3. შემდეგ თქვენ უნდა შექმნათ ყოველდღიური განმეორებადი დავალების ელემენტი.

• დააჭირეთ ღილაკს "ახალი დავალება" ლენტით.
• შემდეგ შეიყვანეთ „Offline“ ამოცანის თემის ველში.
• შემდეგ დააჭირეთ ღილაკს "განმეორება" ჩანართზე "დავალება".
• ამომხტარ დიალოგურ ფანჯარაში აირჩიეთ "ყოველდღიური" განმეორების ნიმუში, ჩართეთ "არ არის დასრულების თარიღი" და დააჭირეთ "OK".
• შემდეგ თქვენ უნდა ჩართოთ შეხსენება „5:00 PM“.
• ბოლოს დააჭირეთ ღილაკს "შენახვა და დახურვა".

4. შემდგომში, თქვენ უნდა შექმნათ კიდევ ერთი ყოველდღიური განმეორებადი დავალება სახელწოდებით „ონლაინ“ და ჩართოთ შეხსენება „8:00 AM“-ზე, ნაჩვენებია როგორც ქვემოთ მოცემული სურათი:
5. ამის შემდეგ, Outlook-ის მთავარ ფანჯარაში დააჭირეთ ღილაკს "Alt + F11".
6. შემდეგ თქვენ მიიღებთ წვდომას Outlook VBA რედაქტორზე, რომელშიც უნდა იპოვოთ და გახსნათ პროექტი "ThisOutlookSession".
7. მოგვიანებით დააკოპირეთ შემდეგი VBA კოდი ამ პროექტში.

Dim objNameSpace As Outlook.NameSpace

'Set Online/Offline Status on Outlook Startup
Private Sub Application_Startup()
    Set objNameSpace = Application.GetNamespace("MAPI")
 
    'If now is before 8:00 AM or after 5:00 PM on Outlook startup
    If Now() < DateSerial(Year(Now), Month(Now), Day(Now)) + #8:00:00 AM# Or Now() > DateSerial(Year(Now), Month(Now), Day(Now)) + #5:00:00 PM# Then
 
       'If Outlook is online
       If objNameSpace.Offline = False Then
          'set it offline
          ActiveExplorer().CommandBars.FindControl(, 5613).Execute
       End If
 
       'If now is between 8:00 AM and 5:00 PM
    Else
 
       'If Outlook is offline
       If objNameSpace.Offline = True Then
          'Set it online
          ActiveExplorer().CommandBars.FindControl(, 5613).Execute
       End If
    End If
End Sub

'Change Online/Offline Status at Specific Time
Private Sub Application_Reminder(ByVal Item As Object)
    Dim objOfflineTask As Outlook.TaskItem
    Dim objOnlineTask As Outlook.TaskItem
 
    Set objNameSpace = Application.GetNamespace("MAPI")
 
    If TypeOf Item Is TaskItem Then
       If Item.Subject = "Offline" Then
          Set objOfflineTask = Item
 
          'If Outlook is online when "Offline" task reminder alerts
          If objNameSpace.Offline = False Then
             'Set Outlook offline
             ActiveExplorer().CommandBars.FindControl(, 5613).Execute
          End If
 
          'Clear the reminder by marking task complete
          objOfflineTask.MarkComplete
 
       ElseIf Item.Subject = "Online" Then
          Set objOnlineTask = Item
 
          'If Outlook is offline when "Online" task reminder alerts
          If objNameSpace.Offline = True Then
             'Set Outlook online
             ActiveExplorer().CommandBars.FindControl(, 5613).Execute
          End If
 
          objOnlineTask.MarkComplete
 
       End If
    End If
End Sub

8. საბოლოოდ, ამ მაკროს გასააქტიურებლად შეგიძლიათ გადატვირთოთ Outlook.
9. ამიერიდან, თქვენი Outlook იქნება ონლაინ სამუშაო საათებში და ავტომატურად გადაერთვება ოფლაინ სტატუსზე სამუშაო საათების მიღმა.

თქვენი ბოლო კურორტი Outlook-ის ავარიის შემთხვევაში

მიუხედავად იმისა, რომ Outlook ამაყობს მრავალი ფუნქციით, Outlook მაინც ვერ იკავებს შეცდომებს და დაზიანებას. მაგრამ ნუ პანიკა. სანამ საკმარის სიფრთხილის ზომებს მიიღებთ, მაინც შეძლებთ თქვენი Outlook მონაცემების ეფექტურად დაცვას. მაგალითად, რეგულარულად უნდა შექმნათ თქვენი PST ფაილების სარეზერვო ასლი, რადგან სარეზერვო ასლები საშუალებას მოგცემთ დაბრუნდეთ კორუმპირებული PST მონაცემები. ასევე, ძლიერი სარემონტო ხელსაწყოს შენახვა, როგორიცაა DataNumen Outlook Repair, ასევე აუცილებლობის საკითხია.

ავტორი შესავალი:

შირლი ჟანგი არის მონაცემთა აღდგენის ექსპერტი DataNumen, Inc., რომელიც მსოფლიო ლიდერია მონაცემთა აღდგენის ტექნოლოგიებში, მათ შორის მდფ-ის შეკეთება და Outlook სარემონტო პროგრამული პროდუქტები. დამატებითი ინფორმაციისთვის ეწვიეთ www.datanumen. ერთად