Jak rychle exportovat všechny hypertextové odkazy ve více e-mailech aplikace Outlook do aplikace Excel

Pokud potřebujete extrahovat všechny hypertextové odkazy z jednoho nebo více e-mailů, je hloupé je kopírovat jeden po druhém. Tento příspěvek vás naučí metodu, jak rychle exportovat všechny hypertextové odkazy z mnoha e-mailů do Excelu.

Z některých důvodů, například přihlašování hypertextových odkazů do všech odeslaných e-mailů, budete muset hypertextové odkazy extrahovat. Bez jakýchkoli pochybností se nedoporučuje ručně je extrahovat a kopírovat. Musíte toužit po mnohem chytřejším přístupu, jako je používání VBA. Zde vám sdílíme takový kousek kódu VBA, který je schopen exportovat všechny hypertextové odkazy v mnoha e-mailech do aplikace Excel jednoduchým kliknutím.

Exportujte všechny hypertextové odkazy ve více e-mailech do aplikace Excel

1. Nejprve spusťte program Outlook jako obvykle.
2. Poté v okně aplikace Outlook musíte stisknout tlačítka „Alt + F11“.
3. Najednou získáte přístup k editoru Outlook VBA.
4. Následně je třeba povolit „Knihovnu objektů Microsoft Word“ a také „Knihovnu objektů Microsoft Excel“. Klikněte na „Nástroje“ > „Odkazy“ a poté je v rozbalovacím dialogovém okně povolit.
5. Dále musíte otevřít nepoužívaný modul, ve kterém musíte zkopírovat níže uvedený kód VBA do tohoto modulu.

Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportAllHyperlinksInMultipleEmailsToExcel()
    Dim objSelection As Selection
    Dim objMail As MailItem
    Dim objMailDocument As Document
    Dim objHyperlink As Hyperlink
    Dim i As Long
 
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
 
    If Not (objSelection Is Nothing) Then
 
       Set objExcelApp = CreateObject("Excel.Application")
       Set objExcelWorkbook = objExcelApp.Workbooks.Add
       Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
       objExcelApp.Visible = True
       objExcelWorkbook.Activate
 
       With objExcelWorksheet
            .Cells(1, 1) = "No."
            .Cells(1, 2) = "Displaying Text"
            .Cells(1, 3) = "Address"
            .Cells(1, 4) = "Source Mail"
      End With
 
      On Error Resume Next
      i = 0
      For Each objMail In objSelection
          objMail.Display
          Set objMailDocument = objMail.GetInspector.WordEditor
          If objMailDocument.Hyperlinks.Count > 0 Then
             For Each objHyperlink In objMailDocument.Hyperlinks
                 If InStr(objHyperlink.Address, "www.") > 0 Then
                    i = i + 1
                    Call ExportToExcel(i, objMail, objHyperlink)
                 End If
             Next
          End If
          objMail.Close olDiscard
      Next
 
      objExcelWorksheet.Columns("A:D").AutoFit
    End If
End Sub

Sub ExportToExcel(n As Long, objCurrentMail As MailItem, objCurrentHyperlink As Hyperlink)
    Dim nLastRow As Integer
 
    nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
 
    objExcelWorksheet.Range("A" & nLastRow) = n
    objExcelWorksheet.Range("B" & nLastRow) = objCurrentHyperlink.TextToDisplay
    objExcelWorksheet.Range("C" & nLastRow) = objCurrentHyperlink.Address
    objExcelWorksheet.Range("D" & nLastRow) = objCurrentMail.Subject
End Sub

6. Poté můžete opustit aktuální okno editoru VBA.
7. Později otevřete „Možnosti aplikace Outlook“ a přizpůsobte panel nástrojů Rychlý přístup tak, abyste přidali nově přidané makro na panel nástrojů Rychlý přístup.
8. Nakonec můžete pořídit snímek:

• Nejprve vyberte v seznamu e-mailů e-maily, jejichž hypertextové odkazy chcete extrahovat.
• Poté klikněte na tlačítko makra na panelu nástrojů Rychlý přístup.
• Po dokončení makra získáte soubor aplikace Excel, jako je obrázek níže:

Opravte neočekávané problémy s Outlookem

Problémy s Outlookem se mohou čas od času vyskytnout bez jakýchkoli varovných znamení. Pokud se však jedná o drobné chyby, Outlook lze opravit jednoduchým restartem nebo jeho... nástroj pro opravu doručené pošty. Ale pokud narazíte na vážné potíže, vnitřní prostředky nebudou mít účinek. V tomto okamžiku je vaše poslední možnost rozhodně spolehlivější a robustnější nástroj, jako je DataNumen Outlook Repair.

Úvod autora:

Shirley Zhang je expertem na obnovu dat DataNumen, Inc., která je světovým lídrem v oblasti technologií pro obnovu dat, včetně poškozený mdf a výhledové softwarové produkty pro opravy. Pro více informací navštivte www.datanumen.com