Kuidas kiiresti Excelisse eksportida Outlooki kontaktrühma kõigi liikmete üksikasjad

Vaikimisi näete kontaktirühmas ainult liikmete nimesid ja e-posti aadresse. Kui soovite saada liikmete muid üksikasju, võite kasutada selles artiklis kirjeldatud viisi.

Kui teete kontaktirühmal selle avamiseks topeltklõpsu, näete selle aknas ainult rühmaliikmete nimesid ja e-posti aadresse. Te ei saa hankida liikmete muid andmeid, nagu ettevõte, ametinimetus, telefoninumber või ettevõtte aadress jne. Üldjuhul peate nende andmete saamiseks leidma oma kontaktide kaustast käsitsi liikmetele vastavad kontaktid. See on liiga tülikas. Siin näitame teile osa VBA-koodist, mis saab need andmed kiiresti Exceli töövihikusse eksportida.

Eksportige kontaktrühma kõigi liikmete andmed Excelisse

1. Et start koos käivitage oma Outlooki rakendus.
2. Seejärel peaksite Outlooki peaaknas vajutama kiirklahve "Alt + F11".
3. Järgmisena peate uues aknas "Microsoft Visual Basic for Applications" avama mittekasutuses oleva mooduli või sisestama otse uue mooduli.
4. Seejärel kopeerige ja kleepige sellesse moodulisse järgmine VBA kood.

Sub ExportMemberContactDetailsToExcel()
    Dim objContactGroup As Outlook.DistListItem
    Dim objGroupMember As Outlook.recipient
    Dim objContacts As Outlook.Items
    Dim objFoundContact As Outlook.ContactItem
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkBook As Excel.Workbook
    Dim objExcelWorkSheet As Excel.Worksheet
    Dim i As Integer
    Dim nRow As Integer
    Dim strFilename As String
 
    Set objContactGroup = Application.ActiveExplorer.Selection(1)
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkBook = objExcelApp.Workbooks.Add
    Set objExcelWorkSheet = objExcelWorkBook.Worksheets(1)
 
    'Set the seven column headers
    With objExcelWorkSheet
         .Cells(1, 1) = "Name"
         .Cells(1, 2) = "Email Address"
         .Cells(1, 3) = "Company"
         .Cells(1, 4) = "Job Title"
         .Cells(1, 5) = "Phone Number"
         .Cells(1, 6) = "Mailing Address"
         .Cells(1, 7) = "Birthday"
    End With
 
    Set objContacts = Application.Session.GetDefaultFolder(olFolderContacts).Items.Restrict("[Email1Address]>''")
 
    nRow = 2
    For i = 1 To objContactGroup.MemberCount
        Set objGroupMember = objContactGroup.GetMember(i)
 
        strFilter = "[Email1Address] = '" & objGroupMember.Address & "'"
        Set objFoundContact = objContacts.Find(strFilter)
 
        If Not (objFoundContact Is Nothing) Then
           'Input the Contact Details
           With objExcelWorkSheet
                .Cells(nRow, 1) = objFoundContact.FullName
                .Cells(nRow, 2) = objFoundContact.Email1Address
                .Cells(nRow, 3) = objFoundContact.CompanyName
                .Cells(nRow, 4) = objFoundContact.JobTitle
                .Cells(nRow, 5) = objFoundContact.BusinessTelephoneNumber
                .Cells(nRow, 6) = objFoundContact.MailingAddress
             If objFoundContact.Birthday = #1/1/4501# Then
                .Cells(nRow, 7) = ""
             Else
                .Cells(nRow, 7) = objFoundContact.Birthday
             End If
           End With
       Else
           With objExcelWorkSheet
               .Cells(nRow, 1) = objGroupMember.Name
               .Cells(nRow, 2) = objGroupMember.Address
           End With
       End If
       nRow = nRow + 1
    Next
 
    'Fit the columns
    objExcelWorkSheet.Columns("A:G").AutoFit
 
    'Change the Path as per where you want to save the new Excel file
    strFilename = "E:\" & objContactGroup.DLName & " Member Contact Details.xlsx"
    'Save the Excel workbook
    objExcelWorkBook.Close True, strFilename
 
    MsgBox ("Complete!")
End Sub

5. Pärast seda saate mugavaks kontrollimiseks lisada uue VBA projekti kiirpääsu tööriistaribale või lindile.
6. Hiljem määrake oma Outlooki makro turvatase madalaks.
7. Lõppkokkuvõttes võite proovida.

• Esmalt valige kontaktirühm.
• Seejärel vajutage kiirpääsuribal või lindil makronuppu.
• Kohe käivitatakse makro.
• Kui see on lõppenud, kuvatakse teade "Lõpeta!"
• Pärast seda saate minna eelmääratletud sihtkoha kohalikku kausta, kust leiate uue Exceli faili.
• Avage see ja näete grupiliikmete kontaktandmeid nagu järgmine ekraanipilt:

Ärge paanitsege Outlooki probleemide ees

Keegi ei ole nõus Outlooki probleemidega nõustuma, olenemata hüpikakendest või veateatest rikutud Outlook andmefail. Seetõttu kipuvad kasutajad Outlooki probleemidega kokku puutudes paanikasse sattuma. Kui soovite sel juhul rahulikuks jääda, peaks teil olema kaks vajalikku asja. Üks on praegused Outlooki andmete varukoopiad. Teine on näiteks võimas Outlooki parandustarkvara DataNumen Outlook Repair.

Autori sissejuhatus:

Shirley Zhang on andmete taastamise ekspert DataNumen, Inc., mis on maailmas juhtiv andmete taastamise tehnoloogiate, sealhulgas sql taastamine ja Outlooki remonditarkvaratooted. Lisateabe saamiseks külastage www.datanumenCom