როგორ მოხდეს შემომავალი ელ.ფოსტის ინფორმაციის ავტომატური ექსპორტი Excel ფაილში Outlook VBA-ით

ბევრი მომხმარებელი იმედოვნებს, რომ Outlook-ს შეუძლია ავტომატურად ექსპორტი მოახდინოს შემომავალი ელ.ფოსტის პირველადი ინფორმაციის Excel ფაილში. ეს სტატია განიხილავს ამ მოთხოვნას და შემოგთავაზებთ სწრაფ მეთოდს Outlook VBA-ის საშუალებით.

ზოგჯერ, გარკვეული მიზეზების გამო, როგორიცაა ფოსტის სტატისტიკა, შეიძლება ხშირად დაგჭირდეთ ელფოსტის ექსპორტი Excel ფაილში. ზოგადად, არსებული მიღებული ელფოსტისთვის, თქვენ შეგიძლიათ უბრალოდ გამოიყენოთ „იმპორტი და ექსპორტი“ ფუნქცია, რათა ექსპორტი მოხდეს Excel-ში ერთი ნაბიჯით. თუმცა, შესაძლოა თქვენც კი გინდოდეთ, რომ Outlook-მა შეძლოს შემომავალი წერილების ავტომატური ექსპორტი Excel-ში, როგორც კი ისინი თქვენს საფოსტო ყუთში მოხვდებიან. ყოველგვარი ეჭვის გარეშე, Outlook-ში ასეთი მშობლიური ფუნქცია არ არის. ამიტომ, თქვენ უნდა გამოიყენოთ სხვა მიდგომები, როგორიცაა მესამე მხარის დანამატი ან Outlook VBA. აქ ჩვენ გასწავლით თუ როგორ უნდა გახადოთ ის ავტომატიზირებული Outlook VBA-ით. წაიკითხეთ, რომ მიიღოთ ნაბიჯები და კოდების მიხედვით.

შემომავალი წერილების ინფორმაციის ავტომატური ექსპორტი Excel ფაილში

1. პირველ რიგში, თქვენ უნდა შექმნათ Excel ფაილი.

• გახსენით ახალი Excel ფაილი.
• შემდეგ თქვენ უნდა აკრიფოთ "არა". უჯრედში A1, „გამომგზავნის სახელი“ უჯრედში B1, „გამგზავნის ელფოსტის მისამართი“ უჯრედში C1 და „ელფოსტის თემა“ უჯრედში D1 და „მიღების დრო“ უჯრედში E1, როგორც შემდეგი სურათი.
• ბოლოს შეინახეთ თქვენთვის სასურველ სახელსა და სასურველ საქაღალდეში.

2. ამის შემდეგ, თქვენ უნდა გაუშვათ Outlook.
3. შემდეგ დააჭირეთ "Alt + F11" ღილაკებს, რომლებიც მიგიყვანთ VBA რედაქტორში.
4. შემდეგი, ამომხტარ ფანჯარაში, ორჯერ უნდა დააჭიროთ "ThisOutlookSession" მარცხენა მხარეს.
5. შემდგომში, „ThisOutlookSession“ პროექტის ფანჯარაში, თქვენ უნდა დააკოპიროთ და ჩასვათ მასში შემდეგი VBA კოდები.

Public WithEvents objMails As Outlook.Items

Private Sub Application_Startup()
    Set objMails = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Private Sub objMails_ItemAdd(ByVal Item As Object)
    Dim objMail As Outlook.MailItem
    Dim strExcelFile As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkBook As Excel.Workbook
    Dim objExcelWorkSheet As Excel.Worksheet
    Dim nNextEmptyRow As Integer
    Dim strColumnB As String
    Dim strColumnC As String
    Dim strColumnD As String
    Dim strColumnE As String

    If Item.Class = olMail Then
       Set objMail = Item
    End If
 
    'Specify the Excel file which you want to auto export the email list
    'You can change it as per your case
    strExcelFile = "E:\Email\Email Statistics.xlsx"
 
    'Get Access to the Excel file
    On Error Resume Next
    Set objExcelApp = GetObject(, "Excel.Application")
    If Error <> 0 Then
       Set objExcelApp = CreateObject("Excel.Application")
    End If
    Set objExcelWorkBook = objExcelApp.Workbooks.Open(strExcelFile)
    Set objExcelWorkSheet = objExcelWorkBook.Sheets("Sheet1")
 
    'Get the next empty row in the Excel worksheet
    nNextEmptyRow = objExcelWorkSheet.Range("B" & objExcelWorkSheet.Rows.Count).End(xlUp).Row + 1
 
    'Specify the corresponding values in the different columns
    strColumnB = objMail.SenderName
    strColumnC = objMail.SenderEmailAddress
    strColumnD = objMail.Subject
    strColumnE = objMail.ReceivedTime
 
    'Add the vaules into the columns
    objExcelWorkSheet.Range("A" & nNextEmptyRow) = nNextEmptyRow - 1
    objExcelWorkSheet.Range("B" & nNextEmptyRow) = strColumnB
    objExcelWorkSheet.Range("C" & nNextEmptyRow) = strColumnC
    objExcelWorkSheet.Range("D" & nNextEmptyRow) = strColumnD
    objExcelWorkSheet.Range("E" & nNextEmptyRow) = strColumnE
 
    'Fit the columns from A to E
    objExcelWorkSheet.Columns("A:E").AutoFit
 
    'Save the changes and close the Excel file
    objExcelWorkBook.Close SaveChanges:=True
End Sub

6. მოგვიანებით თქვენ უნდა მოაწეროთ ხელი ამ კოდს.
7. შემდგომში რეზtart Outlook ახალი VBA პროექტის გასააქტიურებლად.
8. საბოლოოდ, ამიერიდან, ყველა შემომავალი ელფოსტა ავტომატურად იქნება ექსპორტირებული წინასწარ დაყენებულ Excel ფაილში, როგორც კი ისინი მოხვდებიან თქვენს Inbox საქაღალდეში. Excel ფაილი გამოიყურება შემდეგ სურათზე:

თავიდან აიცილოთ მტკივნეული PST მონაცემთა კორუფცია

Outlook-მა დიდი პოპულარობა მოიპოვა თავისი სხვადასხვა მახასიათებლების გამო. თუმცა, ეს არ ნიშნავს, რომ ეს უგუნურია. ის მაინც ნებისმიერ დროს შეიძლება კომპრომეტირებული იყოს. მაგალითად, თუ ხშირად ხურავთ თქვენს Outlook-ს არასწორად, დიდია ალბათობა იმისა, რომ თქვენი PST მონაცემები საფრთხეში აღმოჩნდეს. ამ შემთხვევაში თუ გინდა PST შეკეთება მონაცემები, თქვენ უნდა მიმართოთ გამოცდილ ინსტრუმენტს, როგორიცაა DataNumen Outlook Repair.

ავტორი შესავალი:

შირლი ჟანგი არის მონაცემთა აღდგენის ექსპერტი DataNumen, Inc., რომელიც მსოფლიო ლიდერია მონაცემთა აღდგენის ტექნოლოგიებში, მათ შორის მდფ-ის აღდგენა და Outlook სარემონტო პროგრამული პროდუქტები. დამატებითი ინფორმაციისთვის ეწვიეთ www.datanumen. ერთად