Kuidas lahti tõmblukku võtta .Zip Manused otse Outlookis VBA kaudu

Kui saate manuse jaotises „.zip” faililaiendiga, siis kui soovite need lahti pakkida, peaksite need üldiselt salvestama ja lahti pakkima kohalikule draivile. Kuid paljud loodavad need otse Outlookis lahti pakkida. See artikkel õpetab teile, kuidas seda VBA kaudu hankida.

Te peate olema kunagi saanud manuseid, mis asuvad jaotises „.zip” faililaiendit. Selleks, et pääseda juurde sisemistele failidele ühes zip faili, peate selle kõigepealt lahti pakkima. Sellisel juhul, nagu tavaliselt, peate kõigepealt faili salvestama zip Kopeerige fail kohalikule draivile, paremklõpsake sellel ja valige kontekstimenüüst „Ekstrakti kõik”. Tegelikkuses eelistavad paljud kasutajad faili otse Outlookis lahti pakkida. Outlookil aga sellist sisseehitatud funktsiooni pole. Õnneks saate VBA abil selle imelihtsaks tegemiseks järgida järgmisi samme.

Pakkige lahti .Zip Manused otse Outlookis

1. Kõigepealt käivitage oma Outlooki rakendus.
2. Seejärel vajutage VBA redaktori avamiseks Outlooki aknas kiirklahvi Alt + F11.
3. Järgmisena avage aknas „Microsoft Visual Basic for Applications” moodul, mida ei kasutata.
4. Seejärel kopeerige ja kleepige sellesse moodulisse järgmised VBA koodid.

Public Sub UnzipFileInOutlook()
    Dim objMail As Outlook.MailItem
    Dim objAttachments As Outlook.attachments
    Dim objAttachment As Outlook.Attachment
    Dim objShell As Object
    Dim objFileSystem As Object
    Dim strTempFolder As String
    Dim strFilePath As String
    Dim strFileName As String
 
    Set objMail = Outlook.Application.ActiveInspector.CurrentItem
    Set objAttachments = objMail.attachments
 
    'Save & Unzip the zip file in local drive
    Set objShell = CreateObject("Shell.Application")
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Temp" & Format(Now, "yyyy-mm-dd-hh-mm-ss")
    MkDir (strTempFolder)
 
    For Each objAttachment In objAttachments
        If Right(objAttachment.FileName, 3) = "zip" Then
           strFilePath = strTempFolder & "\" & objAttachment.FileName
           objAttachment.SaveAsFile (strFilePath)
           objShell.NameSpace((strTempFolder)).CopyHere objShell.NameSpace((strFilePath)).Items
        End If
    Next
 
    'Reattach the files extracted from the zip file
    strFileName = Dir(strTempFolder & "\")
 
    While Len(strFileName) > 0
          objMail.attachments.Add (strTempFolder & "\" & strFileName)
          strFileName = Dir
          objMail.Save
    Wend
 
    'Delete the attachments in “.zip” file extension
    Set objAttachments = objMail.attachments
    For Each objAttachment In objAttachments
        If Right(objAttachment.FileName, 3) = "zip" Then
           objAttachment.Delete
           objMail.Save
        End If
    Next
 
    'Delete the temp folder and files
    objFileSystem.DeleteFolder (strTempFolder)
End Sub

5. Pärast seda saate uue VBA projekti lisada sõnumiakna kiirpääsuribale nagu tavaliselt.
6. Lõpuks võite proovida.

• Esmalt avage sõnum zip faili oma aknas.
• Seejärel klõpsake "Toimingud" > "Muuda sõnumit".
• Järgmisena klõpsake kiirjuurdepääsu tööriistaribal uut makro nuppu.
• Korraga, zip fail pakitakse lahti, nagu järgmisel ekraanipildil:

Vabanege tüütutest PST-probleemidest

Kuigi uues Unicode-vormingus PST-fail toetab 20 GB failisuurust, on siiski mõistlik hoida fail võimalikult väikesena. Põhjus on selles, et suur PST-fail on palju altid korruptsioonile. Kui teie PST-fail on ohus, peate selle nimel pingutama taastada PST andmeid. Selle stsenaariumi korral ei jää teil muud üle, kui kasutada mõnda hästi tõestatud ja mainekat tööriista nagu DataNumen Outlook Repair.

Autori sissejuhatus:

Shirley Zhang on andmete taastamise ekspert DataNumen, Inc., mis on maailmas juhtiv andmete taastamise tehnoloogiate, sealhulgas sql remont ja Outlooki remonditarkvaratooted. Lisateabe saamiseks külastage www.datanumenCom