Kuidas oma Outlookis kõik lugemiskviitungid pakkides kustutada

Selleks, et kinnitada, et adressaadid on teie e-kirja lugenud, saate e-kirja kirjutamisel taotleda lugemisteatist. Sellisel juhul võib teie postkast olla selliseid lugemisteatisi täis. Nüüd õpetab see postitus teile, kuidas neid partiidena jäädavalt kustutada.

Pärast artikli lugemist "Kuidas oma Outlookis kõik saatekviitungid partiidena kustutada“, võite mõelda kõigi lugemiskviitungite hulgikustutamise lähenemisviisile. Tegelikult on kaht tüüpi kviitungite ilmselge erinevus nende teemades. Saatekviitung sisaldab teemas „Tarnitud”, kuid lugemiskviitung sisaldab selle asemel „Lugetud”. Seetõttu saate kõigi lugemiskviitungite pakkimiseks kustutada samamoodi. Järgnevalt õpetame teile üksikasjalikult konkreetseid samme.

Partii kustutamine kõik lugemiskviitungid

1. Alguses käivitage oma Outlook.
2. Seejärel minge Outlook VBA redaktorisse, kasutades "Alt + F11" vastavalt "Kuidas Outlookis VBA-koodi käivitada".
3. Järgmisena avage uues aknas tühi moodul ja sisestage sinna järgmine kood.

Dim objOutlookFile As Outlook.Folder

Sub BatchDeleteAllReadReceipts()
    Dim objStore As Outlook.Store
    Dim objFolder As Outlook.Folder
    Dim lTotalCount As Long
 
    lTotalCount = 0
   'Process all Outlook files
    For Each objStore In Outlook.Application.Session.Stores
        Set objOutlookFile = objStore.GetRootFolder
        For Each objFolder In objOutlookFile.Folders
            If objFolder.DefaultItemType = olMailItem Then
               Call ProcessFolders(objFolder, lTotalCount)
            End If
        Next
    Next
 
    'Prompt you of the results
    MsgBox lTotalCount & " read receipts are deleted!", vbInformation + vbOKOnly
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder, lCount As Long)
    Dim i As Long
    Dim objDeliveryReceipt As Outlook.ReportItem
    Dim objSubfolder As Outlook.Folder
    Dim objDeletedItems As Outlook.Items
    Dim objItem As Object
 
    For i = objCurrentFolder.Items.Count To 1 Step -1
        'Find read receipts
        If (TypeOf objCurrentFolder.Items(i) Is ReportItem) And (Left(objCurrentFolder.Items(i).Subject, 5) = "Read:") Then
           Set objDeliveryReceipt = objCurrentFolder.Items.Item(i)
           objDeliveryReceipt.Delete
 
           lCount = lCount + 1
 
           'Permanently delete them
           Set objDeletedItems = objOutlookFile.Folders("Deleted Items").Items
           For Each objItem In objDeletedItems
               If (TypeOf objItem Is ReportItem) And (Left(objItem.Subject, 5) = "Read:") Then
                  objItem.Delete
               End If
           Next
         End If
    Next
 
    'Loop subfolders recursively
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessFolders(objSubfolder, lCount)
       Next
    End If
End Sub

4. Pärast seda klõpsake esimest alamprogrammi.
5. Lõpuks vajutage klahvi "F5".
6. Makro hakkab korraga kustutama kõik lugemiskviitungid teie Outlookist.
7. Kui see on lõppenud, kuvatakse teile tulemuste kohta viip, nagu alloleval ekraanipildil.
8. Praegu saate oma meilikaustu kontrollida. Kõik lugemistšekid on kadunud.

Kaitske Outlooki andmeid

Kuigi Outlooki fail on ilmselt korruptsioonile vastuvõtlik, saame selle kaitsmiseks võtta meetmeid. Näiteks peaksime Outlooki faili hoidma väikese suurusega, kaitsma seda pahatahtlike tegurite eest ja varundama seda regulaarselt. Viimaseks, kuid mitte vähem tähtsaks, valmistage parem ette võimas väline PST-parandustööriist, näiteks DataNumen Outlook Repair. See avaldab parandamisele suurt mõju rikutud Outlook faili.

Autori sissejuhatus:

Shirley Zhang on andmete taastamise ekspert DataNumen, Inc., mis on maailmas juhtiv andmete taastamise tehnoloogiate, sealhulgas sql remont ja Outlooki remonditarkvaratooted. Lisateabe saamiseks külastage www.datanumenCom