Come spostare automaticamente le e-mail con destinatari CC specifici in Outlook

In realtà, molti di voi potrebbero desiderare di creare una regola di Outlook per spostare automaticamente le email con destinatari CC specifici. Tuttavia, le regole di Outlook non supportano la verifica dei destinatari CC. Questo articolo vi insegnerà quindi come farlo utilizzando Outlook VBA.

Ovviamente, è impossibile creare una regola di Outlook per cercare specifici destinatari CC. Come mostrato nello screenshot seguente, per le e-mail ricevute, puoi solo controllare se il tuo nome è nella casella CC. Allo stesso modo, per le e-mail inviate, anche se non esiste una condizione di regola per selezionare la casella CC.

Pertanto, se desideri configurare Outlook per spostare automaticamente le e-mail con specifici destinatari CC, devi cercare altri mezzi. Poi. qui ti insegneremo come ottenerlo tramite Outlook VBA.

Sposta automaticamente le e-mail inviate con destinatari CC specifici

1. Innanzitutto, vai alla scheda "Sviluppatore" e fai clic sul pulsante "Visual Basic".
2. Quindi apri il progetto "ThisOutlookSession" e copia i seguenti codici VBA al suo interno.

Public WithEvents olItems As Outlook.Items

Sub Application_Startup()
    Set olItems = Session.GetDefaultFolder(olFolderSentMail).Items
End Sub

Sub olItems_ItemAdd(ByVal Item As Object)
    If Item.Class = olMail Then
       MoveMail Item
    End If
End Sub

Sub MoveMail(Mail As Outlook.MailItem)
    Dim ccRecip As String
    Dim desFolder As Folder
 
    'Replace "test" with your desired CC'd recipient name or address
    ccRecip = "test"
    'The "Test" folder is a subfolder under "Sent Items" folder
    Set desFolder = Session.GetDefaultFolder(olFolderSentMail).Folders("Test")
 
    If InStr(LCase(Mail.CC), ccRecip) > 0 Then
       Mail.Move desFolder
    End If
End Sub

3. Successivamente, dovresti procedere a firmare questo codice e modificare le impostazioni macro come al solito.
4. Infine, puoi uscire dalla finestra "Visual Basic". Successivamente, le e-mail con i destinatari CC specifici verranno spostate nella cartella di posta specificata.

Sposta automaticamente le e-mail ricevute con destinatari CC specifici

Ora che il codice VBA di cui sopra ha lo scopo di spostare le e-mail inviate con destinatari CC specifici, se si desidera cercare destinatari CC specifici nelle e-mail ricevute e quindi spostarle, è necessario utilizzare invece i seguenti codici.

Public WithEvents olItems As Outlook.Items

Sub Application_Startup()
    Set olItems = Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Sub olItems_ItemAdd(ByVal Item As Object)
    If Item.Class = olMail Then
       MoveMail Item
    End If
End Sub

Sub MoveMail(Mail As Outlook.MailItem)
    Dim Recips As Recipients
    Dim Recip As Recipient
    Dim ccRecip As String
    Dim desFolder As Folder
 
    Set Recips = Mail.Recipients
    'Replace "test" with the specific words in your desired CC recipient address
    ccRecip = "test"
 
    For Each Recip In Recips
        If Recip.Type = olCC Then
           If InStr(LCase(Recip.Address), ccRecip) > 0 Then
              'The "Test" folder is a subfolder under "Inbox" folder
              Set desFolder = Session.GetDefaultFolder(olFolderInbox).Folders("Test")
              Mail.Move desFolder
           End If
        End If
    Next
End Sub

Mantieniti ben preparato per la corruzione di Outlook

Sebbene Outlook sia ricco di funzionalità, non può ancora essere immune alla corruzione. Quindi dovresti stare attento a tutti i potenziali rischi. Indubbiamente, il passaggio fondamentale deve essere l'esecuzione di un backup coerente e aggiornato per i dati di Outlook. Inoltre, dovresti tenere a strumento di ripristino di Outlook corrotto nelle vicinanze. Sarà utile se sia i backup che Scanpst.exe falliscono.

Introduzione dell'autore:

Shirley Zhang è un'esperta di recupero dati in DataNumen, Inc., che è il leader mondiale nelle tecnologie di recupero dati, tra cui riparazione SQL Server errore del file mdf e prodotti software di riparazione di Outlook. Per maggiori informazioni visita www.datanumen.com