Come stampare in batch tutti gli allegati in più e-mail con Outlook VBA

Se desideri stampare in blocco tutti gli allegati in più e-mail selezionate, puoi utilizzare il metodo introdotto in questo articolo. Sta usando un pezzo di codice VBA per raggiungerlo in tempi rapidi.

Come puoi vedere, quando selezioni un singolo allegato, è disponibile una funzione diretta di "Stampa rapida" nella barra multifunzione "Allegati". Tuttavia, quando selezioni più di un allegato, il pulsante "Stampa rapida" verrà disabilitato, per non parlare della stampa di tutti gli allegati in molte e-mail selezionate. Pertanto, a condizione che tu voglia stampare in batch tutti gli allegati in più e-mail in una volta sola, devi cercare altri modi, come strumenti di terze parti o VBA. Incentrato su questa esigenza, qui ti esporremo un pezzo di codice VBA, che può aiutarti a ottenerlo semplicemente con un clic.

Stampa in batch di tutti gli allegati in più e-mail

1. All'inizio, avvia la tua applicazione Outlook.
2. Quindi, nella finestra principale, premi i pulsanti "Alt + F11" per accedere all'editor VBA.
3. Nella successiva finestra "Microsoft Visual Basic for Applications", apri un modulo vuoto.
4. Quindi copia i seguenti codici VBA in tale modulo.

Sub BatchPrintAllAttachmentsinMultipleEmails()
    Dim objFileSystem As Object
    Dim strTempFolder As String
    Dim objSelection As Outlook.Selection
    Dim objItem As Object
    Dim objMail As Outlook.MailItem
    Dim objAttachments As Outlook.attachments
    Dim objAttachment As Outlook.Attachment
    Dim objShell As Object
    Dim objTempFolder As Object
    Dim objTempFolderItem As Object
    Dim strFilePath As String
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Temp for Attachments " & Format(Now, "YYYY-MM-DD_hh-mm-ss")
    'Create a new temp folder
    MkDir (strTempFolder)
 
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
 
    For Each objItem In objSelection
        If TypeOf objItem Is MailItem Then
           Set objMail = objItem
           Set objAttachments = objMail.attachments
 
           'Save all the attachments in the temp folder
           For Each objAttachment In objAttachments
               strFilePath = strTempFolder & "\" & objAttachment.FileName
               objAttachment.SaveAsFile (strFilePath)
 
               'Print all the files in the temp folder
               Set objShell = CreateObject("Shell.Application")
               Set objTempFolder = objShell.NameSpace(0)
               Set objTempFolderItem = objTempFolder.ParseName(strFilePath)
               objTempFolderItem.InvokeVerbEx ("print")
           Next objAttachment
        End If
    Next
End Sub

5. Successivamente, puoi aggiungere la nuova macro alla barra di accesso rapido.
6. Successivamente, dovresti impostare il livello di sicurezza delle macro di Outlook su basso.
7. Alla fine puoi provare.

• Innanzitutto, nell'elenco di posta, seleziona diverse e-mail di cui desideri stampare gli allegati.
• Quindi fare clic sul nuovo pulsante macro nella barra di accesso rapido.
• Successivamente, verranno stampati tutti gli allegati nelle e-mail selezionate.

Attenzione ai virus nascosti nelle macro

Se hai configurato il livello di sicurezza delle macro di Outlook su un livello basso, devi impegnarti molto per bloccare potenziali virus nelle macro dannose. È perché i virus possono distruggere i dati di Outlook in una volta sola. Una volta che i tuoi dati di Outlook sono corrotti, farai del tuo meglio per recuperare Outlook dati con tutti i mezzi, come ricorrere a uno strumento potente come DataNumen Outlook Repair.

Introduzione dell'autore:

Shirley Zhang è un'esperta di recupero dati in DataNumen, Inc., che è il leader mondiale nelle tecnologie di recupero dati, tra cui sql corrotto e prodotti software di riparazione di Outlook. Per maggiori informazioni visita www.datanumen.com