Jak rychle připojit konkrétní stránky dokumentu Word k e-mailu aplikace Outlook

MS Word má přímou funkci podporující uživatele k odeslání aktuálního dokumentu Word jako přílohu e-mailu. Někdy však můžete doufat, že k e-mailu aplikace Outlook připojíte konkrétní stránky dokumentu Word. Nyní vám tento článek bude sdílet metodu.

Chcete-li odeslat celý dokument Word jako přílohu e-mailu v aplikaci MS Word, můžete jednoduše přejít do nabídky „Soubor“ a přejít na kartu „Uložit a odeslat“, pod kterou najdete tlačítko „Odeslat jako přílohu“. Někdy však chcete odeslat pouze konkrétní stránky dokumentu. V této situaci můžete k provedení použít metodu uvedenou v následujících krocích.

Připojte konkrétní stránky dokumentu Word k e-mailu

1. Nejprve byste měli otevřít zdrojový dokument Word, jehož konkrétní stránky chcete odeslat e-mailem.
2. Poté, co se dostanete do okna MS Word, musíte stisknout tlačítka „Alt + F11“.
3. Dále získáte přístup k editoru VBA v MS Word.
4. Poté musíte povolit „Knihovnu objektů Microsoft Outlook“. Toho dosáhnete kliknutím na „Nástroje“ > „Reference“.
5. Následně byste měli zkopírovat následující kód VBA do modulu, který se nepoužívá.

Sub AttachSpecificPagesToOutlookEmail()
    Dim strDocumentName As String
    Dim objSelectedPages As Word.Range
    Dim objTempDocument As Word.Document
    Dim objTempRange As Word.Range
    Dim i As Long
    Dim strTempDocument As String
    Dim objOutlookApp As Outlook.Application
    Dim objMail As Outlook.MailItem
 
    strDocumentName = Left(ActiveDocument.Name, InStr(ActiveDocument.Name, ".") - 1)
 
    'Copy the contents from Page 2 to 4
    'You can change the page as per your own needs
    Selection.GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=2
    Set objSelectedPages = Selection.Range
    Selection.GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=4
    objSelectedPages.End = Selection.Bookmarks("\Page").Range.End
    objSelectedPages.Select
    objSelectedPages.Copy
 
    'Paste the copied contents into a new Word Document
    Set objTempDocument = Word.Application.Documents.Add
    objTempDocument.Activate
    Set objTempRange = objTempDocument.Range(0, 0)
    objTempRange.PasteAndFormat (wdFormatOriginalFormatting)

    For i = objTempDocument.Paragraphs.Count To 1 Step -1
        If Len(objTempDocument.Paragraphs(i).Range) = 1 Then
           objTempDocument.Paragraphs(i).Range.Delete
        Else
           Exit For
        End If
    Next i
 
    'Save this document
    strTempDocument = "E:\" & strDocumentName & " (Excerpt).doc"
    objTempDocument.SaveAs2 strTempDocument, wdFormatDocument
 
    'Attach the new document to a new Outlook email
    On Error Resume Next
    Set objOutlookApp = GetObject(, "Outlook.Application")
    If objOutlookApp Is Nothing Then
       Set objOutlookApp = CreateObject("Outlook.Application")
    End If
 
    Set objMail = objOutlookApp.CreateItem(olMailItem)
    objMail.Attachments.Add (strTempDocument)
    objMail.Display
 
    objTempDocument.Close False
    Kill strTempDocument
End Sub

6. Nakonec můžete toto makro spustit. Stačí stisknout klávesu F5 nebo klepnout na ikonu „Spustit“ na panelu nástrojů.
7. Po dokončení makra se zobrazí nový e-mail aplikace Outlook, který je připojen s výňatkem zdrojového dokumentu Word, například následující snímek obrazovky:

Extrahujte maximum dat z poškozeného souboru aplikace Outlook

Pokud používáte Outlook po celá desetiletí, možná jste byli konfrontováni s různými problémy s Outlookem, včetně vyskakovacích vnitřních chybových zpráv, náhlých zhroucení a vážného poškození souboru. Vzhledem k tomu, že scanpst, vestavěný nástroj pro opravu, se dokáže vypořádat pouze s malými problémy, měli byste raději mít po ruce externí výkonný nástroj pro opravu DataNumen Outlook Repair. Je schopen čerpat maximum dat z poškozeného datového souboru aplikace Outlook.

Úvod autora:

Shirley Zhang je expertem na obnovu dat DataNumen, Inc., která je světovým lídrem v oblasti technologií pro obnovu dat, včetně oprava sql a výhledové softwarové produkty pro opravy. Pro více informací navštivte www.datanumen.com