Kuidas eksportida kiiresti PST-failis olevate kaustade suurusteavet Exceli faili

Kui soovite kontrollida PST-faili iga kausta suuruse teavet, võite kasutada selles artiklis kirjeldatud meetodit. See ekspordib kõigi PST-failis olevate kaustade suuruse teabe kiiresti Exceli faili.

Kui teie PST-fail on liiga suur, võiksite kontrollida iga kausta suurust. See aitab teil hõlpsalt aru saada, millised on suuremad, ja teha sobiva arhiveerimise vastavalt suurusele. Üldiselt võite kausta suuruse kontrollimiseks lihtsalt paremklõpsata kaustal ja seejärel valida "Atribuudid". Uues hüpikakna dialoogiboksis saate klõpsata nupul "Kausta suurus". Kui aga olete loonud palju kaustu, on suuruseteabe ükshaaval käsitsi kontrollimine märkimisväärselt tülikas. Seega, kui soovite hankida PST-faili kõigi kaustade suurusteabe partii, saate kasutada järgmist VBA-koodi. See ekspordib kõik kaustanimed ja suuruse teabe ühe korraga Exceli faili.

Eksportige kõigi PST-failis olevate kaustade suurusteave Exceli faili

1. Alustamiseks käivitage oma Outlooki rakendus.
2. Seejärel lülituge vahekaardile "Arendaja" ja klõpsake nuppu "Visual Basic" või vajutage VBA redaktori avamiseks klahve "Alt + F11".
3. Järgmisena avage aknas „Microsoft Visual Basic for Applications” moodul, mida ei kasutata.
4. Seejärel kopeerige ja kleepige sellesse moodulisse järgmised VBA koodid.

Dim strExcelFile As String
Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportFodlerSizetoExcel()
    Dim objSourcePST As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
    objExcelWorksheet.Cells(1, 1) = "Folder"
    objExcelWorksheet.Cells(1, 2) = "Size"
 
    'Select a source PST file
    Set objSourcePST = Outlook.Application.Session.PickFolder

    For Each objFolder In objSourcePST.Folders
        Call ProcessFolders(objFolder)
    Next
 
    'Fit the columns from A to B
    objExcelWorksheet.Columns("A:B").AutoFit
 
    strExcelFile = "E:\Outlook\" & objSourcePST.Name & " Folder Size (" & Format(Now, "yyyy-mm-dd hh-mm-ss") & ").xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim objItem As Object
    Dim lCurrentFolderSize As Long
    Dim nNextEmptyRow As Integer
 
    objCurrentFolder.Items.SetColumns ("Size")
    For Each objItem In objCurrentFolder.Items
        lCurrentFolderSize = lCurrentFolderSize + objItem.Size
    Next
 
    'Convert byte to kilobyte
    'To convert to megabyte, use:
    'lCurrentFolderSize = (lCurrentFolderSize / 1024) / 1024
    lCurrentFolderSize = lCurrentFolderSize / 1024
 
    nNextEmptyRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1

    'Add the values into the columns
    objExcelWorksheet.Range("A" & nNextEmptyRow) = objCurrentFolder.FolderPath
    objExcelWorksheet.Range("B" & nNextEmptyRow) = lCurrentFolderSize & " KB"
 
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessFolders(objSubfolder)
       Next
    End If
End Sub

5. Pärast seda peaksite määrama oma Outlooki makro turvataseme madalaks.
6. Lõpuks võite proovida.

• Vajutage aktiivses makroaknas klahvi F5.
• Seejärel palutakse teil valida PST-fail, näiteks järgmine pilt:
• Pärast lähtefaili valimist alustab Outlook suurusteabe eksportimist Excelisse.
• Kui makro on lõppenud, saate teate nagu alloleval ekraanipildil.
• Lõpuks leiate Exceli faili eelmääratletud kohalikust kaustast. Exceli fail näeb välja järgmine:

Tegelege sagedaste PST-tõrgetega

Kuna Outlookis esineb vigu, võib teil olla Outlookis palju probleeme. Selleks, et paremini ja paindlikumalt toime tulla masendavate PST-probleemidega, on soovitatav hoida läheduses kogenud ja mainekat parandusutiliiti, nt. DataNumen Outlook Repair. See on võimeline paranda PST probleemid nagu imelihtne.

Autori sissejuhatus:

Shirley Zhang on andmete taastamise ekspert DataNumen, Inc., mis on maailmas juhtiv andmete taastamise tehnoloogiate, sealhulgas SQL Server taastumine ja Outlooki remonditarkvaratooted. Lisateabe saamiseks külastage www.datanumenCom