Cómo evitar el envío de correos electrónicos a una dirección de correo electrónico específica en su Outlook

Muchos usuarios esperan bloquear el envío accidental de correos electrónicos a una dirección de correo electrónico específica en Outlook. Por lo tanto, en este artículo, presentaremos un método para realizarlo.

Outlook no ofrece funciones nativas para bloquear el envío de correos electrónicos a una dirección de correo electrónico específica. Por lo tanto, si desea lograrlo, se requiere un poco de programación. A continuación, compartiremos un fragmento de código VBA. Si no sabe cómo usar VBA, puede leer la publicación anterior:Cómo ejecutar código VBA en su Outlook".

Evite el envío de correos electrónicos a una dirección de correo electrónico específica

1. Al principio, acceda al editor de Outlook VBA a través de "Alt + F11".
2. Luego, coloque el siguiente código en el proyecto "ThisOutlookSession".

Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
    Dim objMail As Outlook.MailItem
    Dim objRecipients As Outlook.Recipients
    Dim ContactGroupFound As Boolean
    Dim i, n As Long
    Dim objRecipient As Outlook.Recipient
 
    If TypeOf Item Is MailItem Then
       Set objMail = Item
 
       'Expand the contact groups in Recipients
       ContactGroupFound = True
       Do While ContactGroupFound = True
          Set objRecipients = objMail.Recipients
          ContactGroupFound = False
 
          For i = objRecipients.Count To 1 Step -1
              If objRecipients(i).AddressEntry.DisplayType <> olUser Then
                 For n = 1 To objRecipients(i).AddressEntry.Members.Count
                     If objRecipients(i).AddressEntry.Members.Item(n).DisplayType = olUser Then
                        objMail.Recipients.Add (objRecipients(i).AddressEntry.Members.Item(n).Address)
                     Else
                        objMail.Recipients.Add (objRecipients(i).AddressEntry.Members.Item(n).Name)
                        ContactGroupFound = True
                     End If
                 Next
                 objRecipients(i).Delete
              End If
          Next i
          objRecipients.ResolveAll
       Loop
 
       'Remove specific email address
       For Each objRecipient In objRecipients
           If objRecipient.Address = "shelly@datanumen.com" Then
              If MsgBox("Do you want to email to " & Chr(34) & "shelly@datanumen.com" & Chr(34) & "?", vbExclamation + vbYesNo) = vbNo Then
                 objRecipient.Delete
              End If
           End If
       Next
    End If
End Sub

3. Después de eso, salga de la ventana "Microsoft Visual Basic para Aplicaciones".
4. Eventualmente, pruébelo siguiendo los siguientes pasos.

• Para empezar, redacte un correo electrónico y complete los destinatarios.
• Luego, haga clic en el botón "Enviar".
• De inmediato, la macro funcionará para expandir los grupos de contactos en los destinatarios, si los hay, y averiguar si los destinatarios contienen la dirección de correo electrónico específica.
• Si se encuentra la dirección, recibirá un mensaje, como se muestra en la siguiente figura.
• Si selecciona "No", la dirección de correo electrónico específica se eliminará inmediatamente.
• Una vez que se envía el correo, puede verificar sus destinatarios, que definitivamente no contienen la dirección de correo electrónico específica.

Repare su archivo de Outlook dañado

¿Alguna vez se ha dañado tu archivo de Outlook? Sin duda, ese es uno de los problemas más molestos de Outlook. Cuando te encuentras en esta situación, tienes que manipular Reparación de PST, que es un poco complicado. Como de costumbre, pensará en utilizar Scanpst la primera vez. Pero, desafortunadamente, puede fallar en tales casos. Su resort debe ser una herramienta con más experiencia, como DataNumen Outlook Repairo servicio profesional de recuperación de PST.

Introducción del autor:

Shirley Zhang es experta en recuperación de datos en DataNumen, Inc., que es el líder mundial en tecnologías de recuperación de datos, incluyendo reparación de sql y productos de software de reparación de Outlook. Para más información visite www.datanumen.com