Cómo extraer automáticamente imágenes incrustadas de correos electrónicos entrantes específicos a través de Outlook VBA

Si desea que Outlook extraiga automáticamente y guarde las imágenes incrustadas de los correos electrónicos entrantes específicos, puede consultar este artículo. Aquí te enseñaremos cómo realizarlo con código VBA.

Algunos usuarios con frecuencia necesitan extraer las imágenes incrustadas de los correos electrónicos entrantes específicos y guardarlas en una determinada carpeta de Windows. Es muy problemático hacerlo manualmente cada vez. Por lo tanto, muchos esperan aprender un enfoque rápido y conveniente para permitir que Outlook lo haga automáticamente. Ahora, aquí compartiremos este método con usted.

Extraer automáticamente imágenes incrustadas de correos electrónicos entrantes específicos

1. En primer lugar, inicie su programa Outlook como de costumbre.
2. Luego, active el editor de Outlook VBA como de costumbre con la referencia t "Cómo ejecutar código VBA en su Outlook".
3. Más tarde, copie y pegue el siguiente código VBA en el proyecto "ThisOutlookSession".

Public WithEvents objInbox As Outlook.Folder
Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
    Set objInbox = Outlook.Application.Session.GetDefaultFolder(olFolderInbox)
    Set objInboxItems = objInbox.Items
End Sub

Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
    Dim objMail As Outlook.MailItem
    Dim objAttachments As Outlook.Attachments
    Dim objAttachment As Outlook.Attachment
    Dim strWindowsFolder As String
    Dim i As Long
 
    If TypeOf Item Is MailItem Then
       Set objMail = Item
 
       'Specify the emails as per your needs
       If objMail.Importance = olImportanceHigh Then
          Set objAttachments = objMail.Attachments
 
          'Specify the windows folder
          strWindowsFolder = "E:\" & objMail.Subject & Format(Now, "yymmddhhmmss")
          MkDir (strWindowsFolder)
 
          'Save all embedded images to the folder
          For i = 1 To objAttachments.Count
              Set objAttachment = objAttachments.Item(i)
              If IsEmbedded(objAttachment) = True Then
                 objAttachment.SaveAsFile strWindowsFolder & "\" & objAttachment.FileName
              End If
          Next
      End If
    End If
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.PropertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.PropertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

4. Después de eso, haga clic en la subrutina “Application_Startup”.
5. Finalmente, haga clic en la tecla "F5" para activar esta macro.
6. A partir de ahora, cada vez que llegue un nuevo correo electrónico específico a la Bandeja de entrada, las imágenes incrustadas se guardarán en la carpeta específica de Windows, como se muestra en la siguiente captura de pantalla.

Limpiar archivos adjuntos grandes con regularidad

Es recomendable limpiar periódicamente los archivos adjuntos grandes de Outlook. Esto ayuda a mantener el tamaño adecuado del archivo. Los archivos de Outlook más grandes son más propensos a dañarse. Como sabe, los daños en los archivos PST son difíciles de solucionar. Quizás intente repararlos primero con una herramienta de reparación de la bandeja de entrada. Sin embargo, en la mayoría de los casos, no funcionará. Su única opción es un servicio especializado. Reparación de PST herramienta, como DataNumen Outlook Repair, o servicios de recuperación profesionales relevantes.

Introducción del autor:

Shirley Zhang es experta en recuperación de datos en DataNumen, Inc., que es el líder mundial en tecnologías de recuperación de datos, incluyendo arreglar mdf y productos de software de reparación de Outlook. Para más información visite www.datanumen.com