Kuidas iga päev sissetulevate meilide koguarvu automaatselt Exceli faili salvestada

See artikkel õpetab teile, kuidas lubada Outlookil automaatselt loendama, kui palju meile iga päev saate, ja kirjutada see number Exceli faili.

Paljud kasutajad peavad loendama iga päev saabunud meilide koguarvu. Lisaks on paljud harjunud edaspidiseks mugavamaks kontrollimiseks koguarvu Exceli faili salvestama. Sel juhul saate loomulikult iga päev käsitsi lugeda ja salvestada. Siiski on see veidi tülikas. Ja mõnikord võite selle tegemise unustada. Seetõttu peate soovima mugavat meetodit, mis paneb Outlooki seda automaatselt tegema. Vastuseks sellele nõudele õpetame teile, kuidas VBA-d selle realiseerimiseks kasutada järgnevalt.

Salvestage iga päev sissetulevate meilide koguarv automaatselt Exceli faili

1. Käivitage kohe alguses oma Outlooki rakendus.
2. Seejärel vajutage Outlooki peaaknas klahvikombinatsiooni Alt + F11.
3. Järgmisena avage hüpikaknas VBA redaktori aknas projekt "ThisOutlookSession".
4. Seejärel kopeerige ja kleepige sellesse projekti järgmised VBA-koodid.

Private Sub Application_Reminder(ByVal Item As Object)
    If Item.Class = olTask And Item.Subject = "Update Email Count" Then
       Call GetAllInboxFolders
    End If
End Sub

Private Sub GetAllInboxFolders()
    Dim objInboxFolder As Outlook.Folder
    Dim strExcelFile As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim nNextEmptyRow As Integer
    Dim lEmailCount As Long
 
    lEmailCount = 0
    Set objInboxFolder = Outlook.Application.Session.GetDefaultFolder(olFolderInbox)
    Call UpdateEmailCount(objInboxFolder, lEmailCount)
 
    ‘Change the path to the Excel file
    strExcelFile = "E:\Email\Email Count.xlsx"
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Open(strExcelFile)
    Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
 
    nNextEmptyRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
 
    'Add the values into the columns
    objExcelWorksheet.Range("A" & nNextEmptyRow) = nNextEmptyRow - 1
    objExcelWorksheet.Range("B" & nNextEmptyRow) = Year(Date - 1) & "-" & Month(Date - 1) & "-" & Day(Date - 1)
    objExcelWorksheet.Range("C" & nNextEmptyRow) = lEmailCount
 
    'Fit the columns from A to C
    objExcelWorksheet.Columns("A:C").AutoFit
   
    'Save the changes and close the Excel file
    objExcelWorkbook.Close SaveChanges:=True
End Sub

Private Sub UpdateEmailCount(objFolder As Outlook.Folder, ByRef lCurEmailCount As Long)
    Dim objItems As Outlook.Items
    Dim objItem As Object
    Dim objMail As Outlook.MailItem
    Dim strDay As String
    Dim strReceivedDate As String
    Dim lEmailCount As Long
    Dim objSubFolder As Outlook.Folder
 
    Set objItems = objFolder.Items
 
    objItems.SetColumns ("ReceivedTime")
    strDay = Year(Date - 1) & "-" & Month(Date - 1) & "-" & Day(Date - 1)
 
    For Each objItem In objItems
        If objItem.Class = olMail Then
           Set objMail = objItem
           strReceivedDate = Year(objMail.ReceivedTime) & "-" & Month(objMail.ReceivedTime) & "-" & Day(objMail.ReceivedTime)
           If strReceivedDate = strDay Then
              lCurEmailCount = lCurEmailCount + 1
           End If
        End If
    Next
 
    'Process the subfolders in the folder recursively
    If (objFolder.Folders.Count > 0) Then
       For Each objSubFolder In objFolder.Folders
           Call UpdateEmailCount(objSubFolder, lCurEmailCount)
       Next
    End If
End Sub

5. Järgmisena allkirjastage see kood ja muutke oma Outlooki makro sätteid, et lubada allkirjastatud makrod.
6. Pärast seda peate looma iga päev korduva ülesande.

• Esiteks klõpsake ülesannete paanil nuppu "Uus ülesanne".
• Hüpikaknas Uus ülesanne klõpsake nuppu "Kordus".
• Seejärel valige järgmises dialoogiboksis "Iga päev", "Iga 1 päeva järel" ja "Lõppkuupäeva pole" ning vajutage lõpuks nuppu "OK".
• Hiljem muutke ülesande teemat ja meeldetuletust vastavalt oma vajadustele.
• Lõpuks klõpsake nuppu "Salvesta ja sulge".

7. Edaspidi loendab Outlook iga kord, kui selle ülesande meeldetuletuse hoiatab, eile saabunud e-kirjad automaatselt ja salvestab seejärel numbri Exceli faili, nagu järgmine ekraanipilt:

PST püsiva andmekao eest põgenemine

Keegi ei ole nõus leppima püsiva PST-andmete kadumisega. Outlooki PST-fail on aga korruptsiooniohtlik. Seetõttu peaksite võtma piisavalt ettevaatusabinõusid, näiteks tegema järjepideva ja ajakohase PST-andmete varukoopia ning hoidma võimsat PST taastamine tööriist läheduses, nagu DataNumen Outlook Repair.

Autori sissejuhatus:

Shirley Zhang on andmete taastamise ekspert DataNumen, Inc., mis on maailmas juhtiv andmete taastamise tehnoloogiate, sealhulgas sql remont ja Outlooki remonditarkvaratooted. Lisateabe saamiseks külastage www.datanumenCom