Jak rychle zkopírovat strukturu složek z jednoho souboru PST aplikace Outlook do druhého prostřednictvím jazyka VBA

Chcete-li zkopírovat strukturu složek z jednoho souboru PST aplikace Outlook do jiného, ​​můžete použít metodu uvedenou v tomto článku, která vás naučí, jak používat VBA, abyste ji získali najednou.

Možná jste za účelem lepší správy e-mailů vytvořili několik vlastních složek v hlavním souboru aplikace Outlook. Při vytváření nového souboru PST aplikace Outlook tedy možná budete chtít použít stejnou strukturu složek. Vlastně v mém předchozím článku –“2 kroky k zachování aktuální hierarchie složek v novém souboru Outlooku“, můžete se naučit tradiční metodu, která k dosažení tohoto cíle využívá funkci „Archivovat“. Nicméně ve skutečnosti je to stále trochu zdlouhavé. Ve srovnání s tím bude použití kódů VBA k jeho získání mnohem rychlejší. Proto vám v následujícím sdělíme propracované kroky a kódy.

Zkopírujte strukturu složek z jednoho souboru PST aplikace Outlook do druhého

1. Hned na začátku spusťte program Outlook.
2. Poté v okně aplikace Outlook stiskněte tlačítka „Alt + F11“.
3. Dále vstoupíte do okna editoru Outlook VBA.
4. Následně zkopírujte a vložte následující kódy VBA do nového modulu.

Public objNewPSTFolder As Outlook.Folder
 
Sub CopyFolderStructure()
    Dim objFolders As Outlook.Folders
    Dim objFolder As Outlook.Folder
 
    'Get the folders of the source Outlook PST file
    Set objFolders = Outlook.Application.Session.Folders("Personal").Folders
 
    'Create the new pst file in your desired local folder and name
    Outlook.Application.Session.AddStore "E:\New PST File.pst"
    Set objNewPSTFolder = Session.Folders.GetLast()
 
    For Each objFolder In objFolders
        CreateFolder objFolder
    Next
 
    MsgBox "Completed!", vbOKOnly + vbInformation, "Copy Folder Structure"
End Sub
 
Sub CreateFolder(objFolder As Outlook.Folder)
    Dim objSubFolder As Outlook.Folder
 
    'Only copy the mail folder
    If (objFolder.DefaultItemType = olMailItem) Then
       'New Outlook PST file auto includes the "Deleted Items" folder, so skip it
       'Skip the useless mail folders - "Conversation Action Settings" and "Quick Step Settings"
       If (objFolder.Name <> "Deleted Items") And (objFolder.Name <> "Conversation Action Settings") And (objFolder.Name <> "Quick Step Settings") Then
 
          'Create the new folder
          objNewPSTFolder.Folders.Add objFolder.Name
          Set objNewPSTFolder = objNewPSTFolder.Folders.Item(objFolder.Name)
 
          For Each objSubFolder In objFolder.Folders
              CreateFolder objSubFolder
          Next
 
          Set objNewPSTFolder = objNewPSTFolder.parent
       End If
    End If

End Sub

5. Poté změňte úroveň zabezpečení maker na nízkou.
6. Později se vraťte do okna editoru VBA a stiskněte klávesu „F5“ pro spuštění makra.
7. Nakonec, když makro skončí práci, dostanete zprávu s výzvou „Dokončeno!“.
8. V tomto okamžiku můžete přejít do navigačního podokna pošty. Uvidíte nový datový soubor aplikace Outlook, který je ve stejné struktuře složek jako zdrojový soubor PST, jako na obrázku níže:

Vypořádejte se s skličujícími potížemi PST

Vzhledem k tomu, že Outlook PST je náchylný k chybám, mnozí z vás se jistě někdy setkali s různými problémy v Outlooku. Tváří v tvář jim můžete nejprve vyzkoušet nástroj na opravu doručené pošty aplikace Outlook. Pokud selže, můžete použít silnější nástroj třetí strany, jako je např DataNumen Outlook Repair, které mohou opravit Outlook Chyby PST jako vánek.

Úvod autora:

Shirley Zhang je expertem na obnovu dat DataNumen, Inc., která je světovým lídrem v oblasti technologií pro obnovu dat, včetně SQL Server opravit a výhledové softwarové produkty pro opravy. Pro více informací navštivte www.datanumen.com