Jak dávkově uložit více konceptů e-mailů jako šablony aplikace Outlook

Možná jste vytvořili několik konceptů e-mailů a doufáme, že je znovu použijete mnohokrát. Pokud ano, proč je hromadně neuložíte jako šablony aplikace Outlook? Tento článek vás naučí, jak toho dosáhnout jedním tahem přes VBA.

Ve výchozím nastavení Outlook umožňuje uživatelům uložit pouze jeden e-mail jako šablonu najednou. Jinými slovy, nemůžete hromadně uložit více konceptů e-mailů jako šablony. Jak můžete vidět, když vyberete více než jeden e-mail a přejdete na „Soubor“ > „Uložit jako“, nemůžete najít formát „Šablona aplikace Outlook“ v seznamu „Uložit jako typ“, k dispozici je pouze „Pouze text“. Ale my vám v následujícím představíme, jak to hromadně realizovat.

Dávkové ukládání více konceptů e-mailů jako šablon aplikace Outlook

1. Na úplném začátku spusťte editor Outlook VBA.
2. V novém okně „Microsoft Visual Basic for Applications“ zkopírujte a vložte níže uvedený kód VBA.

Sub SaveMultipleDraftsAsTemplates()
    Dim objSelection As Outlook.Selection
    Dim i As Long
    Dim strTemplateFolder As String
    Dim objMail As Outlook.MailItem
    Dim strSubject As String
 
    'Get all selected mails
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
 
    If Not (objSelection Is Nothing) Then
       'Get the default folder for saving Outlook Templates
       strTemplateFolder = CStr(Environ("USERPROFILE")) & "\Documents\UserTemplates\"
 
       'Save each mail as template
       For i = objSelection.Count To 1 Step -1
           If objSelection(i).Class = olMail Then
              Set objMail = objSelection(i)
              If objMail.Subject <> "" Then
 
                 'Remove unsupported characters
                 strSubject = objMail.Subject
                 strSubject = Replace(strSubject, "/", " ")
                 strSubject = Replace(strSubject, "\", " ")
                 strSubject = Replace(strSubject, ":", "")
                 strSubject = Replace(strSubject, "?", " ")
                 strSubject = Replace(strSubject, Chr(34), " ")
 
                 objMail.SaveAs strTemplateFolder & strSubject & ".oft", olTemplate
              Else
                 objMail.SaveAs strTemplateFolder & "Template" & i & ".oft", olTemplate
              End If
           End If
       Next
 
       'Open the folder of Templates
       Shell "Explorer.exe" & " " & strTemplateFolder, vbNormalFocus
    End If
End Sub

3. Poté se pro pozdější pohodlí doporučuje připojit toto makro k panelu nástrojů Rychlý přístup (QAT). O podrobných krocích si můžete přečíst „Jak spustit kód VBA ve vašem Outlooku"
4. Nakonec můžete pořídit snímek podle níže uvedených operací.

• Nejprve vyberte koncepty e-mailů, které chcete uložit jako šablony.
• Poté klikněte na tlačítko makra v QAT.
• Po dokončení makra se zobrazí složka Windows pro uložení výchozích šablon aplikace Outlook. Můžete vidět, že tam jsou šablony z vybraných konceptů e-mailů.

Nástroj na opravu doručené pošty může stále selhat

Pokud jde o interní opravný nástroj Outlooku – Scanpst, ocení jej velké množství uživatelů. Tento nástroj je nepochybně skutečně schopen vyřešit většinu malých problémů v aplikaci Outlook. Přesto to není úplně bezchybné. Stále může selhat a způsobit mnoho chyb. Například v případě těžkého Outlook korupce, není schopen opravit kompromitovaný soubor PST. V tomto scénáři nemáte jinou alternativu než použít výkonnější a špičkový nástroj třetí strany, jako je např DataNumen Outlook Repair.

Úvod autora:

Shirley Zhang je expertem na obnovu dat DataNumen, Inc., která je světovým lídrem v oblasti technologií pro obnovu dat, včetně zotavení sql a výhledové softwarové produkty pro opravy. Pro více informací navštivte www.datanumen.com