2 võimalust erinevate kategooriatega Outlooki ülesannete loendite printimiseks erinevatel lehtedel

Kui olete oma Outlooki ülesannetele määranud erinevad värvikategooriad ja soovite nüüd printida erinevate kategooriatega ülesannete loendid erinevatel lehtedel, vaadake seda artiklit. Siin jagame teile 2 meetodit selle saamiseks.

Ülesannete klassifitseerimiseks ja hästi haldamiseks olete võib-olla rakendanud oma ülesannetele värvikategooriaid. Nüüd, kui soovite oma ülesannete loendid erinevate kategooriatega erinevatel lehtedel välja printida, lugege edasi. Järgnevalt tutvustame teile 2 võimalust selle saamiseks.

1. meetod: printige ülesannete loendid ükshaaval käsitsi

1. Kõigepealt avage Outlookis paan "Tasks".
2. Seejärel avage kaust Task.
3. Järgmisena vajutage lindi "Otsi" aktiveerimiseks "Ctrl + E".
4. Pärast seda klõpsake vahekaardil "Otsi" nuppu "Kategoriseeri".
5. Valige rippmenüüst värvikategooria.
6. Seejärel jäetakse loendisse ainult valitud kategooriaga ülesanded.
7. Nüüd minge selle ülesannete loendi printimiseks jaotisesse "Fail" > "Prindi".
8. Seejärel printige samal viisil käsitsi ükshaaval välja teiste värvikategooriatega ülesannete loendid.

2. meetod: ülesannete loendite partii printimine VBA abil

1. Kohe alguses käivitage VBA redaktor vastavalt "Kuidas Outlookis VBA-koodi käivitada".
2. Seejärel lisage viide „MS Exceli objektiteegile” vastavalt jaotisele „Kuidas lisada VBA-s objektiteegi viidet".
3. Järgmisena kopeerige järgmine VBA kood moodulisse.

Sub PrintTaskList_SpecificColorCategory()
    Dim objTasks As Outlook.Items
    Dim objTask As Outlook.TaskItem
    Dim objDictionary As Object
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim varKey As Variant
    Dim strKey As String
    Dim i As Long
    Dim bSheetFound As Boolean
    Dim nLastRow As Integer
    Dim objSheet As Excel.Worksheet
 
    Set objTasks = Application.Session.GetDefaultFolder(olFolderTasks).Items
    Set objDictionary = CreateObject("Scripting.Dictionary")
 
     'Get All Tasks' Categories
    For Each objTask In objTasks
        arrCategory = Split(objTask.Categories, ",")
        For Each varCategory In arrCategory
            If objDictionary.Exists(Trim(varCategory)) = False Then
               objDictionary.Add Trim(varCategory), 0
            End If
        Next
    Next
 
    'Export the Tasks with Different Categories into Different Sheet in an Excel Workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    objExcelApp.Visible = True
 
    i = 0
    For Each varKey In objDictionary.Keys
        strKey = CStr(varKey)

        On Error Resume Next
        objExcelWorkbook.Sheets(strKey).Select
        bSheetFound = (Err = 0)
        On Error GoTo 0
        If bSheetFound = False Then
           i = i + 1
           If i < 4 Then
              Set objExcelWorksheet = objExcelWorkbook.Sheets(i)
           Else
              Set objExcelWorksheet = objExcelWorkbook.Sheets.Add(After:=objExcelWorkbook.Sheets(objExcelWorkbook.Sheets.Count))
           End If
           objExcelWorksheet.Name = strKey
        End If
 
        With objExcelWorksheet
             .Cells(1, 1) = strKey
             .Cells(1, 1).Font.Bold = True
             .Cells(1, 1).Font.Size = 18
             .Cells(2, 1) = "Subject"
             .Cells(2, 1).Font.Bold = True
             .Cells(2, 2) = "Start Date"
             .Cells(2, 2).Font.Bold = True
             .Cells(2, 3) = "Due Date"
             .Cells(2, 3).Font.Bold = True
        End With
 
        For Each objTask In objTasks
            If InStr(objTask.Categories, strKey) > 0 Then
               nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
               With objExcelWorksheet
                    .Range("A" & nLastRow) = objTask.Subject
                    .Range("B" & nLastRow) = objTask.startDate
                    .Range("C" & nLastRow) = objTask.DueDate
               End With
            End If
        Next
 
        objExcelWorksheet.Columns("A:C").AutoFit
    Next
 
    'Print out All Sheets in this Excel Workbook
    For Each objSheet In objExcelWorkbook.Sheets
        objSheet.PrintOut
    Next
 
    objExcelWorkbook.Close False
    objExcelApp.Quit
End Sub

4. Seejärel vajutage selle makro koheseks käivitamiseks klahvi F5.
5. Kui makro on lõppenud, prinditakse erinevate kategooriatega ülesannete loendid erinevatele lehtedele, nagu on näidatud järgmisel ekraanipildil.

Hankige kahjustatud PST-failist väärtuslikud andmed tagasi

Kui teie jaoks on juurdepääsematu PST-fail, on teie järgmine samm kahtlemata PST remont. Sel juhul võite esmalt proovida postkasti parandamise tööriista. Kui see ebaõnnestub, võite proovida mõnda muud välist tööriista, näiteks DataNumen Outlook Repair. See suudab PST-andmeid kiiresti taastada.

Autori sissejuhatus:

Shirley Zhang on andmete taastamise ekspert DataNumen, Inc., mis on maailmas juhtiv andmete taastamise tehnoloogiate, sealhulgas taastada mdf ja Outlooki remonditarkvaratooted. Lisateabe saamiseks külastage www.datanumenCom