როგორ ავტომატურად გამორთოთ ჰიპერბმულები შემომავალი Outlook წერილებში უცნობი გამგზავნისგან

მავნე ბმულების დაბლოკვის მიზნით, უმჯობესია დააკონფიგურიროთ თქვენი Outlook ისე, რომ ავტომატურად გამორთოთ ჰიპერბმულები შემომავალი ელ.წერილებიდან უცნობი გამგზავნისგან. ეს სტატია გამოავლენს VBA კოდების ნაწილს, რომელიც დაგეხმარებათ მიიღოთ ის, როგორც კორკი.

ბევრი მომხმარებელი ჩიოდა, რომ ელ.ფოსტის ვირუსები თავს დაესხნენ მათ Outlook ფაილს. უფრო ხშირად, ვიდრე არა, ეს იმიტომ ხდება, რომ ისინი ადვილად ენდობიან იმ წერილებს უცნობი გამგზავნისგან. ასე რომ, ისინი გადმოწერენ ან დააწკაპუნებენ წერილებში არსებულ ჰიპერბმულებს. ახლა, შემდგომში, ჩვენ გაგიზიარებთ მეთოდს. მას შეუძლია დაუშვას Outlook-ის ავტომატური გამორთვა უცნობი გამგზავნისგან შემომავალი ელ.წერილების ჰიპერბმულები. თუ თქვენ გაქვთ ასეთი საჭიროებები, გთხოვთ წაიკითხოთ მეტი დეტალების მისაღებად.

ავტომატური გამორთვა ჰიპერბმულები უცნობი გამგზავნისგან შემოსულ წერილებში

1. დასაწყებად, Outlook-ში გადადით VBA რედაქტორში „Alt + F11“-ის გამოყენებით.
2. შემდეგ, ახალ ეკრანზე, დაამატეთ „MS VBScript Regular Expressions“ ობიექტი პოსტის მიხედვით.როგორ დავამატოთ ობიექტის ბიბლიოთეკის მითითება VBA-ში".
3. შემდეგ დააკოპირეთ და ჩასვით შემდეგი კოდი „ThisOutlookSession“ პროექტში.

Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
    Set objInboxItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

'Occurs when new mail arrives in your Inbox
Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
    Dim objMail As MailItem
    Dim objContacts As Outlook.Items
    Dim strFilter As String
    Dim objFoundContact As Outlook.ContactItem
    Dim bUnknownSender As Boolean
    Dim objRegExp As Object
    Dim objFoundResults As Object
    Dim i, n As Long
 
    If TypeOf Item Is MailItem Then
       Set objMail = Item
 
       'Check if the sender is in your default Contact folder
       Set objContacts = Application.Session.GetDefaultFolder(olFolderContacts).Items
       For i = 1 To 3
           strFilter = "[Email" & i & "Address] = " & objMail.SenderEmailAddress
           Set objFoundContact = objContacts.Find(strFilter)
           If Not (objFoundContact Is Nothing) Then
              bUnknownSender = False
              Exit For
           End If
       Next
       If objFoundContact Is Nothing Then
          bUnknownSender = True
       End If
 
       'If the sender is unknown
       If bUnknownSender = True Then
          'Find the urls within "<a href=" tags in HTMLbody of Mail
          Set objRegExp = CreateObject("vbscript.RegExp")
          With objRegExp
               .Pattern = "<?href\s*=\s*[""'].+?[""'][^>]*?"
               .IgnoreCase = True
               .Global = True
          End With
 
          If objRegExp.Test(objMail.HTMLBody) Then
             Set objFoundResults = objRegExp.Execute(objMail.HTMLBody)
             For n = 1 To objFoundResults.Count
                 'Disable the hyperlinks in HTMLbody
                 objMail.HTMLBody = Replace(objMail.HTMLBody, objFoundResults.Item(n - 1).Value, "")
             Next
          End If
 
          'Save the mail
          objMail.Save
       End If
    End If
End Sub

4. ამის შემდეგ, გაააქტიურეთ ეს მაკრო Outlook-ის გადატვირთვით ან „Application_Startup“ ქვეპროგრამაში „F5“ კლავიშის დაჭერით.
5. მას შემდეგ, ყოველ ჯერზე, როდესაც ელფოსტა, რომელიც მოდის გამგზავნისგან, რომელიც არ არის შენახული ნაგულისხმევი საკონტაქტო საქაღალდეში, მოხვდება Inbox-ში, Outlook ავტომატურად გათიშავს მასში არსებულ ჰიპერბმულებს.

აუცილებლობის რამდენიმე საკითხი Outlook Protection-ში

იმის გამო, რომ Outlook დაზიანებულია, საკმაოდ რთულია Outlook ფაილის დაცვა. აქ ჩვენ ჩამოვთვლით რამდენიმე აუცილებელ ნივთს Outlook მონაცემთა დაცვის დროს. უპირველეს ყოვლისა, თქვენ რეგულარულად უნდა შექმნათ თქვენი Outlook მონაცემების სარეზერვო ასლი. უფრო მეტიც, აუცილებელია სიფრთხილით მოვეკიდოთ ყველა პოტენციურ რისკს, როგორიცაა მავნე დანართები ან ჰიპერბმულები. დაბოლოს, რაც არანაკლებ მნიშვნელოვანია, წინასწარ უნდა მოამზადოთ Outlook-ის გამოსწორების ძლიერი ინსტრუმენტი, მაგალითად DataNumen Outlook Repair. ის აუცილებლად გამოგადგებათ როცა დაგჭირდებათ PST შეკეთება ფაილი, მაგრამ შემოსულების შეკეთების ინსტრუმენტი ადასტურებს წარუმატებლობას.

ავტორი შესავალი:

შირლი ჟანგი არის მონაცემთა აღდგენის ექსპერტი DataNumen, Inc., რომელიც მსოფლიო ლიდერია მონაცემთა აღდგენის ტექნოლოგიებში, მათ შორის დაზიანებული მდფ და Outlook სარემონტო პროგრამული პროდუქტები. დამატებითი ინფორმაციისთვის ეწვიეთ www.datanumen. ერთად