Jak zobrazit věk odpovídajících osob pro všechny události narozenin v zobrazení seznamu kalendáře aplikace Outlook

Někteří uživatelé by při prohlížení události narozenin v kalendáři rádi viděli také věk odpovídající osoby. V tomto článku proto sdílíme metodu, jak tuto myšlenku snadno splnit.

Když do kontaktu přidáte informace o narozeninách, Outlook automaticky vytvoří událost narozenin v kalendáři. Za těchto okolností můžete pokaždé, když v kalendáři uvidíte události narozenin, také chtít zjistit věk odpovídajících osob. Zde vám tedy představíme způsob, jak si to uvědomit.

Zobrazit věk odpovídajících osob pro všechny události narozenin v zobrazení seznamu

1. Na samém začátku spusťte editor Outlook VBA.
2. Potom zkopírujte následující kód do modulu.

Sub ShowAgesOfBirthdayEventsListView()
    Dim objStore As Outlook.Store
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    'Process All Calendar Folders in Your Outlook
    For Each objStore In Outlook.Application.Session.Stores
        Set objOutlookFile = objStore.GetRootFolder
        For Each objFolder In objOutlookFile.Folders
            If objFolder.DefaultItemType = olAppointmentItem Then
               Call ProcessFolders(objFolder)
            End If
        Next
    Next
End Sub

Sub ProcessFolders(ByVal objCalendar As Outlook.Folder)
    Dim i As Integer
    Dim objItem As Object
    Dim objBirthdayEvent As Outlook.AppointmentItem
    Dim dStart, dBirth As Date
    Dim nAge As Integer
    Dim objNewProperty As Outlook.UserProperty
    Dim objSubCalendar As Outlook.Folder

    For i = objCalendar.Items.Count To 1 Step -1
        Set objItem = objCalendar.Items.Item(i)
        'Add "Age" Property to Birthday Events
        If (objItem.MeetingStatus = olNonMeeting) And (objItem.IsRecurring = True) And (Right(objItem.Subject, 11) = "'s Birthday") Then
           Set objBirthdayEvent = objItem
           dStart = objBirthdayEvent.Start
 
           'Count Age
           dCurrentBirthday = DateSerial(Year(Now), Month(dStart), Day(dStart))
           nAge = DateDiff("yyyy", dStart, dCurrentBirthday)
 
           Set objNewProperty = objBirthdayEvent.UserProperties.Find("Age", True)
           If objNewProperty Is Nothing Then
              Set objNewProperty = objBirthdayEvent.UserProperties.Add("Age", olText, True)
           End If
 
           objNewProperty.value = nAge
           objBirthdayEvent.Save
        End If
    Next
 
    'Process All Sub-Calendar Folders Recursively
    If objCalendar.Folders.Count > 0 Then
       For Each objSubCalendar In objCalendar.Folders
           Call ProcessFolders(objSubCalendar)
       Next
    End If
End Sub

3. Poté vložte kurzor do prvního podprogramu a stiskněte „F5“ pro spuštění tohoto makra.
4. Po dokončení makra ukončete editor VBA a otevřete složku kalendáře.
5. Následně přejděte na kartu „Zobrazit“ a klikněte na „Změnit zobrazení“> „Seznam“.
6. Dále klikněte na tlačítko „Zobrazit nastavení“.
7. V rozbalovacím dialogovém okně zvolte „Sloupce“.
8. Poté v dalším dialogovém okně „Zobrazit sloupce“ vyberte ze seznamu „Vybrat dostupná pole z“ možnost „Uživatelem definovaná pole ve složce“.
9. Později přidejte „Věk“ do pole „Dostupné sloupce“ a klikněte na tlačítko „Přidat ->“.
10. Nakonec klikněte na řadu „OK“, dokud se nevrátíte zpět do seznamu položek kalendáře.
11. Nyní v seznamu vidíte věk osob všech narozeninových událostí, jak ukazuje následující obrázek.

Opravte kompromitovaný soubor aplikace Outlook

Při setkání můžete mít paniku poškozený Outlook soubor, který obsahuje mnoho vašich cenných e-mailů a plánů. Bez ohledu na to, že takový problém je docela zoufalý, stále se musíte okamžitě uklidnit a zvážit účinná opatření. Pokud budete mít stále obavy, situace se může zhoršovat a zhoršovat. Ve skutečnosti existuje několik způsobů a nástrojů, které mohou opravit poškozený soubor, například nástroj pro opravu doručené pošty a robustnější a zkušenější nástroj, například DataNumen Outlook Repair.

Úvod autora:

Shirley Zhang je expertem na obnovu dat DataNumen, Inc., která je světovým lídrem v oblasti technologií pro obnovu dat, včetně SQL Server opravit a výhledové softwarové produkty pro opravy. Pro více informací navštivte www.datanumen.com