2 kiiret viisi oma Wordi dokumendist osade eraldamiseks

Selles artiklis pakume teile kahte kiiret ja lihtsat viisi oma Wordi dokumendist jaotiste eraldamiseks mõnda teise või mitmesse.

Üsna sageli juhtub, et sisu eraldatakse ühest dokumendist teise. Ja meie eelmises artiklis oleme arutanud, kuidas dokumendist lehti eraldada. Üksikasjaliku teabe saamiseks vaadake seda artiklit: 2 kiiret viisi Wordi dokumendist üksikute lehtede eraldamiseks

Täna näitame teile, kuidas jaotiste kaupa ekstraktida.    

1. meetod: ekstraheerige praegune jaotis uueks dokumendiks

1. Esiteks asetage kursor sihtrühma.
2. Järgmisena vajutage Wordis VBA redaktori käivitamiseks klahvikombinatsiooni Alt + F11.
3. Seejärel klõpsake vasakpoolses veerus "Tavaline".
4. Ja menüüribal klõpsake nuppu "Lisa".
5. Seejärel valige rippmenüüst "Moodul".
6. Topeltklõpsake uue mooduli avamiseks ja kleepige sinna järgmised koodid:

Sub SaveCurrentSectionAsNewDoc()
  Dim strFolder As String
  Dim dlgFile As FileDialog
  Dim strNewFileName As String
  Dim objDocAdded As Document
  Dim objDoc As Document
 
  ' Initialization
  Set objDoc = ActiveDocument
 
  ' Pick a place to store the new file.
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      strFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first!"
      Exit Sub
    End If
  End With
 
  strNewFileName = InputBox("Enter new file name here: ", "File Name")
 
  ' Select and copy current section range.
  objDoc.Bookmarks("\Section").Range.Select
  Selection.Copy
 
  ' Open a new document to paste the above selection.
  Set objDocAdded = Documents.Add
  Selection.Paste
 
  ' Save and close the new document.
  objDocAdded.SaveAs FileName:=strFolder & strNewFileName & ".docx"
  objDocAdded.Close
End Sub

7. Järgmisena klõpsake menüüribal "Käivita" või vajutage "F5".
8. Seejärel avaneb aken "Sirvi". Valige uue dokumendi salvestamise koht ja klõpsake "OK".
9. Ja väljale "Faili nimi" sisestage uue faili nimi ja klõpsake "OK".

Nüüd olete selle jaotise uude dokumenti ekstraheerinud.

2. meetod: eraldage dokumendist iga jaotis üksikutele uutele

See viis aitab teil dokumendi kõiki jaotisi pakiliselt töödelda. Muidugi vajame ka makrot.

1. Alustuseks avage sihtdokument.
2. Seejärel järgige makro installimiseks ja käivitamiseks meetodi 1 samme.
3. Ainult seekord asendage see makro selle makroga:

Sub SaveEachSectionAsADoc()
  Dim objDocAdded As Document
  Dim objDoc As Document
  Dim nSectionNum As Integer
  Dim strFolder As String

  Dim dlgFile As FileDialog
 
  ' Initialization
  Set objDoc = ActiveDocument
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  ' Pick a location to keep new files.
  With dlgFile
    If .Show = -1 Then
      strFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first!"
      Exit Sub
    End If
  End With
 
  ' Step through each section in current document, copy and paste each to a new one.
  For nSectionNum = 1 To ActiveDocument.Sections.Count
    Selection.GoTo What:=wdGoToSection, Which:=wdGoToNext, Name:=nSectionNum
    ActiveDocument.Sections(nSectionNum).Range.Copy
 
    Set objDocAdded = Documents.Add
    Selection.Paste
 
    ' Save and close new documents.
    objDocAdded.SaveAs FileName:=strFolder & "Section " & nSectionNum & ".docx"
    objDocAdded.Close
  Next nSectionNum
End Sub

4. Siiski valige aknas "Sirvi" salvestustee ja klõpsake "OK".

Parandage ärritavad sõnavead

Selle kasutamise ajal kohtab sageli mõningaid Wordi tõrkeid. See võib olla tüütu, selleks peame võtma aega sõna taastama niipea kui võimalik. Sest mida kauem me sellega viivitame, seda suurem on andmete kadu. Seetõttu on soovitatav eelnevalt hankida remondiutiliit.

Autori sissejuhatus:

Vera Chen on andmete taastamise ekspert DataNumen, Inc., mis on maailmas juhtiv andmete taastamise tehnoloogiate, sealhulgas rikutud xls ja pdf tarkvaratooted. Lisateabe saamiseks külastage www.datanumenCom