როგორ ავტომატურად ჩაწეროთ ყოველდღიურად შემომავალი ელ.ფოსტის საერთო რაოდენობა Excel ფაილში

ეს სტატია გასწავლით თუ როგორ უნდა მისცეთ Outlook-ს ავტომატურად დათვლას რამდენი ელ.წერილი მიიღეთ ყოველდღე და ჩაწეროთ ნომერი Excel ფაილში.

ბევრ მომხმარებელს მოეთხოვება დათვალოს ყოველდღიურად მიღებული ელ.წერილების საერთო რაოდენობა. გარდა ამისა, მომავალში უფრო მოსახერხებელი შემოწმებისთვის, ბევრი მიჩვეულია მთლიანი რაოდენობის ჩაწერას Excel ფაილში. ამ შემთხვევაში, რა თქმა უნდა, შეგიძლიათ აირჩიოთ ხელით დათვლა და ჩაწერა ყოველდღე. თუმცა, ეს ცოტა პრობლემურია. და შეიძლება ზოგჯერ დაგავიწყდეს ამის გაკეთება. ამიტომ, თქვენ უნდა მოისურვოთ მოსახერხებელი მეთოდი, რომელიც Outlook-ს ავტომატურად გააკეთებს. ამ მოთხოვნის საპასუხოდ, ჩვენ გასწავლით, თუ როგორ გამოიყენოთ VBA მის გასაცნობად შემდეგში.

ავტომატური ჩაწერა ყოველდღიურად შემომავალი ელ.წერილების რაოდენობა Excel ფაილში

1. თავიდანვე გაუშვით თქვენი Outlook აპლიკაცია.
2. შემდეგ დააჭირეთ "Alt + F11" კლავიშების მალსახმობებს Outlook-ის მთავარ ფანჯარაში.
3. შემდეგ VBA რედაქტორის ფანჯარაში გახსენით პროექტი "ThisOutlookSession".
4. ამის შემდეგ, დააკოპირეთ და ჩასვით შემდეგი VBA კოდები ამ პროექტში.

Private Sub Application_Reminder(ByVal Item As Object)
    If Item.Class = olTask And Item.Subject = "Update Email Count" Then
       Call GetAllInboxFolders
    End If
End Sub

Private Sub GetAllInboxFolders()
    Dim objInboxFolder As Outlook.Folder
    Dim strExcelFile As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim nNextEmptyRow As Integer
    Dim lEmailCount As Long
 
    lEmailCount = 0
    Set objInboxFolder = Outlook.Application.Session.GetDefaultFolder(olFolderInbox)
    Call UpdateEmailCount(objInboxFolder, lEmailCount)
 
    ‘Change the path to the Excel file
    strExcelFile = "E:\Email\Email Count.xlsx"
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Open(strExcelFile)
    Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
 
    nNextEmptyRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
 
    'Add the values into the columns
    objExcelWorksheet.Range("A" & nNextEmptyRow) = nNextEmptyRow - 1
    objExcelWorksheet.Range("B" & nNextEmptyRow) = Year(Date - 1) & "-" & Month(Date - 1) & "-" & Day(Date - 1)
    objExcelWorksheet.Range("C" & nNextEmptyRow) = lEmailCount
 
    'Fit the columns from A to C
    objExcelWorksheet.Columns("A:C").AutoFit
   
    'Save the changes and close the Excel file
    objExcelWorkbook.Close SaveChanges:=True
End Sub

Private Sub UpdateEmailCount(objFolder As Outlook.Folder, ByRef lCurEmailCount As Long)
    Dim objItems As Outlook.Items
    Dim objItem As Object
    Dim objMail As Outlook.MailItem
    Dim strDay As String
    Dim strReceivedDate As String
    Dim lEmailCount As Long
    Dim objSubFolder As Outlook.Folder
 
    Set objItems = objFolder.Items
 
    objItems.SetColumns ("ReceivedTime")
    strDay = Year(Date - 1) & "-" & Month(Date - 1) & "-" & Day(Date - 1)
 
    For Each objItem In objItems
        If objItem.Class = olMail Then
           Set objMail = objItem
           strReceivedDate = Year(objMail.ReceivedTime) & "-" & Month(objMail.ReceivedTime) & "-" & Day(objMail.ReceivedTime)
           If strReceivedDate = strDay Then
              lCurEmailCount = lCurEmailCount + 1
           End If
        End If
    Next
 
    'Process the subfolders in the folder recursively
    If (objFolder.Folders.Count > 0) Then
       For Each objSubFolder In objFolder.Folders
           Call UpdateEmailCount(objSubFolder, lCurEmailCount)
       Next
    End If
End Sub

5. შემდეგი, მოაწერეთ ხელი ამ კოდს და შეცვალეთ თქვენი Outlook მაკრო პარამეტრები, რათა დაუშვას ხელმოწერილი მაკროები.
6. ამის შემდეგ, თქვენ უნდა შექმნათ განმეორებადი დავალება ყოველდღიურად.

• უპირველეს ყოვლისა, დააწკაპუნეთ ღილაკზე "ახალი დავალება" ამოცანების პანელში.
• ახალი ამოცანის ფანჯარაში დააჭირეთ ღილაკს "განმეორება".
• შემდეგ დიალოგურ ფანჯარაში აირჩიეთ „ყოველდღიურად“, „ყოველ 1 დღეში“ და „დასრულების თარიღი არ არის“ და ბოლოს დააჭირეთ „OK“.
• მოგვიანებით შეცვალეთ დავალების თემა და შეხსენება თქვენი საჭიროების მიხედვით.
• საბოლოოდ დააჭირეთ ღილაკს "შენახვა და დახურვა".

7. ამიერიდან, ყოველ ჯერზე, როცა ამ ამოცანის შეხსენება გაფრთხილდება, Outlook ავტომატურად დათვლის გუშინ მიღებულ წერილებს და შემდეგ ჩაიწერს ნომერს Excel ფაილში, როგორც შემდეგი ეკრანის სურათი:

გაქცევა PST მონაცემთა მუდმივი დაკარგვისგან

არავის სურს მიიღოს PST მონაცემთა მუდმივი დაკარგვა. თუმცა, Outlook PST ფაილი მიდრეკილია კორუფციისკენ. ამიტომ, თქვენ უნდა მიიღოთ საკმარისი სიფრთხილის ზომები, როგორიცაა თანმიმდევრული და განახლებული PST მონაცემების სარეზერვო ასლის შექმნა და მძლავრი ინფორმაციის შენარჩუნება. PST აღდგენა ინსტრუმენტი სიახლოვეს, როგორიცაა DataNumen Outlook Repair.

ავტორი შესავალი:

შირლი ჟანგი არის მონაცემთა აღდგენის ექსპერტი DataNumen, Inc., რომელიც მსოფლიო ლიდერია მონაცემთა აღდგენის ტექნოლოგიებში, მათ შორის sql შეკეთება და Outlook სარემონტო პროგრამული პროდუქტები. დამატებითი ინფორმაციისთვის ეწვიეთ www.datanumen. ერთად