Cómo establecer diferentes tiempos de recordatorio predeterminados para diferentes tipos de elementos marcados en Outlook

De forma predeterminada, Outlook utilizará automáticamente el tiempo de recordatorio predeterminado de las tareas para todo tipo de elementos marcados. Sin embargo, si desea utilizar un tiempo de recordatorio diferente para los elementos marcados en función del tipo de elemento, puede consultar el método presentado en este artículo.

Outlook le permite establecer un tiempo de recordatorio predeterminado para todos los elementos marcados, independientemente del tipo de elemento. Puede ir al menú "Archivo" y hacer clic en "Opciones". Luego, en la ventana "Opciones de Outlook", puede ver la opción "Hora de recordatorio predeterminada" en la pestaña "Tareas", como se muestra en la siguiente captura de pantalla.

Sin embargo, la mayoría de los usuarios prefieren usar diferentes horas de recordatorio para distintos tipos de elementos marcados, como las 9:00 para correos electrónicos marcados y las 17:30 para contactos marcados. A continuación, nos centraremos en este ejemplo para presentar un método.

Establecer un tiempo de recordatorio predeterminado diferente para diferentes tipos de elementos marcados

1. Para empezar, abre la aplicación Outlook.
2. Luego, acceda al editor de Outlook VBA con referencia a "Cómo ejecutar código VBA en su Outlook".
3. En la siguiente ventana de "Microsoft Visual Basic para Aplicaciones", copie el siguiente código en el proyecto "ThisOutlookSession".

Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objMail As Outlook.MailItem
Public WithEvents objContact As Outlook.ContactItem

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olMail Then
       Set objMail = objExplorer.Selection.Item(1)
    ElseIf TypeOf objExplorer.Selection.Item(1) Is ContactItem Then
       Set objContact = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail Then
       Set objMail = Inspector.CurrentItem
    ElseIf Inspector.CurrentItem.Class = olContact Then
       Set objContact = Inspector.CurrentItem
    End If
End Sub

Private Sub objMail_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objMail.IsMarkedAsTask = True Then
          If objMail.TaskDueDate <> "1/1/4501" Then
             With objMail
                  .ReminderSet = True
                  'Change the reminder time for flagged emails
                  .ReminderTime = objMail.TaskDueDate & " 10:00"
                  .Save
             End With
          End If
       End If
    End If
End Sub

Private Sub objContact_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objContact.IsMarkedAsTask = True Then
          If objContact.TaskDueDate <> "1/1/4501" Then
             With objContact
                  .ReminderSet = True
                  'Change the reminder time for flagged contacts
                  .ReminderTime = objContact.TaskDueDate & " 17:30"
                  .Save
             End With
          End If
       End If
    End If
End Sub

4. Después, reinicie Outlook para activar esta macro.
5. A partir de ahora, cada vez que marque un correo electrónico, la hora del recordatorio se establecerá en "10:00" en la fecha de vencimiento de la bandera.
6. Y cuando marca un contacto, la hora del recordatorio se establecerá en “17:30” en la fecha de vencimiento de la marca.

Aborde los problemas de Outlook de manera flexible

Puedes encontrarte con todo tipo de problemas en tu Outlook. Por lo tanto, debes aprender algunas medidas para lidiar con ellos de antemano. Por ejemplo, si tu Outlook se reinicia con frecuencia, necesitas reparar Office o deshabilitar los complementos de terceros, etc. O si tu archivo PST de Outlook se ve comprometido, puedes intentar primero... herramienta de reparación de la bandeja de entrada. Cuando falla, puedes seguir recurriendo a una poderosa herramienta externa, como DataNumen Outlook Repair.

Introducción del autor:

Shirley Zhang es experta en recuperación de datos en DataNumen, Inc., que es el líder mundial en tecnologías de recuperación de datos, incluyendo recuperación de mdf y productos de software de reparación de Outlook. Para más información visite www.datanumen.com