Kuidas kiiresti eemaldada VBA kaudu kaustast dubleeritud Outlooki üksused

Kui soovite Outlookis duplikaatüksuste eemaldamise teha, on ükshaaval otsimine ja eemaldamine üsna tülikas. See postitus õpetab teile, kuidas seda Outlook VBA abil kiiresti teha.

Minu eelmises artiklis - "Kuidas kiiresti leida ja eemaldada Outlookis dubleerivaid e-kirju”, saate õppida korduvate e-kirjade otsimise ja eemaldamise nippi, mis sorteerib kirjad esmalt teema, seejärel vastuvõtuaja ja seejärel manuste järgi, et leida välja duplikaatüksused ning lõpuks valida duplikaadid ja vajutada klahvi "Kustuta". Kuigi see meetod on näiliselt veidi mugavam, on see Outlook VBA kasutamisega võrreldes palju tülikam. Järgmiste VBA-koodide abil saate kiiresti eemaldada duplikaatüksused lihtsalt ühe klõpsuga, olenemata meilidest, ülesannetest, kontaktidest või kohtumistest. Nüüd lugege edasi, et saada koodid üksikasjalikult.

Eemaldage kaustast Outlooki dubleerivad üksused

1. Alustamiseks käivitage oma Outlooki programm.
2. Seejärel vajutage klahvikombinatsiooni Alt + F11.
3. Järgmises VBA redaktori aknas topeltklõpsake kasutusel oleva mooduli avamiseks või sisestage uus moodul otse, valides "Insert" > "Module".
4. Järgmisena kopeerige ja kleepige moodulisse järgmised VBA koodid.

Sub RemoveDuplicateItems()
    Dim objFolder As Folder
    Dim objDictionary As Object
    Dim i As Long
    Dim objItem As Object
    Dim strKey As String

    Set objDictionary = CreateObject("scripting.dictionary")
    'Select a source folder
    Set objFolder = Outlook.Application.Session.PickFolder

    If Not (objFolder Is Nothing) Then
       For i = objFolder.Items.Count To 1 Step -1
           Set objItem = objFolder.Items.Item(i)
 
           Select Case objFolder.DefaultItemType
                  'Check email subject, body and sent time
                  Case olMailItem
                       strKey = objItem.Subject & "," & objItem.Body & "," & objItem.SentOn
                  'Check appointment subject, start time, duration, location and body
                  Case olAppointmentItem
                       strKey = objItem.Subject & "," & objItem.Start & "," & objItem.Duration & "," & objItem.Location & "," & objItem.Body
                  'Check contact full name and email address
                  Case olContactItem
                       strKey = objItem.FullName & "," & objItem.Email1Address & "," & objItem.Email2Address & "," & objItem.Email3Address
                  'Check task subject, start date, due date and body
                  Case olTaskItem
                       strKey = objItem.Subject & "," & objItem.StartDate & "," & objItem.DueDate & "," & objItem.Body
           End Select
 
           strKey = Replace(strKey, ", ", Chr(32))
 
           'Remove the duplicate items
           If objDictionary.Exists(strKey) = True Then
              objItem.Delete
           Else
              objDictionary.Add strKey, True
           End If
       Next i
    End If
End Sub

5. Pärast seda allkirjastage see makro digitaalselt ja muutke oma Outlooki makro turvatase madalaks.
6. Hiljem saate seda uut VBA projekti käivitada. Klõpsake tööriistaribal otse ikooni "Käivita".
7. Seejärel peate valima kausta, kust soovite dubleerivad üksused eemaldada.
8. Lõpuks kustutatakse valitud kaustas olevad duplikaatüksused korraga.

Kaitske haavatavaid PST-andmeid

Kuna PST-fail on korruptsioonile vastuvõtlik, peaksite oma PST-faili kaitsmiseks palju pingutama. Näiteks peaksite vältima Outlooki ebaõiget sulgemist. Lisaks peate valmistama tugeva Outlooki parandus tööriist, näiteks DataNumen Outlook Repair mis suudab teie PST õigel ajal päästa.

Autori sissejuhatus:

Shirley Zhang on andmete taastamise ekspert DataNumen, Inc., mis on maailmas juhtiv andmete taastamise tehnoloogiate, sealhulgas taastuma SQL Server ja Outlooki remonditarkvaratooted. Lisateabe saamiseks külastage www.datanumenCom