Come inviare in batch tutti i file in una cartella di Windows tramite e-mail di Outlook separate

Se desideri inviare a qualcuno tutti i file in una cartella di Windows tramite singole e-mail di Outlook, puoi utilizzare il metodo introdotto in questo articolo. Sta facendo uso del codice VBA, che è abbastanza efficace.

Dopo aver letto il mio precedente articolo – “3 metodi rapidi per allegare tutti i file in una cartella locale a un'e-mail di Outlook”, alcuni utenti desiderano inviare tutti i file in una cartella locale tramite e-mail separate. In modo standard, dovresti creare e-mail e allegare i file uno per uno. È abbastanza fastidioso. Pertanto, di seguito, ti presenteremo un modo più efficace.

Invia in batch tutti i file in una cartella di Windows tramite e-mail separate

1. Innanzitutto, avvia il programma Outlook.
2. Quindi, in Outlook, accedi all'editor VBA in riferimento all'articolo - "Come eseguire il codice VBA in Outlook".
3. Successivamente, copia e incolla il seguente codice VBA in un progetto o in un modulo.

Sub SendAllFilesInSeparateEmails()
    Dim objShell As Object
    Dim objWindowsFolder As Object
    Dim objFile As Object
    Dim strWindowsFolder As String
    Dim objFileSystem As Object
    Dim objMail As Outlook.MailItem
 
    'Select a Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows Folder:", 0, "")
 
    If Not objWindowsFolder Is Nothing Then
       strWindowsFolder = objWindowsFolder.self.Path & "\"
       Set objFileSystem = CreateObject("Scripting.FileSystemObject")
       Set objWindowsFolder = objFileSystem.GetFolder(strWindowsFolder)
 
       'Send each file in an email
       For Each objFile In objWindowsFolder.Files
 
           'Create a new mail
           Set objMail = Outlook.Application.CreateItem(olMailItem)
           'Change the details as per your needs
           With objMail
                .Subject = Left(objFile.Name, Len(objFile.Name) - (Len(objFileSystem.GetExtensionName(objFile.Name)) + 1))
                .Attachments.Add objFile.Path
                .Recipients.Add ("someone@datanumen.com")
                .Recipients.ResolveAll
                .Send
          End With
       Next
 
       'Prompt you when completing sending
       MsgBox "All done!", vbOKOnly + vbExclamation
    End If
End Sub

4. Successivamente, puoi eseguire questa macro in una sola volta. Basta premere il tasto "F5".
5. Successivamente, ti verrà richiesto di selezionare la cartella Windows di origine nella finestra di dialogo popup.
6. Alla fine, Outlook allegherà tutti i file in questa cartella di Windows per separare le e-mail e inviare le e-mail al destinatario predefinito.
7. Al termine, riceverai un messaggio che richiede "Tutto fatto!".

Tieni d'occhio l'integrità di Outlook

Sebbene Outlook sia stato pubblicizzato come il client di posta elettronica più popolare sul mercato, presenta ancora un difetto fatale: la sua vulnerabilità. In altre parole, Outlook è soggetto a vari errori e danneggiamenti. Pertanto, è fondamentale prestare molta attenzione all'integrità del proprio Outlook, proteggendolo da eventuali danni. Inoltre, è necessario eseguire regolarmente il backup dei file di Outlook. Si consiglia inoltre di procurarsi uno strumento di riparazione PST, come DataNumen Outlook Repair. Si può riparare Outlook problemi senza problemi.

Introduzione dell'autore:

Shirley Zhang è un'esperta di recupero dati in DataNumen, Inc., che è il leader mondiale nelle tecnologie di recupero dati, tra cui correzione sql e prodotti software di riparazione di Outlook. Per maggiori informazioni visita www.datanumen.com