2 modi rapidi per trovare o eliminare frasi contenenti testo specifico nella tua parola

In questo articolo, ti offriremo 2 modi rapidi per trovare o eliminare frasi contenenti testo specifico nella tua parola.

È risaputo che in Word è possibile utilizzare la funzione "Trova e sostituisci" per individuare facilmente tutte le occorrenze di parole specifiche. In questo modo, non avremo problemi a evidenziarle, sostituirle o eliminarle. Come potete vedere, l'obiettivo è una parola o una frase. Oggi, tuttavia, siamo lieti di illustrarvi come utilizzare una macro per trovare o eliminare frasi contenenti un determinato testo.

Metodo 1: trova o elimina frasi contenenti testo specifico

1. Per cominciare, premi "Alt + F11" per attivare l'editor VBA in Word.
2. Quindi crea un nuovo modulo facendo clic su "Normale".
3. Quindi fai clic su "Inserisci" e scegli "Modulo" per ottenerne uno nuovo.
4. E apri il modulo con doppio clic.
5. Ora incolla i seguenti codici:

Sub DeleteSentencesContainingSpecificWords()
  Dim strTexts As String
  Dim strButtonValue As String
 
  strTexts = InputBox("Enter texts to be found here: ")
 
  With Selection
    .HomeKey Unit:=wdStory
 
    '  Find the entered texts.
    With Selection.Find
      .ClearFormatting
      .Text = strTexts
      .Replacement.Text = ""
      .Forward = True
      .Wrap = wdFindContinue
      .Format = False
      .MatchCase = False
      .MatchWholeWord = False
      .MatchWildcards = False
      .MatchSoundsLike = False
      .MatchAllWordForms = False
      .Execute
    End With
 
    Do While .Find.Found = True
      '  Expand the selection to the entire sentence.
      Selection.Expand Unit:=wdSentence
      strButtonValue = MsgBox("Are you sure to delete the sentence?", vbYesNo)
      If strButtonValue = vbYes Then
        Selection.Delete
      End If
      .Collapse wdCollapseEnd
      .Find.Execute
    Loop
  End With
End Sub

6. Quindi fai clic su "Esegui".
7. Ci sarà una casella di input, che ti chiederà di inserire del testo. Basta digitare il testo comune contenuto in tutte le frasi. Fare clic su "OK".
8. Quindi vedrai una frase contenente il testo nella selezione con una finestra di messaggio che richiede. Fare clic su "Sì" per eliminare la frase e su "No" per mantenerla.
9. Dopo la conferma, la frase successiva con il testo designato viene selezionata. E c'è anche una casella di conferma. In pratica, la macro ti guida attraverso l'intero documento, individuando le frasi target e chiedendoti conferma ogni volta.

Metodo 2: trova o elimina frasi contenenti qualsiasi testo in un elenco

Con la macro nel metodo 1, puoi cercare solo una parola o una frase alla volta. Certamente, puoi eseguire ripetutamente la macro per cercare più istanze di parole o frasi. Per soddisfare la necessità di ricerche multiple, ti forniremo un'altra macro.

1. Innanzitutto, inserisci tutti i testi da modificare in un nuovo documento. Assicurati che ogni testo occupi un paragrafo e non ci siano spazi finali. Chiudi e salva il documento.
2. Quindi installa ed esegui una macro con i passaggi esatti nel metodo 1.
3. Quindi sostituisci macro con questo:

Sub DeleteSentencesContainingSpecificWordsOnAList()
  Dim objListDoc As Document, objTargetDoc As Document
  Dim objParaRange As Range
  Dim objParagraph As Paragraph
  Dim strFileName As String, strButtonValue As String
  Dim dlgFile As FileDialog
 
  Set dlgFile = Application.FileDialog(msoFileDialogFilePicker)
 
  With dlgFile
    If .Show = -1 Then
      strFileName = .SelectedItems(1)
    Else
      MsgBox "No file is selected! Please select the target file."
      Exit Sub
    End If
  End With
  Set objTargetDoc = ActiveDocument
  Set objListDoc = Documents.Open(strFileName)
  objTargetDoc.Activate
 
  For Each objParagraph In objListDoc.Paragraphs
    Set objParaRange = objParagraph.Range
    objParaRange.End = objParaRange.End - 1
 
    With Selection
      .HomeKey Unit:=wdStory
 
      '  Find target words.
      With Selection.Find
        .ClearFormatting
        .Text = objParaRange
        .MatchWholeWord = True
        .MatchCase = False
        .Execute
      End With
 
      '  Expand the selection to the entire sentence.
      Do While .Find.Found
        Selection.Expand Unit:=wdSentence
        strButtonValue = MsgBox("Are you sure to delete the sentence?", vbYesNo)
        If strButtonValue = vbYes Then
          Selection.Delete
        End If
        .Collapse wdCollapseEnd
        .Find.Execute
      Loop
    End With
  Next objParagraph
End Sub

4. Ora si aprirà la finestra "Sfoglia". Scegli il documento appena salvato e fai clic su “Apri”.
5. La seguente procedura è uguale a quella del metodo 1.

Approccio alla gestione dei documenti corrotti

La perdita di dati preziosi è assolutamente devastante. Può persino mettere in gioco la tua attività. Per evitare tale frustrazione, è necessario procurarsi un Correzione della parola strumento il prima possibile. Tale strumento ti aiuterà a vincere la battaglia con la corruzione dei documenti.

Introduzione dell'autore:

Vera Chen è un'esperta di recupero dati in DataNumen, Inc., che è il leader mondiale nelle tecnologie di recupero dati, tra cui correggere Excel and pdf riparare prodotti software. Per maggiori informazioni visita www.datanumen.com