Kuidas määrata Outlookis erinevat tüüpi märgistatud üksuste jaoks erinev vaikemeeldetuletusaeg

Vaikimisi kasutab Outlook automaatselt igat tüüpi lipuga märgitud üksuste jaoks ülesannete vaikemeeldetuletusaega. Kui aga soovite kasutada märgistatud üksuste jaoks üksuse tüübi alusel erinevat meeldetuletusaega, võite viidata selles artiklis tutvustatud meetodile.

Outlook võimaldab teil määrata kõigile lipuga märgitud üksustele meeldetuletuse vaikeaja, olenemata üksuse tüübist. Võite minna menüüsse "Fail" ja klõpsata "Valikud". Seejärel näete aknas "Outlooki suvandid" vahekaardil "Ülesanded" valikut "Meeldetuletuse vaikeaeg", nagu on näidatud järgmisel ekraanipildil.

Sellest hoolimata loodavad enamik kasutajaid erinevat tüüpi lipukestega üksuste jaoks kasutada erinevat meeldetuletuse aega, näiteks lipukestega kirjade jaoks kella 9.00 ja lipukestega kontaktide jaoks kella 17.30. Järgnevalt keskendume sellele näitele, et meetodit tutvustada.

Määrake erinevat tüüpi märgistatud üksuste jaoks erinev vaikemeeldetuletusaeg

1. Alustamiseks käivitage Outlooki rakendus.
2. Seejärel avage Outlook VBA redaktor, viidates "Kuidas Outlookis VBA-koodi käivitada".
3. Järgmises aknas "Microsoft Visual Basic for Applications" kopeerige järgmine kood projekti "ThisOutlookSession".

Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objMail As Outlook.MailItem
Public WithEvents objContact As Outlook.ContactItem

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olMail Then
       Set objMail = objExplorer.Selection.Item(1)
    ElseIf TypeOf objExplorer.Selection.Item(1) Is ContactItem Then
       Set objContact = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail Then
       Set objMail = Inspector.CurrentItem
    ElseIf Inspector.CurrentItem.Class = olContact Then
       Set objContact = Inspector.CurrentItem
    End If
End Sub

Private Sub objMail_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objMail.IsMarkedAsTask = True Then
          If objMail.TaskDueDate <> "1/1/4501" Then
             With objMail
                  .ReminderSet = True
                  'Change the reminder time for flagged emails
                  .ReminderTime = objMail.TaskDueDate & " 10:00"
                  .Save
             End With
          End If
       End If
    End If
End Sub

Private Sub objContact_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objContact.IsMarkedAsTask = True Then
          If objContact.TaskDueDate <> "1/1/4501" Then
             With objContact
                  .ReminderSet = True
                  'Change the reminder time for flagged contacts
                  .ReminderTime = objContact.TaskDueDate & " 17:30"
                  .Save
             End With
          End If
       End If
    End If
End Sub

4. Pärast seda taaskäivitage Outlook selle makro aktiveerimiseks.
5. Nüüdsest määratakse iga kord, kui e-kirja märgistate, meeldetuletuse kellaajaks märgistamise tähtpäeval "10:00".
6. Ja kui märgistate kontakti, seatakse meeldetuletuse kellaajaks märgistamise tähtpäeval "17:30".

Lahendage Outlooki probleeme paindlikult

Outlookis võib esineda igasuguseid probleeme. Seega peate eelnevalt õppima mõned meetmed nende lahendamiseks. Näiteks kui teie Outlook taaskäivitub sageli, peate Office'i parandama või kolmanda osapoole lisandmoodulid keelama jne. Või kui teie Outlook PST satub ohtu, võite kõigepealt proovida järgmist. postkasti parandamise tööriist. Kui see ebaõnnestub, võite jätkata võimsa välise tööriista kasutamist, näiteks DataNumen Outlook Repair.

Autori sissejuhatus:

Shirley Zhang on andmete taastamise ekspert DataNumen, Inc., mis on maailmas juhtiv andmete taastamise tehnoloogiate, sealhulgas mdf taastamine ja Outlooki remonditarkvaratooted. Lisateabe saamiseks külastage www.datanumenCom