Jak rychle vytvořit skupinu kontaktů ze všech kontaktů aplikace Outlook s konkrétním pracovním názvem

Chcete-li snadněji komunikovat s kontakty s konkrétním pracovním názvem, můžete z těchto kontaktů rychle vytvořit skupinu kontaktů. Nyní v tomto článku s vámi sdílíme rychlou metodu.

Pokud často hromadně odesíláte e-maily, úkoly nebo pozvánky na schůzku kontaktům, které mají konkrétní pracovní pozici, bude mnohem pohodlnější, když z nich vytvoříte skupinu kontaktů. Obecně platí, že standardním způsobem musíte nejprve vytvořit novou skupinu kontaktů a poté postupně přidávat kontakty do skupiny jako členy. Je to trochu problematické. Proto vás v následujících částech naučíme mnohem rychlejší způsob, jak to získat.

Vytvořte skupinu kontaktů ze všech kontaktů s konkrétním názvem pracovní pozice

1. Nejprve ve složce Kontakty vyberte kontakt, který má konkrétní pracovní pozici.
2. Poté stiskněte „Alt + F11“ pro přístup k editoru Outlook VBA.
3. Dále zkopírujte následující kód VBA do prázdného modulu nebo projektu.

Dim objContact As Outlook.ContactItem
Dim strJobTitle As String
Dim objNewGroup As Outlook.DistListItem
Dim objTempMail As Outlook.MailItem

Sub CreateContactGroupfromContactsSameJobTitle()
    Dim objStore As Outlook.Store
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    Set objContact = Outlook.Application.ActiveExplorer.Selection(1)
    strJobTitle = objContact.JobTitle
 
    Set objNewGroup = Outlook.Application.CreateItem(olDistributionListItem)
    Set objTempMail = Outlook.Application.CreateItem(olMailItem)
 
    'Process all Contacts folders
    For Each objStore In Outlook.Application.Session.Stores
        Set objOutlookFile = objStore.GetRootFolder
        For Each objFolder In objOutlookFile.Folders
            If objFolder.DefaultItemType = olContactItem Then
               Call ProcessContactsFolders(objFolder)
            End If
        Next
    Next
 
    objNewGroup.AddMembers objTempMail.Recipients
    objNewGroup.Display
End Sub

Sub ProcessContactsFolders(ByVal objCurFolder As Outlook.Folder)
    Dim objItem As Object
    Dim objSubfolder As Outlook.Folder
 
    For Each objItem In objCurFolder.Items
        If objItem.Class = olContact Then
           If objItem.JobTitle = strJobTitle Then
              'Add the contact having the specific job title to the new group
              objTempMail.Recipients.Add (objItem.Email1Address)
              objTempMail.Recipients.ResolveAll
           End If
        End If
    Next
 
    'Process all subfolders recursively
    If objCurFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurFolder.Folders
           Call ProcessContactsFolders(objSubfolder)
       Next
    End If
End Sub

4. Poté přesuňte kurzor na první podprogram.
5. Nakonec spusťte toto makro klepnutím na klíčové tlačítko „F5“.
6. Po dokončení makra se zobrazí nová skupina kontaktů. Obsahuje všechny kontakty se stejným pracovním názvem vybraného kontaktu v kroku 1.

Efektivní ochrana dat aplikace Outlook

Ačkoli je Outlook bohatý na funkce, nemůže se zbavit skutečnosti, že je zranitelný. Pokud tedy nechcete přijít o svá vzácná data Outlooku, musíte se snažit je chránit. Například je třeba v pravidelných intervalech zálohovat data aplikace Outlook. Pokud je také cenově dostupný, doporučuje se mít špičkový nástroj pro opravu PST, jako je například DataNumen Outlook Repair, které mohou opravit PST data za okamžik.

Úvod autora:

Shirley Zhang je expertem na obnovu dat DataNumen, Inc., která je světovým lídrem v oblasti technologií pro obnovu dat, včetně poškozený sql a výhledové softwarové produkty pro opravy. Pro více informací navštivte www.datanumen.com