Jak rychle připojit konkrétní snímky z PowerPoint Prezentace do e-mailu aplikace Outlook

Pokud chcete extrahovat konkrétní snímky a PowerPoint prezentaci na samostatnou novou prezentaci a připojit ji k e-mailu aplikace Outlook, můžete využít způsob sdílený v tomto článku.

Místo připojení celého PowerPoint prezentace k e-mailu, pokud chcete připojit konkrétní snímky prezentace, obecně je třeba nejprve zkopírovat konkrétní snímky do nové prezentace. Je to příliš problematické. Proto vám zde ukážeme metodu, která ji může realizovat najednou.

Připojte konkrétní snímky a PowerPoint Prezentace na e-mail

1. Nejprve otevřete konkrétní PowerPoint Prezentace.
2. Pak v PowerPoint V okně aplikace stiskněte klávesy „Alt + F11“ pro přístup do editoru VBA.
3. Dále v novém okně vytvořte nový modul klepnutím na „Vložit“> „Modul“.
4. Následně zkopírujte a vložte následující kód VBA do tohoto modulu.

Sub AttachSpecificSlidesToOutlookEmail()
    Dim objActivePresetation As Presentation
    Dim objSlide As Slide
    Dim n As Long
    Dim strName As String
    Dim strTempPresetation As String
    Dim objTempPresetation As Presentation
    Dim objOutlookApp As Object
    Dim objMail As Object
 
    Set objActivePresetation = ActivePresentation
 
    For Each objSlide In objActivePresetation.Slides
        objSlide.Tags.Delete ("Selected")
    Next
 
    'Add a tag "Selected" to the selected slides
    For n = 1 To ActiveWindow.Selection.SlideRange.Count
        ActiveWindow.Selection.SlideRange(n).Tags.Add "Selected", "YES"
    Next n
 
    strName = objActivePresetation.Name
    strName = Left(strName, InStrRev(strName, ".") - 1)
    strTempPresetation = Environ("TEMP") & "\" & strName & ".pptx"
 
    'Copy the active presentation to a temp presentation
    objActivePresetation.SaveCopyAs strTempPresetation
    Set objTempPresetation = Presentations.Open(strTempPresetation)
 
    'Remove the untagged slides
    For n = objTempPresetation.Slides.Count To 1 Step -1
        If objTempPresetation.Slides(n).Tags("Selected") <> "YES" Then
           objTempPresetation.Slides(n).Delete
        End If
    Next n
 
    objTempPresetation.Save
    objTempPresetation.Close
 
    'Attach the temp presentation to a new email
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objMail = objOutlookApp.CreateItem(olMailItem)
 
    'Change the email details as per your needs
    With objMail
         .To = "test@datanumen.com"
         .Subject = strName
         .Body = "Dear," & vbCr & vbCr & vbTab & "Specific slides are extracted and attached."
         .Attachments.Add strTempPresetation
         .Display
    End With
End Sub

5. Poté můžete zavřít aktuální okno.
6. Později přejděte na „Soubor“> „Možnosti“> „Panel nástrojů Rychlý přístup“ a přidejte nové makro na Panel nástrojů Rychlý přístup.
7. Nakonec můžete toto makro vyzkoušet.

• Pro začátek vyberte konkrétní snímky, které chcete extrahovat.
• Poté klikněte na tlačítko makra na panelu nástrojů Rychlý přístup.
• Najednou se zobrazí e-mail aplikace Outlook, ve kterém je PowerPoint prezentace, která je extrahována ze zdrojové prezentace.

Využijte efektivní nástroj pro obnovení

Jak všichni víme, Outlook je vybaven vestavěným nástrojem pro opravy - scanpst. Přesto si v Outlooku jednoduše poradí s malými závadami. Pokud je to, s čím jste konfrontováni, vážné poškození, nebude to mít žádný účinek. V tomto okamžiku vám nezbývá než se vrátit k jinému výkonnému a spolehlivému nástroji pro opravy, jako je DataNumen Outlook Repair. S ním budete schopni zachránit poškozený soubor aplikace Outlook.

Úvod autora:

Shirley Zhang je expertem na obnovu dat DataNumen, Inc., která je světovým lídrem v oblasti technologií pro obnovu dat, včetně poškozený mdf a výhledové softwarové produkty pro opravy. Pro více informací navštivte www.datanumen.com