Kuidas kiiresti eksportida igas värvikategoorias Outlooki kohtumistele kulutatud aega

Kui soovite koostada aruannet iga värvikategooria kohtumistele kulutatud koguaja kohta, saate kasutada selles artiklis kirjeldatud meetodit. See aitab teil seda kiiresti saavutada, ilma et peaksite käsitsi loendama.

Paljud kasutajad on harjunud enamiku oma tegevustest Outlooki kalendrisse logima. Samuti määravad nad igale tegevusele kategooria, et neid hõlpsamini hallata ja eristada. Sellisel juhul soovivad mõned kasutajad genereerida aruande, mis näitab iga värvikategooria kalendrikirjetele kulutatud aega. Kahtlemata on käsitsi loendamine ja sisestamine tülikas. Seetõttu jagame siin viisi, kuidas seda ülesannet lihtsa klõpsuga täita.

Ekspordi iga värvikategooria kohtumistele kulutatud koguaeg

1. Kõigepealt käivitage oma Outlooki rakendus.
2. Seejärel võite pärast Outlooki akna sisenemist puudutada klahvi "Alt + F11" nuppe.
3. Seejärel saate juurdepääsu aknale „Microsoft Visual Basic for Applications”.
4. Järgmisena peate lubama „Microsoft Exceli objektiteeki“. Selleks klõpsake valikul „Tööriistad“ > „Viited“.
5. Seejärel peaksite leidma ja avama mooduli, mida ei kasutata.
6. Pärast seda peate sellesse moodulisse kopeerima järgmise VBA koodi.

Sub ExportTimeSpentOnAppointmentsInEachColorCategory()
    Dim objDictionary As Object
    Dim objAppointments As Outlook.Items
    Dim objAppointment As Outlook.AppointmentItem
    Dim strCategory As String
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim arrKey As Variant
    Dim arrItem As Variant
    Dim i As Long
    Dim nLastRow As Integer
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
    Set objAppointments = Application.Session.PickFolder.Items
  
    For Each objAppointment In objAppointments
        arrCategory = Split(objAppointment.Categories, ",")
        For Each varCategory In arrCategory
            strCategory = Trim(varCategory)
            If objDictionary.Exists(strCategory) Then
               objDictionary.Item(strCategory) = objDictionary.Item(strCategory) + objAppointment.Duration
            Else
               objDictionary.Add strCategory, objAppointment.Duration
            End If
        Next
    Next
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
    objExcelApp.Visible = True
    objExcelWorkbook.Activate
 
    With objExcelWorksheet
         .Cells(1, 1) = "Color Category"
         .Cells(1, 1).Font.Bold = True
         .Cells(1, 1).Font.Size = 14
         .Cells(1, 2) = "Total Time (min)"
         .Cells(1, 2).Font.Bold = True
         .Cells(1, 2).Font.Size = 14
    End With
 
    arrKey = objDictionary.Keys
    arrItem = objDictionary.Items
 
    For i = LBound(arrKey) To UBound(arrKey)
        nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.count).End(xlUp).Row + 1
 
        objExcelWorksheet.Cells(nLastRow, 1) = arrKey(i)
        objExcelWorksheet.Cells(nLastRow, 2) = arrItem(i)
    Next

    objExcelWorksheet.Columns("A:B").AutoFit
End Sub

7. Lõpuks saate selle makro käivitada, klõpsates tööriistaribal ikooni "Käivita" või vajutades klahvi "F5".
8. Seejärel palutakse teil valida konkreetne kalender.
9. Kui olete valinud ja vajutanud "OK", jätkab makro töötamist. Pärast selle lõppemist kuvatakse taustal uus Exceli fail.
10. Saate sellele juurde pääseda. See näeb välja nagu järgmine ekraanipilt:

Hoidke silma peal oma Outlookiga seotud võimalike ohtude eest

Outlooki kasutajad peaksid jälgima kõiki võimalikke riske, sealhulgas tundmatuid meilimanuseid, manustatud linke ja inimlikke vigu. Vastasel juhul võib teie Outlook igal ajal rikkuda. Samuti on vaja regulaarselt teha Outlooki andmete varukoopiaid ja kasutada spetsiaalset parandustööriista. DataNumen Outlook Repair on üks enim soovitatud parandustööriistu. See saab Outlooki parandamine probleemid hetkega.

Autori sissejuhatus:

Shirley Zhang on andmete taastamise ekspert DataNumen, Inc., mis on maailmas juhtiv andmete taastamise tehnoloogiate, sealhulgas kahjustatud mdf ja Outlooki remonditarkvaratooted. Lisateabe saamiseks külastage www.datanumenCom