Kuidas automaatselt keelata hüperlingid tundmatutelt saatjatelt sissetulevates Outlooki meilides

Outlooki lahendused September 29, 2025

Pahatahtlike linkide blokeerimiseks konfigureerige oma Outlook paremini nii, et see keelaks automaatselt hüperlingid tundmatutelt saatjatelt saabuvates e-kirjades. See artikkel paljastab tüki VBA-koode, mis aitavad teil seda nagu korgist hankida.

Paljud kasutajad on kurtnud, et e-posti kaudu levivad viirused ründasid nende Outlooki faili. Enamasti on põhjuseks see, et nad usaldavad kergesti tundmatute saatjate e-kirju. Nii laadivad nad alla või klõpsavad meilides olevaid hüperlinke. Nüüd, edaspidi, jagame meetodit. See võimaldab Outlookil automaatselt keelata tundmatutelt saatjatelt saabuvate e-kirjade hüperlingid. Kui teil on selliseid vajadusi, lugege lisateabe saamiseks edasi.Automaatne keelake hüperlingid tundmatutelt saatjatelt sissetulevates Outlooki meilides

Hüperlingide automaatne keelamine tundmatutelt saatjatelt sissetulevates e-kirjades

  1. Alustuseks minge Outlookis VBA redaktorisse, kasutades klahvikombinatsiooni „Alt + F11”.
  2. Järgmisena lisa uuele ekraanile postituse kohaselt objekt „MS VBScript Regular Expressions”.Kuidas lisada VBA-s objektiteegi viidet".
  3. Seejärel kopeerige ja kleepige järgmine kood projekti "ThisOutlookSession".
Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
    Set objInboxItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

'Occurs when new mail arrives in your Inbox
Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
    Dim objMail As MailItem
    Dim objContacts As Outlook.Items
    Dim strFilter As String
    Dim objFoundContact As Outlook.ContactItem
    Dim bUnknownSender As Boolean
    Dim objRegExp As Object
    Dim objFoundResults As Object
    Dim i, n As Long
 
    If TypeOf Item Is MailItem Then
       Set objMail = Item
 
       'Check if the sender is in your default Contact folder
       Set objContacts = Application.Session.GetDefaultFolder(olFolderContacts).Items
       For i = 1 To 3
           strFilter = "[Email" & i & "Address] = " & objMail.SenderEmailAddress
           Set objFoundContact = objContacts.Find(strFilter)
           If Not (objFoundContact Is Nothing) Then
              bUnknownSender = False
              Exit For
           End If
       Next
       If objFoundContact Is Nothing Then
          bUnknownSender = True
       End If
 
       'If the sender is unknown
       If bUnknownSender = True Then
          'Find the urls within "<a href=" tags in HTMLbody of Mail
          Set objRegExp = CreateObject("vbscript.RegExp")
          With objRegExp
               .Pattern = "<?href\s*=\s*[""'].+?[""'][^>]*?"
               .IgnoreCase = True
               .Global = True
          End With
 
          If objRegExp.Test(objMail.HTMLBody) Then
             Set objFoundResults = objRegExp.Execute(objMail.HTMLBody)
             For n = 1 To objFoundResults.Count
                 'Disable the hyperlinks in HTMLbody
                 objMail.HTMLBody = Replace(objMail.HTMLBody, objFoundResults.Item(n - 1).Value, "")
             Next
          End If
 
          'Save the mail
          objMail.Save
       End If
    End If
End Sub

VBA kood – keelake automaatselt hüperlingid tundmatutelt saatjatelt sissetulevates e-kirjades

  1. Pärast seda aktiveerige see makro kas Outlooki taaskäivitamise või alamrutiinis „Application_Startup” klahvi „F5” vajutamise teel.
  2. Sellest ajast alates keelab Outlook iga kord, kui saatjalt pärit meilisõnum, mis ei ole vaikekausta kontaktide kaustas, kausta Inbox, selles sisalduvad hüperlingid automaatselt keelanud.Hüperlinkide automaatne keelamine

Mitmed Outlooki kaitse vajalikkuse küsimused

Kuna Outlook on kahjustuste suhtes vastuvõtlik, on Outlooki faili üsna raske kaitsta. Siin loetleme mitmed Outlooki andmekaitse ajal kohustuslikud toimingud. Esiteks peate oma Outlooki andmeid regulaarselt varundama. Lisaks on oluline olla ettevaatlik kõigi võimalike riskide, nagu pahatahtlikud manused või hüperlingid, eest. Viimaseks, kuid mitte vähem tähtsaks, peaksite eelnevalt ette valmistama võimsa Outlooki parandustööriista, näiteks DataNumen Outlook Repair. See tuleb kindlasti kasuks, kui vaja remont PST fail, kuid postkasti parandustööriist osutub ebaõnnestumiseks.

Autori sissejuhatus:

Shirley Zhang on andmete taastamise ekspert DataNumen, Inc., mis on maailmas juhtiv andmete taastamise tehnoloogiate, sealhulgas kahjustatud mdf ja Outlooki remonditarkvaratooted. Lisateabe saamiseks külastage www.datanumenCom

Kommentaarid on suletud.