Come trovare rapidamente paragrafi di una frase nel tuo documento di Word

In questo articolo, vogliamo mostrarvi un metodo rapido per trovare tutti i paragrafi composti da una sola frase in un documento Word tramite VBA.

Di tanto in tanto, alcuni documenti possono avere requisiti molto specifici per la loro formattazione e struttura. Ad esempio, potresti non essere autorizzato ad avere paragrafi con una sola frase. Questi paragrafi non sono difficili da riconoscere, ma ci vuole tempo, soprattutto è un documento lungo.

Oggi ti offriremo il modo rapido per specificare tutti i paragrafi di una frase nel tuo documento.

Trova tutti i paragrafi di una frase in un documento

1. In primo luogo, Word conta un punto come una frase. Quindi, se ci sono parole come "Mr." o "Ms.", Word lo considera come una frase. Per escludere tale distrazione, è necessario sostituire "Mr." con "signor". E quando finisci di trovare il paragrafo di una singola frase, puoi cambiarli di nuovo. Per sostituire le parole, puoi fare riferimento a questo link: Come trovare e sostituire più elementi nel documento di Word
2. In secondo luogo, premi "Alt + F11" per attivare l'editor VBA.
3. Quindi fare clic su progetto "Normale".
4. Fai clic sulla scheda "Inserisci" nella barra dei menu e scegli "Modulo" nel menu a discesa.
5. Quindi fai doppio clic sul modulo per aprirlo.
6. Incolla i seguenti codici sul modulo:

Sub HighlightParagraphsWithSingleSentence()
  Dim nParagraphNum As Integer
  Dim nCountParagraph As Integer
  Dim objParagraphRange As Range
  Dim nCountSentence As Integer
  Dim nHighlightNum As Integer
 
  nCountParagraph = ActiveDocument.Paragraphs.Count
  nHighlightNum = 0
 
  For nParagraphNum = 1 To nCountParagraph
    Set objParagraphRange = ActiveDocument.Paragraphs(nParagraphNum).Range
    nCountSentence = objParagraphRange.Sentences.Count
    ' Highlight all paragraphs with single-sentence.
    If nCountSentence = 1 And objParagraphRange.Characters.Count > 1 Then
      nHighlightNum = nHighlightNum + 1
      objParagraphRange.HighlightColorIndex = wdYellow
    End If
  Next

  If nHighlightNum > 0 Then
    MsgBox ("There are " & nHighlightNum & " paragraphs with single sentence and they are highlighted.")
  Else
    MsgBox ("There are no paragraphs with single sentence")
  End If

End Sub

7. Ultimo ma non meno importante, fai clic sul pulsante "Esegui" o premi "F5".

Riceverai una tale finestra di messaggio, che ti dirà che il lavoro è finito.

Trova tutti i paragrafi di una frase in più documenti

1. Innanzitutto, devi inserire tutti i documenti di destinazione in una cartella.
2. Quindi installa ed esegui la seguente macro:

Sub HighlightParagraphsWithSingleSentenceInMultipleFiles()
  Dim nParagraphNum As Integer
  Dim nCountParagraph As Integer
  Dim objParagraphRange As Range
  Dim nCountSentence As Integer
  Dim StrFolder As String
  Dim strFile As String
  Dim objDoc As Document
  Dim dlgFile As FileDialog
  Dim nHighlightNum As Integer
  Dim strSummary As String

  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)

  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox ("No Folder is selected!")
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.doc*", vbNormal)
 
  While strFile <> ""
    nHighlightNum = 0
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    Set objDoc = ActiveDocument
    nCountParagraph = ActiveDocument.Paragraphs.Count
 
    For nParagraphNum = 1 To nCountParagraph
      Set objParagraphRange = ActiveDocument.Paragraphs(nParagraphNum).Range
      nCountSentence = objParagraphRange.Sentences.Count
      ' Highlight all paragraphs with single-sentence.
      If nCountSentence = 1 And objParagraphRange.Characters.Count > 1 Then
        nHighlightNum = nHighlightNum + 1
        objParagraphRange.HighlightColorIndex = wdYellow
      End If
    Next
    objDoc.ActiveWindow.ActivePane.View.SeekView = wdSeekMainDocument
    objDoc.Save
    If nHighlightNum = 0 Then
      objDoc.Close
    End If
 
    strSummary = strSummary & strFile & " : " & nHighlightNum & " paragraphs with single sentence." & vbCrLf
    strFile = Dir()
  Wend
  MsgBox (strSummary)
 
End Sub

3. Nella finestra "Sfoglia" aperta, seleziona la cartella in cui conservi i documenti e fai clic su "OK".

La macro quindi evidenzierà tutti i paragrafi di una frase e lascerà i documenti aperti. Se un documento non contiene un paragrafo di una frase, verrà chiuso. Inoltre, c'è una finestra di messaggio, che indica il numero di paragrafi di una frase in ogni documento.

Affrontare l'incidente di perdita di dati

Gli errori dell'utente e l'interruzione improvvisa dell'alimentazione possono causare la morte di Word. Mentre una parola crollata può non solo influenzare il lavoro quotidiano, ma anche portare a danni al documentoQuesto non è certo l'aspetto più fastidioso di un disastro informatico. È meglio affidarsi immediatamente a un'utility di riparazione per recuperare i dati.

Introduzione dell'autore:

Vera Chen è un'esperta di recupero dati in DataNumen, Inc., che è il leader mondiale nelle tecnologie di recupero dati, tra cui recuperare eccellere and pdf riparare prodotti software. Per maggiori informazioni visita www.datanumen.com