Jak dávkově odebrat všechny e-mailové adresy s konkrétní doménou z kontaktů aplikace Outlook

Někdy můžete doufat, že z kontaktů odstraníte všechny e-mailové adresy s určitou doménou. V takové situaci to ale asi nebudete chtít dělat jednu po druhé. Proto vás tento příspěvek naučí mnohem chytřejší metodu.

Například společnost změní svůj název. Mezitím se také změní doména společnosti. V aplikaci Outlook jste však v této společnosti uložili mnoho kontaktů, jejichž e-mailové adresy jsou se starou doménou. Tyto e-mailové adresy již samozřejmě nejsou platné. Pokud tedy chcete za těchto okolností tyto e-mailové adresy odstranit najednou, můžete použít následující způsob.

Dávkové odebrání všech e-mailových adres s konkrétní doménou z kontaktů

1. Pro začátek otevřete editor VBA v Outlooku pomocí klávesové zkratky – „Alt + F11“.
2. Potom v novém okně vložte následující kód VBA do prázdného modulu.

Dim strDomain As String

Sub BatchRemoveAllEmailAddressesInSpecificDomain()
    Dim objStore As Store
    Dim objFolder As Folder
    Dim lTotalCount As Long
 
    'Input the specific domain
    strDomain = InputBox("Enter the specific domain:", , "@false.com")
 
    If Len(strDomain) <> 0 Then
       lTotalCount = 0
       'Process all Contact folders in your Outlook
       For Each objStore In Application.Session.Stores
           For Each objFolder In objStore.GetRootFolder.Folders
               If objFolder.DefaultItemType = olContactItem Then
                  Call ProcessContactFolders(objFolder, lTotalCount)
               End If
           Next
       Next
 
       'Prompt you
       MsgBox lTotalCount & " email addresses in " & strDomain & " are removed!", vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessContactFolders(ByVal objCurrentFolder As Folder, ByRef lCount As Long)
    Dim objContacts As Items
    Dim i As Long
    Dim objContact As ContactItem
 
    Set objContacts = objCurrentFolder.Items
 
    For i = objContacts.Count To 1 Step -1
        If TypeName(objContacts(i)) = "ContactItem" Then
           Set objContact = objContacts(i)
 
           'Check 3 email addresses of each contact
           If InStr(objContact.Email1Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email1Address = ""
              objContact.Email1DisplayName = ""
           ElseIf InStr(objContact.Email2Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email2Address = ""
              objContact.Email2DisplayName = ""
           ElseIf InStr(objContact.Email3Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email3Address = ""
              objContact.Email3DisplayName = ""
           End If
 
           objContact.Save
        End If
     Next
 
     If objCurrentFolder.Folders.Count > 0 Then
        For Each objSubfolder In objCurrentFolder.Folders
            Call ProcessContactFolders(objSubfolder, lCount)
        Next
     End If
End Sub

3. Poté umístěte kurzor do podprogramu „BatchRemoveAllEmailAddressesInSpecificDomain“.
4. Nakonec spusťte toto makro kliknutím na tlačítko „F5“.
5. Následně do vyskakovacího dialogového okna zadejte konkrétní doménu.
6. Po kliknutí na „OK“ se makro spustí.
7. Po dokončení obdržíte zprávu o výsledcích.
8. Nyní můžete zkontrolovat kontakty. Všechny e-mailové adresy s konkrétní doménou musely zmizet.

Uchovejte svůj soubor aplikace Outlook

S rostoucím a větším rizikem spojeným s vaším Outlookem je stále obtížnější chránit vaše cenná data Outlooku. Například byste měli nejen vytrvat v pravidelném zálohování dat, ale musíte si také dávat pozor na své operace. Není moudré snadno důvěřovat jakýmkoli e-mailům od neznámých odesílatelů. Jinak, pokud bude obsahovat virus, bude váš soubor aplikace Outlook infikován. V té době se musíte pokusit Oprava aplikace Outlook prostřednictvím pozoruhodného nástroje pro opravu, jako je DataNumen Outlook Repair.

Úvod autora:

Shirley Zhang je expertem na obnovu dat DataNumen, Inc., která je světovým lídrem v oblasti technologií pro obnovu dat, včetně zotavit se Sql Server a výhledové softwarové produkty pro opravy. Pro více informací navštivte www.datanumen.com