Jak získat oznámení, pokud neobdržíte odpověď na konkrétní e-mail v očekávaném čase

Tento článek vás naučí rychlý trik pomocí VBA, který vám umožní, aby vás aplikace Outlook automaticky vyzvala, zda chcete poslat e-mail s oznámením, když jste nedostali odpověď na konkrétní e-mail v určitém čase.

U životně důležitých e-mailů se občas určitě budete těšit na jejich odpovědi. Jinými slovy musíte doufat, že vám příjemce může odpovědět co nejdříve. Jinak, pokud jste ještě neobdrželi odpověď v očekávaném čase, zašlete příjemci e-mail s následným oznámením znovu. V reakci na tento požadavek proto představíme metodu, která pomocí VBA zajistí, aby vás aplikace Outlook v takovém případě automaticky varovala a vyzvala. Čtěte dále a získejte propracované kroky a kódy.

Pokud neobdržíte odpověď na konkrétní e-mail v očekávaném čase, získejte oznámení

1. Hned na začátku, starVáš Outlook.
2. Poté musíte nastavit konkrétní čas připomenutí na konkrétní e-mail.

• Nejprve klikněte pravým tlačítkem na konkrétní e-mail.
• Poté vyberte „Sledovat“> „Přidat připomenutí“.
• V dialogovém okně můžete nastavit čas připomenutí stejný jako konkrétní čas, ve kterém chcete obdržet jeho odpověď.

3. Poté stiskněte klávesy „Alt + F11“ pro přístup k editoru Outlook VBA.
4. Dále v novém okně otevřete projekt „ThisOutlookSession“ a zkopírujte do něj následující kódy.

Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
    Set objInboxItems = Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

'If receive the reply, clear the flag and remove the reminder
Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
    Dim objSentItems As Outlook.Items
    Dim objVariant As Variant
    Dim i As Long
    Dim strSubject As String
    Dim dSendTime As String
 
    Set objSentItems = Outlook.Application.Session.GetDefaultFolder(olFolderSentMail).Items
 
    If Item.Class = olMail Then
       For i = 1 To objSentItems.Count
           If objSentItems.Item(i).Class = olMail Then
              Set objVariant = objSentItems.Item(i)
              strSubject = LCase(objVariant.Subject)
              dSendTime = objVariant.SentOn
 
              If LCase(Item.Subject) = "re: " & strSubject Or InStr(LCase(Item.Subject), strSubject) > 0 Then
                 If Item.SentOn > dSendTime Then
                    With objVariant
                         .ClearTaskFlag
                         .ReminderSet = False
                         .Save
                    End With
                 End If
              End If
           End If
       Next i
    End If
End Sub

'Get a prompt asking if to send a notification email
Private Sub Application_Reminder(ByVal Item As Object)
    Dim strPrompt As String
    Dim nResponse As Integer
    Dim objFollowUpMail As Outlook.MailItem
 
    'You can change the subject as per your real case
    If (Item.Class = olMail) And (LCase(Item.Subject) = "datanumen outlook repair") Then
       strPrompt = "You haven't yet recieved the reply of " & Chr(34) & Item.Subject & Chr(34) & " within your expected time. Do you want to send a follow-up notification email?"
       nResponse = MsgBox(strPrompt, vbYesNo + vbQuestion, "Confirm to Send a Follow-Up Notification Email")
       If nResponse = vbYes Then
          Set objFollowUpMail = Application.CreateItem(olMailItem)
          With objFollowUpMail
               .To = Item.Recipients.Item(1).Address
               .Subject = "Follow Up: " & Chr(34) & Item.Subject & Chr(34)
               .Body = "Please respond to my email " & Chr(34) & Item.Subject & Chr(34) & "as soon as possible"
               .attachments.Add Item
               .Display
          End With
       End If
    End If
End Sub

5. Následně tento kód podepište.
6. Později změňte nastavení maker aplikace Outlook, abyste povolili digitálně podepsaná makra.
7. Nakonec restar• Outlook aktivuje nové makro. Od této chvíle bude Outlook fungovat následovně:

• Pokud jste obdrželi odpověď na konkrétní e-mail předtím, než se objeví jeho připomenutí, Outlook automaticky vymaže příznak a deaktivuje připomenutí.
• Pokud jste neobdrželi odpověď, když se spustí její připomenutí, Outlook se vás zeptá, zda chcete poslat e-mail s následným oznámením. Pokud zvolíte „Ano“, e-mail bude odeslán. Pokud vyberete „Ne“, výzva zmizí najednou.

Vyřešte nepříjemné problémy s Outlookem

Protože Outlook je náchylný k chybám, aby se zabránilo Outlook korupce, měli byste se spolehnout nejen na nástroj pro doručenou poštu, Scanpst.exe. Měli byste připravit další silný a renomovaný nástroj pro opravy, jako je DataNumen Outlook Repair, které mohou odstranit nepříjemné problémy, které Scanpst.exe nedokáže vyřešit.

Úvod autora:

Shirley Zhang je expertem na obnovu dat DataNumen, Inc., která je světovým lídrem v oblasti technologií pro obnovu dat, včetně korupce sql a výhledové softwarové produkty pro opravy. Pro více informací navštivte www.datanumen.com