Jak automaticky nastavit jiný čas připomenutí pro schůzky aplikace Outlook v různých barevných kategoriích

Pokud klasifikujete schůzky aplikace Outlook podle barevných kategorií a chcete nastavit jiný čas připomenutí schůzek v různých barevných kategoriích, můžete si přečíst tento článek. Zde vás naučíme, jak to realizovat pomocí aplikace Outlook VBA.

Například rozdělujete schůzky do dvou skupin. Jedna je v barevné kategorii „Mimo pracoviště“, protože místo konání schůzky je příliš daleko, a druhá je v barevné kategorii „Na pracovišti“, protože místo konání schůzky je přímo zde. Nyní chcete, aby Outlook automaticky nastavil čas připomenutí schůzky „mimo pracoviště“ na 1 hodinu před začátkem a schůzky „na pracovišti“ na 15 minut před začátkem. S ohledem na tento požadavek si níže ukážeme rychlou metodu.

Automaticky nastavit různé připomenutí pro schůzky v různých barevných kategoriích

1. Nejprve spusťte aplikaci Outlook.
2. Poté stisknutím kláves „Alt + F11“ otevřete okno editoru VBA.
3. Dále v následujícím okně zkopírujte a vložte níže uvedený kód VBA do projektu „ThisOutlookSession“.

Public WithEvents objCalendar As Outlook.Folder
Public WithEvents objCalendarItems As Outlook.Items

Private Sub Application_Startup()
    Set objCalendar = Outlook.Application.Session.GetDefaultFolder(olFolderCalendar)
    Set objCalendarItems = objCalendar.Items
End Sub

Private Sub objCalendarItems_ItemAdd(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub objCalendarItems_ItemChange(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub SetReminder_BasedOnCategories(ByVal objCalendarItem As Object)
    Dim objMeeting As Outlook.AppointmentItem
    Dim strCategories As String
 
    If objCalendarItem.Class = olAppointment Then
       'Check if the item is a meeting
       If objCalendarItem.MeetingStatus = olMeeting Then
          Set objMeeting = objCalendarItem
          strCategories = objMeeting.Categories
 
          'Set Reminder as 60 min before start for offsite appointments
          If InStr(strCategories, "Offsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 60
                 .Save
             End With
             'Set Reminder as 15 min before start for onsite appointments
          ElseIf InStr(strCategories, "Onsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 15
                 .Save
             End With
          End If
       End If
    End If
End Sub

4. Později je třeba kliknout do podprogramu „Application_Startup“ a stisknout klávesu „F5“ pro spuštění tohoto makra.
5. Od té doby aplikace Outlook při každém přidání nové schůzky do výchozího kalendáře nebo při změně stávající schůzky automaticky zkontroluje kategorie schůzky a automaticky nastaví jiný čas připomenutí.

Odstraňte chyby aplikace Outlook

S Outlookem se mohou čas od času vyskytnout různé problémy. Proto je pro uživatele nesmírně důležité naučit se, jak se s problémy v Outlooku vypořádat. Pro začátek je lepší pravidelně zálohovat data Outlooku. Navíc, pokud je to dostupné, doporučuje se mít silný Oprava aplikace Outlook nástroj v okolí, například DataNumen Outlook Repair. Může skenovat váš soubor PST, zjistit problémy s Outlookem a poté je snadno vyřešit.

Úvod autora:

Shirley Zhang je expertem na obnovu dat DataNumen, Inc., která je světovým lídrem v oblasti technologií pro obnovu dat, včetně zotavení sql a výhledové softwarové produkty pro opravy. Pro více informací navštivte www.datanumen.com