Cómo exportar rápidamente un correo electrónico de Outlook como un archivo de imagen

A algunos usuarios les gustaría exportar un correo electrónico de Outlook como un archivo de imagen, como un archivo jpg. Por lo tanto, en este artículo, le presentaremos cómo obtenerlo a través del código VBA de Outlook.

Debe haber aprendido una variedad de trucos para exportar un correo electrónico como archivo de texto, documento de Word, etc. Entonces, ¿qué tal exportar un correo electrónico como una imagen como un archivo JPG? Aparentemente, Outlook no tiene esta función. Pero, a continuación, compartiremos un medio rápido con usted.

Exportar rápidamente un correo electrónico de Outlook como un archivo de imagen

1. Para empezar, abre tu aplicación Outlook.
2. Luego, en la ventana principal de Outlook, obtenga acceso al editor de VBA de acuerdo con el artículo - "Cómo ejecutar código VBA en su Outlook.
3. A continuación, habilite “Biblioteca de objetos de MS Word” y “MS PowerPoint Biblioteca de objetos” haciendo referencia al artículo – “Cómo agregar una referencia a una biblioteca de objetos en VBA.
4. A continuación, copie y pegue el siguiente código VBA en un módulo en blanco.

Sub ExportEmailAsImage()
    Dim objMail As Outlook.MailItem
    Dim strFileName As String
    Dim strWordDocument As String
    Dim objWordApp As Word.Application
    Dim objWordDocument As Word.Document
    Dim objDocumentRange As Word.Range
    Dim objPowerPointApp As PowerPoint.Application
    Dim objPresentation As PowerPoint.Presentation
    Dim objShape As PowerPoint.Shape
 
    On Error Resume Next
    'Export the email as Word document
    Set objMail = Outlook.Application.ActiveExplorer.Selection(1)
    strFileName = Replace(objMail.Subject, "/", " ")
    strFileName = Replace(strFileName, "\", " ")
    strFileName = Replace(strFileName, ":", "")
    strFileName = Replace(strFileName, "?", " ")
    strFileName = Replace(strFileName, Chr(34), " ")
    strWordDocument = Environ("Temp") & "\" & strFileName & ".doc"
 
    objMail.SaveAs strWordDocument, olDoc

    Set objWordApp = CreateObject("Word.Application")
    Set objWordDocument = objWordApp.Documents.Open(strWordDocument)
    objWordApp.Visible = True
 
    objWordApp.Selection.Find.ClearFormatting
    objWordApp.Selection.Find.Replacement.ClearFormatting
 
    With objWordApp.Selection.Find
        .Text = "^p^p"
        .Replacement.Text = "^p"
        .Wrap = wdFindContinue
    End With
 
    'Insert the document into a PowerPoint Presentation slide as an object
    objWordApp.Selection.Find.Execute Replace:=wdReplaceAll
    Set objDocumentRange = objWordDocument.Range()
    objDocumentRange.Font.Name = "Calibri"
    objDocumentRange.Font.Size = 10
    objWordDocument.Close True
    objWordApp.Quit
 
    Set objPowerPointApp = CreateObject("PowerPoint.Application")
    Set objPresentation = objPowerPointApp.Presentations.Add
    objPowerPointApp.Visible = msoTrue
 
    With objPresentation
        .PageSetup.SlideHeight = 792
        .PageSetup.SlideWidth = 612
        .Slides.AddSlide 1, .SlideMaster.CustomLayouts(1)
    End With
 
    'Export the slide
    With objPresentation.Slides(1)
         Set objShape = .Shapes.AddOLEObject(0, 0, 612, 792, , strWordDocument)
        .Export "E:\Email_" & strFileName & ".jpg", "JPG"
    End With
 
    objPresentation.Saved = msoTrue
    objPresentation.Close
    objPowerPointApp.Quit
End Sub

5. Después de eso, debe agregar la macro a la barra de herramientas de acceso rápido.
6. Posteriormente, podría cerrar el editor de VBA.
7. Más tarde, seleccione un correo electrónico y presione el botón de macro en la barra de herramientas de acceso rápido.
8. Cuando se complete la macro, puede ir a la carpeta local predefinida para encontrar el archivo de imagen exportado de este correo electrónico.

Recuperar datos de Outlook de un archivo dañado

Puede resultar muy frustrante si su archivo de Outlook sufre daños graves. En ese caso, deberá extraer los datos de Outlook del archivo dañado. Algunos usuarios optan por utilizar la herramienta de reparación de la bandeja de entrada. Sin embargo, en la mayoría de los casos, no surte efecto. Por lo tanto, es mejor contar con una solución robusta y confiable. Corrección de PST herramienta, como DataNumen Outlook Repair. Puede escanear el archivo dañado y recuperar el máximo de datos sin problemas.

Introducción del autor:

Shirley Zhang es experta en recuperación de datos en DataNumen, Inc., que es el líder mundial en tecnologías de recuperación de datos, incluyendo arreglar mdf y productos de software de reparación de Outlook. Para más información visite www.datanumen.com