Jak automaticky označit víkendové události jako soukromé v aplikaci Outlook

Pro most uživatelé, schůzky naplánované na víkend jsou obvykle soukromé. Proto chtějí, aby Outlook automaticky označil a zobrazil takové schůzky jako soukromé. V tomto článku to provedeme trochou skriptování.

Aby aplikace Outlook snadněji rozlišovala mezi obchodními a soukromými schůzkami, umožňuje uživatelům označit schůzky jako soukromé. Tímto způsobem zjistíte, že je docela pohodlné a snadné tisknout kalendář bez soukromých schůzek. V této situaci můžete chtít, aby váš Outlook automaticky rozpoznal a označil konkrétní události jako soukromé. Například obecně jsou schůzky o víkendu soukromé, takže je chcete nechat v Outlooku automaticky označit jako soukromé. Dále vás provedeme tím, jak toho dosáhnout.

Automaticky označit víkendové schůzky jako soukromé

1. Nejprve spusťte editor Outlook VBA podle „Jak spustit kód VBA ve vašem Outlooku".
2. Poté v okně „Microsoft Visual Basic pro aplikace“ vložte následující kód do projektu „ThisOutlookSession“.

Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objAppointment As Outlook.AppointmentItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olAppointment Then
       Set objAppointment = Inspector.CurrentItem
    End If
End Sub

Private Sub objExplorer_Activate()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olAppointment Then
       Set objAppointment = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objAppointment_Open(Cancel As Boolean)
    Call MarkWeedendAppointmentPrivate(objAppointment)
End Sub

Private Sub objAppointment_PropertyChange(ByVal Name As String)
    If Name = "Start" Or Name = "End" Then
       Call MarkWeedendAppointmentPrivate(objAppointment)
    End If
End Sub

Private Sub MarkWeedendAppointmentPrivate(ByVal objAppointment As Outlook.AppointmentItem)
    Dim dStartDate As Date
 
    dStartDate = Format(objAppointment.Start, "Short Date")
 
    'If the appointment start falls on weekend
    Select Case Weekday(dStartDate)
           Case 7, 1
                'Mark it private
                objAppointment.Sensitivity = olPrivate
    End Select
End Sub

3. Poté restart Outlook aktivovat makro.
4. Od této chvíle, kdykoli vytvoříte novou schůzku nebo změníte stávající schůzku na víkend, aplikace Outlook ji automaticky označí jako soukromou.

Vyřešte nepříjemné problémy s aplikací Outlook

Je možné, že jste při jednání s Outlookem narazili na některé problémy, například neočekávané zamrznutí aplikace, chybové zprávy vyskakovacích oken atd. Když byste je trpěli, měli byste strach. Prosím, uklidni se! Panika nepomůže nic, ale zhorší případ. Za prvé můžete zkontrolovat, zda máte přístup k souboru PST jako obvykle. Pokud ano, musíte opravit soubor PST, což lze provést pomocí nástroj pro opravu doručené pošty nebo výkonnější externí nástroj DataNumen Outlook Repair.

Úvod autora:

Shirley Zhang je expertem na obnovu dat DataNumen, Inc., která je světovým lídrem v oblasti technologií pro obnovu dat, včetně Oprava MDF a výhledové softwarové produkty pro opravy. Pro více informací navštivte www.datanumen.com