Come stampare rapidamente tutti i file in un file Zip Allegato di un'e-mail di Outlook

Molti utenti sperano di stampare tutti i file compressi in formato a zip allegato di un'e-mail di Outlook senza salvare e decomprimere fastidiosamente il file zip attaccamento. Quindi, questo articolo introdurrà un mezzo molto più efficace per realizzarlo.

Quando vuoi stampare un file zip Per allegare un file, potresti essere abituato a selezionarlo e a fare clic sul pulsante "Stampa rapida" nella barra multifunzione. Tuttavia, in questo modo, Outlook ti chiederà comunque di salvarlo e decomprimerlo prima. Se desideri evitare questi passaggi fastidiosi, puoi utilizzare il seguente codice VBA.

Stampa tutti i file in a Zip Allegato di un'e-mail

1. Per iniziare, avvia l'applicazione Outlook.
2. Quindi, accedi all'editor VBA di Outlook seguendo i passaggi mostrati nell'articolo - "Come eseguire il codice VBA in Outlook".
3. Successivamente, puoi aprire il progetto "ThisOutlookSession" o un modulo inutilizzato.
4. Successivamente, copia e incolla il codice VBA qui sotto.

Dim objShell As Object
Dim objFileSystem As Object

Sub PrintAllFilesInZipAttachment ()
    Dim objAttachmentSelection As Outlook.AttachmentSelection
    Dim objAttachment, objTempAttachment As Outlook.Attachment
    Dim strTempFolder As String
    Dim strSavingPath As String
    Dim objTempMail As Outlook.MailItem
    Dim strFileName As String
 
    'Get selected attachment
    Set objAttachmentSelection = Outlook.Application.ActiveExplorer.AttachmentSelection
    Set objAttachment = objAttachmentSelection.Item(1)

    If Right(LCase(objAttachment.filename), 3) = "zip" Then
 
       'Save & Unzip the zip attachment
       Set objShell = CreateObject("Shell.Application")
       Set objFileSystem = CreateObject("Scripting.FileSystemObject")
       strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Unzip" & Format(Now, "yyyymmddhhmmss")
       MkDir (strTempFolder)
 
       strSavingPath = strTempFolder & "\" & objAttachment.filename
       objAttachment.SaveAsFile (strSavingPath)
       objShell.NameSpace((strTempFolder)).CopyHere objShell.NameSpace((strSavingPath)).Items
  
       'Attach Unzipped files to a temp mail
       Set objTempMail = Outlook.Application.CreateItem(olMailItem)
       objTempMail.Display
       strFileName = Dir(strTempFolder & "\")
 
       While Len(strFileName) > 0
             objTempMail.Attachments.Add (strTempFolder & "\" & strFileName)
             strFileName = Dir()
       Wend
 
       'Print all attachments of the temp email
       Call PrintFiles(objTempMail)
 
       objTempMail.Close olDiscard
 
       objFileSystem.DeleteFolder (strTempFolder)
    End If
End Sub

Sub PrintFiles(ByVal objMail As Outlook.MailItem)
    Dim objAttachment As Outlook.Attachment
    Dim strTempFolder, strFilePath As String
    Dim objTempFolder As Object
    Dim objTempFolderItem As Object
 
    strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\TEMP" & Format(Now, "yyyymmddhhmmss")
    MkDir (strTempFolder)
 
    'Print all attachments
    For Each objAttachment In objMail.Attachments
        If Right(LCase(objAttachment.filename), 3) <> "zip" Then
           strFilePath = strTempFolder & "\" & objAttachment.filename
           objAttachment.SaveAsFile (strFilePath)
 
           Set objShell = CreateObject("Shell.Application")
           Set objTempFolder = objShell.NameSpace(0)
           Set objTempFolderItem = objTempFolder.ParseName(strFilePath)
           objTempFolderItem.InvokeVerbEx ("print")
        End If
    Next
 
    objFileSystem.DeleteFolder (strTempFolder)
End Sub

5. Successivamente, chiudi la finestra dell'editor VBA corrente.
6. Successivamente, vai su Opzioni di Outlook per aggiungere la nuova macro alla barra di accesso rapido.
7. Infine, puoi fare uno scatto:

• Per prima cosa seleziona a zip allegato di una mail.
• Quindi, fai clic sulla macro nella barra di accesso rapido.

8. Immediatamente, i file si comprimono nel file selezionato zip verrà stampato l'allegato.

Eseguire il backup dei file di dati di Outlook

Potresti aver scoperto che Outlook è soggetto a danneggiamenti. Una volta che Outlook si corrompe, i tuoi dati andranno persi. Pertanto, è importante eseguire regolarmente il backup dei file di dati di Outlook, in modo da poterli recuperare facilmente. Ma se scopri che il backup risale a diverse settimane fa ed è inefficace, non ti resta altra scelta che rivolgerti a un servizio affidabile ed esperto. Recupero PST strumento, come DataNumen Outlook Repair.

Introduzione dell'autore:

Shirley Zhang è un'esperta di recupero dati in DataNumen, Inc., che è il leader mondiale nelle tecnologie di recupero dati, tra cui mdf danneggiato e prodotti software di riparazione di Outlook. Per maggiori informazioni visita www.datanumen.com