Jak rychle najít odstavce s jednou větou v dokumentu Word

V tomto příspěvku vám chceme ukázat rychlý způsob, jak najít všechny jednovětné odstavce v dokumentu Word pomocí VBA.

Občas mohou mít některé dokumenty velmi specifické požadavky na formátování a strukturu. Například vám nemusí být povoleno mít odstavce pouze s jednou větou. Tyto odstavce není těžké rozpoznat, ale vyžaduje to čas, zvláště je to dlouhý dokument.

Dnes vám nabídneme rychlý způsob, jak určit všechny odstavce s jednou větou v dokumentu.

Najděte všechny odstavce s jednou větou v jednom dokumentu

1. Nejprve Word počítá tečku jako větu. Pokud tedy existují slova jako „Mr.“ nebo „Paní“, Word to považuje za větu. Chcete-li takové rozptýlení vyloučit, musíte nahradit „Mr.“ s „panem“. A když dokončíte vyhledání odstavce jedné věty, můžete je změnit zpět. Chcete-li nahradit slova, můžete použít tento odkaz: Jak najít a nahradit více položek v dokumentu Word
2. Poté stiskněte „Alt + F11“ a spusťte editor VBA.
3. Poté klikněte na „Normální“ projekt.
4. Na panelu nabídek klikněte na kartu „Vložit“ a v rozevírací nabídce vyberte „Modul“.
5. Dalším dvojitým kliknutím otevřete modul.
6. Vložte následující kódy do modulu:

Sub HighlightParagraphsWithSingleSentence()
  Dim nParagraphNum As Integer
  Dim nCountParagraph As Integer
  Dim objParagraphRange As Range
  Dim nCountSentence As Integer
  Dim nHighlightNum As Integer
 
  nCountParagraph = ActiveDocument.Paragraphs.Count
  nHighlightNum = 0
 
  For nParagraphNum = 1 To nCountParagraph
    Set objParagraphRange = ActiveDocument.Paragraphs(nParagraphNum).Range
    nCountSentence = objParagraphRange.Sentences.Count
    ' Highlight all paragraphs with single-sentence.
    If nCountSentence = 1 And objParagraphRange.Characters.Count > 1 Then
      nHighlightNum = nHighlightNum + 1
      objParagraphRange.HighlightColorIndex = wdYellow
    End If
  Next

  If nHighlightNum > 0 Then
    MsgBox ("There are " & nHighlightNum & " paragraphs with single sentence and they are highlighted.")
  Else
    MsgBox ("There are no paragraphs with single sentence")
  End If

End Sub

7. V neposlední řadě klikněte na tlačítko „Spustit“ nebo stiskněte „F5“.

Obdržíte takovou zprávu se zprávou, že práce je hotová.

Najděte všechny odstavce s jednou větou ve více dokumentech

1. Nejprve musíte umístit všechny cílové dokumenty do složky.
2. Poté nainstalujte a spusťte následující makro:

Sub HighlightParagraphsWithSingleSentenceInMultipleFiles()
  Dim nParagraphNum As Integer
  Dim nCountParagraph As Integer
  Dim objParagraphRange As Range
  Dim nCountSentence As Integer
  Dim StrFolder As String
  Dim strFile As String
  Dim objDoc As Document
  Dim dlgFile As FileDialog
  Dim nHighlightNum As Integer
  Dim strSummary As String

  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)

  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox ("No Folder is selected!")
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.doc*", vbNormal)
 
  While strFile <> ""
    nHighlightNum = 0
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    Set objDoc = ActiveDocument
    nCountParagraph = ActiveDocument.Paragraphs.Count
 
    For nParagraphNum = 1 To nCountParagraph
      Set objParagraphRange = ActiveDocument.Paragraphs(nParagraphNum).Range
      nCountSentence = objParagraphRange.Sentences.Count
      ' Highlight all paragraphs with single-sentence.
      If nCountSentence = 1 And objParagraphRange.Characters.Count > 1 Then
        nHighlightNum = nHighlightNum + 1
        objParagraphRange.HighlightColorIndex = wdYellow
      End If
    Next
    objDoc.ActiveWindow.ActivePane.View.SeekView = wdSeekMainDocument
    objDoc.Save
    If nHighlightNum = 0 Then
      objDoc.Close
    End If
 
    strSummary = strSummary & strFile & " : " & nHighlightNum & " paragraphs with single sentence." & vbCrLf
    strFile = Dir()
  Wend
  MsgBox (strSummary)
 
End Sub

3. V otevřeném okně „Procházet“ vyberte složku, ve které uchováváte dokumenty, a klikněte na „OK“.

Makro poté zvýrazní všechny odstavce s jednou větou a ponechá dokumenty otevřené. Pokud dokument neobsahuje odstavec s jednou větou, bude uzavřen. Kromě toho je zde okno se zprávou označující počet odstavců s jednou větou v každém dokumentu.

Řešení incidentu ztráty dat

Chyby uživatelů a náhlý výpadek napájení mohou mít za následek smrt Wordu. Zatímco složený Word může nejen ovlivnit každodenní práci, ale také vést k poškození dokumentuTohle rozhodně není ta nejnepříjemnější část datové katastrofy. Je lepší si nechat data okamžitě obnovit pomocí opravného nástroje.

Úvod autora:

Vera Chen je expertka na obnovu dat DataNumen, Inc., která je světovým lídrem v oblasti technologií pro obnovu dat, včetně obnovit Excel a pdf opravy softwarových produktů. Pro více informací navštivte www.datanumen.com