Jak rychle připojit poslední upravený soubor ve složce Windows k e-mailu aplikace Outlook

Někdy můžete chtít rychle najít a připojit naposledy upravený soubor v konkrétní složce Windows k e-mailu aplikace Outlook. V tomto případě můžete použít metodu uvedenou v tomto článku.

Někteří uživatelé chtějí, aby Outlook rychle zjistil a přidal k e-mailu naposledy upravený soubor ve složce Windows, například naposledy vytvořený, změněný nebo uložený soubor. Outlook však takovou přímou a nativní funkci nenabízí. Proto si v následujícím textu ukážeme kousek kódu VBA, který to snadno realizuje.

Připojte poslední upravený soubor ve složce Windows k e-mailu

1. Hned na začátku byste měli spustit aplikaci Outlook.
2. Poté, co se dostanete do hlavního okna Outlooku, můžete stisknout klávesy „Alt + F11“.
3. Dále se úspěšně dostanete do okna editoru VBA aplikace Outlook.
4. Následně byste měli najít a otevřít modul, který se nepoužívá.
5. A pak zkopírujte a vložte následující kód VBA do tohoto okna modulu.

Sub AttachLastModifiedSpecificFile()
    Dim objShell As Object
    Dim objSelectedFolder As Object
    Dim objFileSystem As Object
    Dim strSourceFolderPath As String
    Dim objSourceFolder As Object
    Dim objFile As Object
    Dim dLastModifiedDate As Date
    Dim strLastModifiedFilePath As String
    Dim objMail As Outlook.MailItem
 
    On Error GoTo ErrorHandler
    'Select a local source folder
    Set objShell = CreateObject("Shell.Application")
    Set objSelectedFolder = objShell.BrowseForFolder(0, "Select the source folder", 0, "")
    strSourceFolderPath = objSelectedFolder.self.Path
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objSourceFolder = objFileSystem.GetFolder(strSourceFolderPath)
 
    If objSourceFolder.Files.Count > 0 Then
       For Each objFile In objSourceFolder.Files
           'Find the last modified file within "xlsx" file type in the selected Windows folder
           If (objFile.DateLastModified > dLastModifiedDate) And (objFileSystem.GetExtensionName(objFile) = "xlsx") Then
              'You can add or change criteria, such as
              'Left(objFile.Name, 4) = "Test" ---> file whose name begins with "Test"
              '(objFile / 1024) / 1024 > 2 --> File exceeds 2 MB
              'Note: Use "And" to connect more than one criteria
              strLastModifiedFilePath = objFile.Path
              dLastModifiedDate = objFile.DateLastModified
           End If
       Next
 
       If strLastModifiedFilePath <> "" Then
          'Confirm attaching it to the current outlook email
          strMsg = "The last modified file in the " & Chr(34) & strSourceFolderPath & Chr(34) & " is: " & vbCrLf & vbCrLf & "File: " & strLastModifiedFilePath & vbCrLf & "Date: " & dLastModifiedDate & vbCrLf & vbCrLf & "Do you want to attach it?"
          nPrompt = MsgBox(strMsg, vbQuestion + vbYesNo, "Confirm Attaching Last Modified File")
 
          If nPrompt = vbYes Then
             Set objMail = Outlook.Application.ActiveInspector.CurrentItem
             objMail.Attachments.Add strLastModifiedFilePath
         End If
      Else
         MsgBox "No file in the selected folder can meet your predefined criteria!", vbExclamation + vbOKOnly
      End If
    Else
      MsgBox "No file exists in the selected Windows folder!", vbExclamation + vbOKOnly
    End If
 
ErrorHandler:
    Exit Sub
End Sub

6. Poté můžete zavřít aktuální okno editoru VBA a pokračovat přidáním nového makra na panel nástrojů Rychlý přístup nebo na pás karet v okně Zprávy.
7. Později budete muset změnit úroveň zabezpečení maker aplikace Outlook na nízkou.
8. Nakonec to můžete vyzkoušet.

• Nejprve vytvořte a vytvořte nový e-mail aplikace Outlook jako obvykle.
• Poté stiskněte tlačítko makra na panelu nástrojů Rychlý přístup, jako na obrázku níže:
• Dále budete muset vybrat zdrojovou složku Windows a stisknout „OK“.
• Pokud je ve vybrané složce Windows takový soubor, zobrazí se výzva jako na následujícím snímku obrazovky:
• Když stisknete „Ano“, tento soubor se připojí najednou.

Řešení problémů s Outlookem co nejdříve

Kdykoli narazíte na problémy s Outlookem, doporučujeme je vyřešit co nejdříve. V této situaci si raději připravte robustní Oprava aplikace Outlook nástroj předem, například DataNumen Outlook Repair. Je schopen opravit chyby PST a efektivně zachránit data aplikace Outlook.

Úvod autora:

Shirley Zhang je expertem na obnovu dat DataNumen, Inc., která je světovým lídrem v oblasti technologií pro obnovu dat, včetně poškozený mdf a výhledové softwarové produkty pro opravy. Pro více informací navštivte www.datanumen.com