Jak automaticky zakázat hypertextové odkazy v příchozích e-mailech aplikace Outlook od neznámých odesílatelů

Chcete-li blokovat škodlivé odkazy, raději nakonfigurujte svůj Outlook tak, aby automaticky zakázal hypertextové odkazy v příchozích e-mailech od neznámých odesílatelů. Tento článek odhalí část kódů VBA, které vám mohou pomoci získat to jako korek.

Mnoho uživatelů si stěžovalo, že viry přenášené e-mailem napadly jejich soubor aplikace Outlook. Více často než ne, je to proto, že snadno důvěřují těmto e-mailům od neznámých odesílatelů. Takže si stahují nebo klikají na hypertextové odkazy v e-mailech. Nyní se níže podělíme o metodu. Je schopen nechat Outlook automaticky zakázat hypertextové odkazy příchozích e-mailů od neznámých odesílatelů. Pokud máte takové potřeby, přečtěte si prosím další podrobnosti.

Automaticky zakázat hypertextové odkazy v příchozích e-mailech od neznámých odesílatelů

1. Pro začátek přejděte v Outlooku do editoru VBA pomocí kláves „Alt + F11“.
2. Dále na nové obrazovce přidejte objekt „MS VBScript Regular Expressions“ dle příspěvku „Jak přidat odkaz na knihovnu objektů ve VBA".
3. Poté zkopírujte a vložte následující kód do projektu „ThisOutlookSession“.

Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
    Set objInboxItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

'Occurs when new mail arrives in your Inbox
Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
    Dim objMail As MailItem
    Dim objContacts As Outlook.Items
    Dim strFilter As String
    Dim objFoundContact As Outlook.ContactItem
    Dim bUnknownSender As Boolean
    Dim objRegExp As Object
    Dim objFoundResults As Object
    Dim i, n As Long
 
    If TypeOf Item Is MailItem Then
       Set objMail = Item
 
       'Check if the sender is in your default Contact folder
       Set objContacts = Application.Session.GetDefaultFolder(olFolderContacts).Items
       For i = 1 To 3
           strFilter = "[Email" & i & "Address] = " & objMail.SenderEmailAddress
           Set objFoundContact = objContacts.Find(strFilter)
           If Not (objFoundContact Is Nothing) Then
              bUnknownSender = False
              Exit For
           End If
       Next
       If objFoundContact Is Nothing Then
          bUnknownSender = True
       End If
 
       'If the sender is unknown
       If bUnknownSender = True Then
          'Find the urls within "<a href=" tags in HTMLbody of Mail
          Set objRegExp = CreateObject("vbscript.RegExp")
          With objRegExp
               .Pattern = "<?href\s*=\s*[""'].+?[""'][^>]*?"
               .IgnoreCase = True
               .Global = True
          End With
 
          If objRegExp.Test(objMail.HTMLBody) Then
             Set objFoundResults = objRegExp.Execute(objMail.HTMLBody)
             For n = 1 To objFoundResults.Count
                 'Disable the hyperlinks in HTMLbody
                 objMail.HTMLBody = Replace(objMail.HTMLBody, objFoundResults.Item(n - 1).Value, "")
             Next
          End If
 
          'Save the mail
          objMail.Save
       End If
    End If
End Sub

4. Poté aktivujte toto makro buď restartováním Outlooku, nebo stisknutím klávesy „F5“ v podprogramu „Application_Startup“.
5. Od té doby pokaždé, když se do doručené pošty dostane e-mail od odesílatele, který není uložen ve výchozí složce Kontakty, Outlook v něm hypertextové odkazy automaticky deaktivuje.

Několik důležitých věcí v ochraně aplikace Outlook

Vzhledem k tomu, že aplikace Outlook je náchylná k poškození, je velmi obtížné chránit soubor aplikace Outlook. Zde uvedeme několik věcí, které musíte mít při ochraně dat aplikace Outlook. Nejprve musíte pravidelně zálohovat data aplikace Outlook. Kromě toho je nezbytné, abyste si dávali pozor na všechna potenciální rizika, jako jsou škodlivé přílohy nebo hypertextové odkazy. V neposlední řadě byste si měli předem připravit výkonný opravný nástroj Outlooku, např DataNumen Outlook Repair. Určitě se vám bude hodit, když budete potřebovat opravit PST soubor, ale nástroj pro opravu doručené pošty prokáže selhání.

Úvod autora:

Shirley Zhang je expertem na obnovu dat DataNumen, Inc., která je světovým lídrem v oblasti technologií pro obnovu dat, včetně poškozený mdf a výhledové softwarové produkty pro opravy. Pro více informací navštivte www.datanumen.com