Jak automaticky exportovat informace z příchozích e-mailů do souboru aplikace Excel pomocí aplikace Outlook VBA

Mnoho uživatelů doufá, že aplikace Outlook dokáže automaticky exportovat primární informace příchozích e-mailů do souboru aplikace Excel. Tento článek se podívá na tento požadavek a představí rychlou metodu prostřednictvím aplikace Outlook VBA.

Někdy z určitých důvodů, jako jsou statistiky pošty, můžete často potřebovat exportovat e-maily do souboru aplikace Excel. Obecně platí, že pro existující přijaté e-maily můžete jednoduše použít funkci „Import a Export“ k exportu do Excelu najednou. Možná si však dokonce přejete, aby aplikace Outlook mohla automaticky exportovat příchozí e-maily do aplikace Excel, jakmile dorazí do vaší poštovní schránky. Bez jakýchkoliv pochybností taková nativní funkce v Outlooku neexistuje. Proto musíte použít jiné přístupy, jako je doplněk třetí strany nebo Outlook VBA. Zde vás naučíme, jak jej zautomatizovat pomocí aplikace Outlook VBA. Čtěte dále, abyste získali kroky a podle kódů.

Automatický export informací o příchozích e-mailech do souboru aplikace Excel

1. Na prvním místě byste měli vytvořit soubor Excel.

• Otevřete nový soubor aplikace Excel.
• Pak byste měli napsat „Ne“. v buňce A1, „Jméno odesílatele“ v buňce B1, „E-mailová adresa odesílatele“ v buňce C1 a „Předmět e-mailu“ v buňce D1 a „Čas přijetí“ v buňce E1, jako na následujícím obrázku.
• Nakonec jej uložte do požadovaného jména a požadované složky.

2. Poté byste měli spustit aplikaci Outlook.
3. Poté stiskněte klávesy „Alt + F11“, čímž se dostanete do editoru VBA.
4. Dále ve vyskakovacím okně byste měli dvakrát kliknout na „ThisOutlookSession“ na levé straně.
5. Následně v okně projektu „ThisOutlookSession“ musíte zkopírovat a vložit do něj následující kódy VBA.

Public WithEvents objMails As Outlook.Items

Private Sub Application_Startup()
    Set objMails = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Private Sub objMails_ItemAdd(ByVal Item As Object)
    Dim objMail As Outlook.MailItem
    Dim strExcelFile As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkBook As Excel.Workbook
    Dim objExcelWorkSheet As Excel.Worksheet
    Dim nNextEmptyRow As Integer
    Dim strColumnB As String
    Dim strColumnC As String
    Dim strColumnD As String
    Dim strColumnE As String

    If Item.Class = olMail Then
       Set objMail = Item
    End If
 
    'Specify the Excel file which you want to auto export the email list
    'You can change it as per your case
    strExcelFile = "E:\Email\Email Statistics.xlsx"
 
    'Get Access to the Excel file
    On Error Resume Next
    Set objExcelApp = GetObject(, "Excel.Application")
    If Error <> 0 Then
       Set objExcelApp = CreateObject("Excel.Application")
    End If
    Set objExcelWorkBook = objExcelApp.Workbooks.Open(strExcelFile)
    Set objExcelWorkSheet = objExcelWorkBook.Sheets("Sheet1")
 
    'Get the next empty row in the Excel worksheet
    nNextEmptyRow = objExcelWorkSheet.Range("B" & objExcelWorkSheet.Rows.Count).End(xlUp).Row + 1
 
    'Specify the corresponding values in the different columns
    strColumnB = objMail.SenderName
    strColumnC = objMail.SenderEmailAddress
    strColumnD = objMail.Subject
    strColumnE = objMail.ReceivedTime
 
    'Add the vaules into the columns
    objExcelWorkSheet.Range("A" & nNextEmptyRow) = nNextEmptyRow - 1
    objExcelWorkSheet.Range("B" & nNextEmptyRow) = strColumnB
    objExcelWorkSheet.Range("C" & nNextEmptyRow) = strColumnC
    objExcelWorkSheet.Range("D" & nNextEmptyRow) = strColumnD
    objExcelWorkSheet.Range("E" & nNextEmptyRow) = strColumnE
 
    'Fit the columns from A to E
    objExcelWorkSheet.Columns("A:E").AutoFit
 
    'Save the changes and close the Excel file
    objExcelWorkBook.Close SaveChanges:=True
End Sub

6. Později byste měli tento kód podepsat.
7. Následně restart Outlook k aktivaci nového projektu VBA.
8. Od této chvíle budou všechny příchozí e-maily automaticky exportovány do přednastaveného souboru aplikace Excel, jakmile přijdou do složky Doručená pošta. Excel soubor bude vypadat jako následující obrázek:

Zabraňte bolestivému poškození dat PST

Outlook si vysloužil mnoho chvály díky svým různým funkcím. To však neznamená, že je to spolehlivé. Stále to může být kdykoli kompromitováno. Pokud například často nesprávně zavíráte svůj Outlook, je velmi pravděpodobné, že vaše data PST budou vystavena nebezpečí. V tomto případě, pokud byste chtěli opravit PST data, musíte se obrátit na zkušený nástroj, jako je např DataNumen Outlook Repair.

Úvod autora:

Shirley Zhang je expertem na obnovu dat DataNumen, Inc., která je světovým lídrem v oblasti technologií pro obnovu dat, včetně obnovit mdf a výhledové softwarové produkty pro opravy. Pro více informací navštivte www.datanumen.com