Jak dávkově smazat všechny přečtené příjmy ve vašem Outlooku

Abyste si ověřili, že si příjemci váš e-mail přečetli, můžete při psaní e-mailu požádat o potvrzení o přečtení. V takovém případě může být vaše poštovní schránka plná takových potvrzení o přečtení. V tomto příspěvku se dozvíte, jak je hromadně a trvale smazat.

Po přečtení článku „Jak dávkově smazat všechny doručenky ve vašem Outlooku„, Můžete přemýšlet o přístupu k hromadnému mazání všech potvrzení o přečtení. Zjevný rozdíl mezi těmito dvěma druhy příjmů je ve skutečnosti jejich předmětem. Potvrzení o doručení obsahuje v předmětu „Doručeno“, ale přečtené potvrzení místo toho obsahuje „Číst“. Proto můžete stejným způsobem použít hromadné odstranění všech potvrzení o přečtení. V následujících bodech vás podrobně naučíme konkrétní kroky.

Dávkové odstranění všech potvrzení o přečtení

1. Na začátku spusťte Outlook.
2. Poté přejděte do editoru Outlook VBA pomocí „Alt + F11“ podle „Jak spustit kód VBA ve vašem Outlooku".
3. Dále v novém okně otevřete prázdný modul a vložte do něj následující kód.

Dim objOutlookFile As Outlook.Folder

Sub BatchDeleteAllReadReceipts()
    Dim objStore As Outlook.Store
    Dim objFolder As Outlook.Folder
    Dim lTotalCount As Long
 
    lTotalCount = 0
   'Process all Outlook files
    For Each objStore In Outlook.Application.Session.Stores
        Set objOutlookFile = objStore.GetRootFolder
        For Each objFolder In objOutlookFile.Folders
            If objFolder.DefaultItemType = olMailItem Then
               Call ProcessFolders(objFolder, lTotalCount)
            End If
        Next
    Next
 
    'Prompt you of the results
    MsgBox lTotalCount & " read receipts are deleted!", vbInformation + vbOKOnly
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder, lCount As Long)
    Dim i As Long
    Dim objDeliveryReceipt As Outlook.ReportItem
    Dim objSubfolder As Outlook.Folder
    Dim objDeletedItems As Outlook.Items
    Dim objItem As Object
 
    For i = objCurrentFolder.Items.Count To 1 Step -1
        'Find read receipts
        If (TypeOf objCurrentFolder.Items(i) Is ReportItem) And (Left(objCurrentFolder.Items(i).Subject, 5) = "Read:") Then
           Set objDeliveryReceipt = objCurrentFolder.Items.Item(i)
           objDeliveryReceipt.Delete
 
           lCount = lCount + 1
 
           'Permanently delete them
           Set objDeletedItems = objOutlookFile.Folders("Deleted Items").Items
           For Each objItem In objDeletedItems
               If (TypeOf objItem Is ReportItem) And (Left(objItem.Subject, 5) = "Read:") Then
                  objItem.Delete
               End If
           Next
         End If
    Next
 
    'Loop subfolders recursively
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessFolders(objSubfolder, lCount)
       Next
    End If
End Sub

4. Poté klikněte na první podprogram.
5. Nakonec stiskněte klávesu „F5“.
6. Makro najednou bude fungovat tak, že z Outlooku odstraníte všechna potvrzení o přečtení.
7. Po dokončení se zobrazí výzva k výsledku, například snímek obrazovky níže.
8. V současné době můžete zkontrolovat své poštovní složky. Všechna potvrzení o přečtení byla pryč.

Chraňte data aplikace Outlook

Přestože je soubor aplikace Outlook náchylný k poškození, můžeme podniknout kroky k jeho ochraně. Například bychom měli udržovat soubor aplikace Outlook v malé velikosti, chránit jej před škodlivými faktory a pravidelně jej zálohovat. V neposlední řadě si raději připravte silný externí nástroj pro opravu PST DataNumen Outlook Repair. Bude to mít velký dopad na opravy poškozený Outlook soubor.

Úvod autora:

Shirley Zhang je expertem na obnovu dat DataNumen, Inc., která je světovým lídrem v oblasti technologií pro obnovu dat, včetně oprava sql a výhledové softwarové produkty pro opravy. Pro více informací navštivte www.datanumen.com